tools/mkcaniuse

   1 #!/usr/bin/env perl
   2 use 5.014;
   3 use warnings;
   4
   5 use Data::Dump 'pp';
   6 use JSON::PP;
   7 use File::stat;
   8 use Time::Piece;
   9 use List::Util 'uniq';
  10
  11 our $VERSION = '1.04';
  12
  13 my %BROWSERJOIN = (
  14         edge    => 'ie',
  15         and_chr => 'android',
  16 );
  17
  18 local $/;  # slurp
  19 my $source = readline;
  20
  21 $JSON::PP::false = 0;
  22 $JSON::PP::true  = 1;
  23
  24 my $data = decode_json($source);
  25 $data->{-date} = Time::Piece->new($_)->datetime
  26         for delete $data->{updated} || ();
  27
  28 delete $data->{eras};
  29 for (values %{ $data->{data} }) {
  30         delete @{$_}{qw[ usage_perc_a usage_perc_y ]};
  31 }
  32 while (my ($browser, $alias) = each %BROWSERJOIN) {
  33         my $agent =        $data->{agents}->{$browser} or next;
  34         my $amend = delete $data->{agents}->{$alias}   or next;
  35         unshift @{ $agent->{version_list} }, @{ $amend->{version_list} };
  36         $agent->{browser} = sprintf '%s (former %s)',
  37                 $agent->{browser}, $amend->{browser};
  38
  39         # prefer deprecated name if newer is convoluted (Chr/And.)
  40         $agent->{abbr} = $amend->{abbr} if $agent->{abbr} =~ m{/};
  41
  42         for (values %{ $data->{data} }) {
  43                 my $stats = delete $_->{stats}->{$alias} or next;
  44                 $_ = { %{$_}, %{$stats} } for $_->{stats}->{$browser};
  45         }
  46 }
  47
  48 for my $feature (values %{ $data->{data} }) {
  49         while (my ($attr, $row) = each %{$feature}) {
  50                 delete $feature->{$attr} if ref $row eq '' and $row eq '';
  51         }
  52 }
  53
  54 while (my ($agent, $row) = each %{ $data->{agents} }) {
  55         delete $row->{usage_global};
  56         $row->{versions} = [ uniq map { $_->{version} } @{ $row->{version_list} } ];
  57
  58         # convert metadata list into (cleaned) lookup table
  59         my %version_lookup;
  60         for (@{ $row->{version_list} }) {
  61                 delete $_->{era};
  62                 delete $_->{prefix} unless $_->{prefix};
  63                 $version_lookup{ delete $_->{version} } = $_;
  64         }
  65         $row->{version_list} = \%version_lookup;
  66
  67         # omit identical values from subsequent versions
  68         for my $feature (values %{ $data->{data} }) {
  69                 my $cmp;  # same value to be omitted
  70                 my $verstats = $feature->{stats}->{$agent};
  71                 for my $version (@{ $row->{versions} }) {
  72                         defined $verstats->{$version}
  73                                 or warn "missing feature $feature->{title} for $agent $version";
  74                         if (defined $cmp and $verstats->{$version} eq $cmp) {
  75                                 delete $verstats->{$version};
  76                         }
  77                         else {
  78                                 $cmp = $verstats->{$version};
  79                         }
  80                 }
  81         }
  82 }
  83
  84 say "# automatically generated by $0";
  85 print '+', pp($data);
  86
  87 __END__
  88
  89 =head1 NAME
  90
  91 mkcaniuse - Turn Javascript data into an equivalent Perl structure
  92
  93 =head1 SYNOPSIS
  94
  95         tools/mkcaniuse data.json >browser-support.inc.pl
  96