Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6 no  warnings 'uninitialized';  # save some useless checks for more legible code
   7 use Carp;
   8
   9 our $VERSION = '3.00';
  10
  11 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  12 my @rowdesc = qw(numeric top home bottom);
  13 my %keyrows = do 'keys.inc.pl';
  14 # add first two cases of each row again with each char prepended by + (alt)
  15 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  16
  17 my %keytrans = (
  18         '^h' => "\x{232B}", # BS
  19         '^i' => "\x{21E5}", # TAB
  20         '^m' => "\x{21B5}", # CR
  21         '^?' => "\x{2326}", # DEL
  22         '^[' => "\x{238B}", # ESC
  23 );
  24
  25 sub new {
  26         my $class = shift;
  27         my ($self) = @_;
  28
  29         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  30         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  31         $self->{map} ||= 'qwerty';
  32
  33         $self->{sign} ||= do {
  34                 require Shiar_Sheet::KeySigns;
  35                 Shiar_Sheet::KeySigns->VERSION(1.04);
  36                 \%Shiar_Sheet::KeySigns::sign;
  37         };
  38
  39         $self->{showkeys} = $PLP::Script::showkeys;
  40         $self->{style   } = $PLP::Script::style;
  41
  42         bless $self, $class;
  43 }
  44
  45 sub map {
  46         my $self = shift;
  47         my ($mapname) = @_;
  48
  49         return $self->{map} = $mapname if defined $keyrows{$mapname};
  50         return undef;
  51 }
  52
  53 sub escapeclass {
  54         local $_ = shift;
  55         s/\^/_c/g;
  56         s/\+/_m/g;
  57         s/\[/_sbo/g;
  58         s/\]/_sbc/g;
  59         s/\\/_b/g;
  60         s/^$/_/;
  61         return $_;
  62 }
  63
  64 sub escapehtml {
  65         local $_ = shift;
  66         s/</&lt;/g;
  67         s/>/&gt;/g;
  68         s/  / &nbsp;/g;
  69         return $_;
  70 }
  71
  72 sub escapedesc {
  73         my $self = shift;
  74         local $_ = shift;
  75         s{ (< ([^>]*) >) }{ $self->{sign}->{$2} // $1 }xeg;
  76         return $_;
  77 }
  78
  79 sub keyunalias {
  80         my $self = shift;
  81         my ($key, $ancestry) = @_;
  82
  83         $key =~ s/(\S*?)(\+?\^?\S$)/$2/;
  84         my $mode = $1;
  85         my $keyinfo = $self->{def}->{$mode}->{$key};
  86
  87         return unless defined $keyinfo;
  88         return $keyinfo unless ref $keyinfo eq 'SCALAR';
  89         $keyinfo = ${$keyinfo};
  90         return '' if $ancestry->{$key}++;  # endless loop failsafe
  91         return $self->keyunalias($keyinfo, $ancestry);
  92 }
  93
  94 sub print_letter {
  95         my $self = shift;
  96         my ($key, $mode) = @_;
  97
  98         return if $key eq '^0';
  99         return 'Esc' if $key eq "\e";
 100         return $keytrans{$key} if defined $keytrans{$key};
 101         my $html = $self->{def}{$mode}{lead} . escapehtml($key);
 102            $html =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 103            $html =~ s{\+(?=.)}{<small>+</small>};  # meta
 104         return $html;
 105 }
 106
 107 sub print_key {
 108         my $self = shift;
 109         my ($mode, $key, $def) = @_;
 110
 111         if (not defined $def) {
 112                 $def = [$key eq '^0' ? 'ni' : 'no'];
 113         }
 114         elsif (ref $def eq 'SCALAR') {
 115                 $def = [undef, $def];
 116         }
 117         if (ref $def ne 'ARRAY') {
 118                 carp "print_key: invalid definition for $mode$key: $def";
 119                 return;
 120         }
 121         my ($flags, $txt) = @{$def};
 122         if (ref $txt eq 'SCALAR') {
 123                 my $ref = ${$txt};
 124                 $def = $self->keyunalias($ref);
 125                 $ref = 'esc' if $ref eq "\e";
 126                 $flags //= $def->[0] if ref $def eq 'ARRAY';
 127                 $txt = $self->{sign}->{alias} . $ref;
 128                 $flags .= ' alias';
 129         }
 130         my ($desc, $mnem) = split /\n/, $self->escapedesc($txt);
 131
 132         my $keytxt = $self->print_letter($key, $mode);
 133            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 134            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 135         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 136            $keytxt  = "<b$keyhint>$keytxt</b>";
 137            $keytxt .= ' '.$desc if defined $desc;
 138            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 139         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 140                 ' onclick="setmode(%s)"',
 141                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 142         );
 143         $flags =~ s/\bx\w+/ext/;
 144         $flags =~ s/\bv\d+/new/;
 145         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 146
 147         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 148         print "\n";
 149 }
 150
 151 sub print_rows {
 152         my $self = shift;
 153         my ($rowsspec, $defrows) = @_;
 154         $defrows ||= [2, 1, 0];
 155         my %moderows = (
 156                 -DEFAULT => defined $rowsspec && $rowsspec ne '' &&
 157                         split(/\s* ([^=\s]*) = \s*/x, $rowsspec),
 158                 # plus specific mode overrides prefixed by '='
 159         );
 160         my @modes = sort keys %{ $self->{def} };
 161
 162         printf '<table id="rows" class="%s">'."\n\n", $self->{tableclass} // 'keys';
 163
 164 print_row:
 165         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 166                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 167
 168 #               grep {
 169 #                       defined $self->{def}->{''}->{$_} or defined $self->{def}->{g}->{$_}
 170 #               } map { @{$_} } @{$keyrow} or next;
 171
 172                 printf qq{<tbody class="row row%d">\n}, $row+1;
 173                 for my $basemode (@modes) {
 174                         my @moderows = split /\s+/,
 175                                 $row < 0 ? '1' : # top row (esc key) always unshifted
 176                                 $moderows{$basemode} // $moderows{-DEFAULT};
 177
 178                 for my $submode (@moderows ? @moderows : '') {
 179                         my $mode = $basemode . $submode;
 180                         my @caserows = $mode =~ s/(\d+)(?:-(\d*))?$//
 181                                 ? (map {$_ - 1} split //, $row == 0 ? $2 // $1 : $1)  # user override
 182                                 : @$defrows;  # default
 183                         my $modekeys = $self->{def}{$mode};
 184
 185                         for my $case (@caserows) {
 186                                 my $keycase = $keyrow->[$case] or next;
 187                                   @$keycase or next;
 188                                 my @caseclass;
 189                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 190                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 191                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 192
 193                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 194                                         ' class="%s"', join ' ', @caseclass
 195                                 );
 196                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 197                                                 $self->escapedesc($self->{mode}->{$mode} || "mode $basemode"),
 198                                                 "$rowdesc[$row] row $casedesc[$case]"
 199                                 ) unless $row < 0;
 200                                 print "\n";
 201                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 202                                 print qq{\t\t</tr>\n};
 203                         } # case
 204
 205                 } # submode
 206
 207                 } # basemode
 208                 print qq{\t</tbody>\n};
 209         } # row
 210
 211         print "</table>\n";
 212 }
 213
 214 sub print_legend {
 215         my $self = shift;
 216         my ($class, $flags) = @_;
 217
 218         say qq{\t\t<dl class="legend $class">};
 219         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s</dd>'."\n",
 220                 $_, map { $self->escapedesc($_) } @{ $self->{flag}->{$_} || ["($_)", '...'] }
 221         ) for @$flags;
 222         say "\t\t</dl>";
 223 }
 224
 225 1;
 226
 227 =head1 NAME
 228
 229 Shiar_Sheet::Keyboard - Output HTML for key sheets
 230
 231 =head1 SYNOPSIS
 232
 233         our %sign = (alias => 'see: ');
 234
 235         my $keys = Shiar_Sheet::Keyboard({
 236                 def => {
 237                         'lead' => {
 238                                 'A' => \'a', # alias
 239                                 'a' => ['classes', 'description', 'hover comments'],
 240                         },
 241                 },
 242                 mode => {
 243                         'lead' => 'mode description',
 244                 },
 245         });
 246         $keys->map('dvorak') or die "Keyboard map not found";
 247
 248         $keys->print_rows;
 249
 250 =head1 DESCRIPTION
 251
 252 Used by https://sheet.shiar.nl to display keyboard sheets.
 253 Assumes specific stylesheets and javascript from this site,
 254 so probably not of much use elsewhere.
 255
 256 =head1 AUTHOR
 257
 258 Mischa POSLAWSKY <perl@shiar.nl>
 259
 260 =head1 LICENSE
 261
 262 Licensed under the GNU Affero General Public License version 3.
 263