Shiar_Sheet/Keyboard.pm

   1 package Shiar_Sheet::Keyboard;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6 no  warnings 'uninitialized';  # save some useless checks for more legible code
   7 use Carp;
   8
   9 our $VERSION = '3.01';
  10
  11 my @casedesc = (undef, qw/shift ctrl meta/, 'shift meta');
  12 my @rowdesc = qw(numeric top home bottom);
  13 my %keyrows = do 'keys.inc.pl';
  14 # add first two cases of each row again with each char prepended by + (alt)
  15 push @$_, map { [map {"+$_"} @$_] } @$_[0,1] for map {@$_} values %keyrows;
  16
  17 my %keytrans = (
  18         '^h' => "\x{232B}", # BS
  19         '^i' => "\x{21E5}", # TAB
  20         '^m' => "\x{21B5}", # CR
  21         '^?' => "\x{2326}", # DEL
  22         '^[' => "\x{238B}", # ESC
  23 );
  24
  25 sub new {
  26         my $class = shift;
  27         my ($self) = @_;
  28
  29         croak 'Invalid keyboard definitions specified' unless ref $self eq 'HASH';
  30         croak 'No key definitions specified' unless ref $self->{def} eq 'HASH';
  31         $self->{map} ||= 'qwerty';
  32
  33         $self->{sign} ||= do {
  34                 require Shiar_Sheet::KeySigns;
  35                 Shiar_Sheet::KeySigns->VERSION(1.04);
  36                 \%Shiar_Sheet::KeySigns::sign;
  37         };
  38
  39         $self->{showkeys} = $PLP::Script::showkeys;
  40         $self->{style   } = $PLP::Script::style;
  41
  42         bless $self, $class;
  43 }
  44
  45 sub map {
  46         my $self = shift;
  47         my ($mapname) = @_;
  48
  49         return $self->{map} = $mapname if defined $keyrows{$mapname};
  50         return undef;
  51 }
  52
  53 sub escapeclass {
  54         local $_ = shift;
  55         s/\^/_c/g;
  56         s/\+/_m/g;
  57         s/\[/_sbo/g;
  58         s/\]/_sbc/g;
  59         s/\\/_b/g;
  60         s/^$/_/;
  61         return $_;
  62 }
  63
  64 sub escapehtml {
  65         local $_ = shift;
  66         s/</&lt;/g;
  67         s/>/&gt;/g;
  68         s/  / &nbsp;/g;
  69         return $_;
  70 }
  71
  72 sub escapedesc {
  73         my $self = shift;
  74         local $_ = shift;
  75         s{ (< ([^>]*) >) }{ $self->{sign}->{$2} // $1 }xeg;
  76         return $_;
  77 }
  78
  79 sub keyunalias {
  80         my $self = shift;
  81         my ($key, $ancestry) = @_;
  82
  83         $key =~ s/(\S*?)(\+?\^?\S$)/$2/;
  84         my $mode = $1;
  85         my $keyinfo = $self->{def}->{$mode}->{$key};
  86
  87         return unless defined $keyinfo;
  88         return $keyinfo unless ref $keyinfo eq 'SCALAR';
  89         $keyinfo = ${$keyinfo};
  90         return '' if $ancestry->{$key}++;  # endless loop failsafe
  91         return $self->keyunalias($keyinfo, $ancestry);
  92 }
  93
  94 sub print_letter {
  95         my $self = shift;
  96         my ($key, $mode) = @_;
  97
  98         return if $key eq '^0';
  99         return 'Esc' if $key eq "\e";
 100         return $keytrans{$key} if defined $keytrans{$key};
 101         my $html = $self->{def}{$mode}{lead} . escapehtml($key);
 102            $html =~ s{\^(?=.)}{<small>^</small>};  # element around ctrl-identifier
 103            $html =~ s{\+(?=.)}{<small>+</small>};  # meta
 104         return $html;
 105 }
 106
 107 sub print_key {
 108         my $self = shift;
 109         my ($mode, $key, $def) = @_;
 110
 111         if (not defined $def) {
 112                 $def = [$key eq '^0' ? 'ni' : 'no'];
 113         }
 114         elsif (ref $def eq 'SCALAR') {
 115                 $def = [undef, $def];
 116         }
 117         if (ref $def ne 'ARRAY') {
 118                 carp "print_key: invalid definition for $mode$key: $def";
 119                 return;
 120         }
 121         my ($flags, $txt) = @{$def};
 122         if (ref $txt eq 'SCALAR') {
 123                 my $ref = ${$txt};
 124                 $def = $self->keyunalias($ref);
 125                 $ref = 'esc' if $ref eq "\e";
 126                 $flags //= $def->[0] if ref $def eq 'ARRAY';
 127                 $txt = $self->{sign}->{alias} . $ref;
 128                 $flags .= ' alias';
 129         }
 130         my ($desc, $mnem) = split /\n/, $self->escapedesc($txt);
 131
 132         my $onclick = $flags =~ s/ ?\bmode(\S*)// && defined $self->{def}{$1} && sprintf(
 133                 ' onclick="setmode(%s)"',
 134                 $1 eq '' ? '' : sprintf(q{'mode%s'}, escapeclass($1))
 135         );
 136         my $keyhint = defined($mnem) && qq{ title="$mnem"};
 137         if ($self->{tableclass} =~ /\bbig\b/) {
 138                 $onclick .= $keyhint;
 139                 $keyhint = '';
 140         }
 141         my $keytxt = $self->print_letter($key, $mode);
 142            $keytxt .= "<small>$self->{sign}->{motion}</small>" if $flags =~ s/ ?\bargm\b//;  # motion argument
 143            $keytxt .= $self->{sign}->{$1} while $flags =~ s/(?:^| )(arg[a-ln-z]?)\b//;  # arguments
 144            $keytxt  = "<b$keyhint>$keytxt</b>";
 145            $keytxt .= ' '.$desc if defined $desc;
 146            $keytxt = qq{<a href="/$1">$keytxt</a>} if $flags =~ s/ ?\blink(\S*)//;
 147         $flags =~ s/\bx\w+/ext/;
 148         $flags =~ s/\bv\d+/new/;
 149         $flags .= ' chr'.ord(substr $key, -1) if $key ne '^0';
 150
 151         print qq{\t\t<td class="$flags"$onclick>$keytxt};
 152         print "\n";
 153 }
 154
 155 sub print_rows {
 156         my $self = shift;
 157         my ($rowsspec, $defrows) = @_;
 158         $defrows ||= [2, 1, 0];
 159         my %moderows = (
 160                 -DEFAULT => defined $rowsspec && $rowsspec ne '' &&
 161                         split(/\s* ([^=\s]*) = \s*/x, $rowsspec),
 162                 # plus specific mode overrides prefixed by '='
 163         );
 164         my @modes = sort keys %{ $self->{def} };
 165
 166         printf '<table id="rows" class="%s">'."\n\n", $self->{tableclass} // 'keys';
 167
 168 print_row:
 169         for (my $row = -1; $row <= $#{ $keyrows{$self->{map}} }; $row++) {
 170                 my $keyrow = $row < 0 ? [["\e"]] : $keyrows{$self->{map}}->[$row];
 171
 172 #               grep {
 173 #                       defined $self->{def}->{''}->{$_} or defined $self->{def}->{g}->{$_}
 174 #               } map { @{$_} } @{$keyrow} or next;
 175
 176                 printf qq{<tbody class="row row%d">\n}, $row+1;
 177                 for my $basemode (@modes) {
 178                         my @moderows = split /\s+/,
 179                                 $row < 0 ? '1' : # top row (esc key) always unshifted
 180                                 $moderows{$basemode} // $moderows{-DEFAULT};
 181
 182                 for my $submode (@moderows ? @moderows : '') {
 183                         my $mode = $basemode . $submode;
 184                         my @caserows = $mode =~ s/(\d+)(?:-(\d*))?$//
 185                                 ? (map {$_ - 1} split //, $row == 0 ? $2 // $1 : $1)  # user override
 186                                 : @$defrows;  # default
 187                         my $modekeys = $self->{def}{$mode};
 188
 189                         for my $case (@caserows) {
 190                                 my $keycase = $keyrow->[$case] or next;
 191                                   @$keycase or next;
 192                                 my @caseclass;
 193                                 push @caseclass, 'mode', 'mode'.escapeclass($basemode) if $basemode ne '';
 194                                 push @caseclass, 'lead' if defined $modekeys->{lead};  # leading command key shown
 195                                 push @caseclass, $casedesc[$case] if defined $casedesc[$case];
 196
 197                                 printf "\t<tr%s>", @caseclass > 0 && sprintf(
 198                                         ' class="%s"', join ' ', @caseclass
 199                                 );
 200                                 printf('<th>%s<small>: %s</small></th>', # XXX insert &nbsp; here to fix msie<=6
 201                                                 $self->escapedesc($self->{mode}->{$mode} || "mode $basemode"),
 202                                                 "$rowdesc[$row] row $casedesc[$case]"
 203                                 ) unless $row < 0;
 204                                 print "\n";
 205                                 $self->print_key($mode, $_, $modekeys->{$_}) for @$keycase;
 206                                 print qq{\t\t</tr>\n};
 207                         } # case
 208
 209                 } # submode
 210
 211                 } # basemode
 212                 print qq{\t</tbody>\n};
 213         } # row
 214
 215         print "</table>\n";
 216 }
 217
 218 sub print_legend {
 219         my $self = shift;
 220         my ($class, $flags) = @_;
 221
 222         say qq{\t\t<dl class="legend $class">};
 223         printf("\t\t".'<dt class="%s">%s'."\n\t\t\t".'<dd>%s</dd>'."\n",
 224                 $_, map { $self->escapedesc($_) } @{ $self->{flag}->{$_} || ["($_)", '...'] }
 225         ) for @$flags;
 226         say "\t\t</dl>";
 227 }
 228
 229 1;
 230
 231 =head1 NAME
 232
 233 Shiar_Sheet::Keyboard - Output HTML for key sheets
 234
 235 =head1 SYNOPSIS
 236
 237         our %sign = (alias => 'see: ');
 238
 239         my $keys = Shiar_Sheet::Keyboard({
 240                 def => {
 241                         'lead' => {
 242                                 'A' => \'a', # alias
 243                                 'a' => ['classes', 'description', 'hover comments'],
 244                         },
 245                 },
 246                 mode => {
 247                         'lead' => 'mode description',
 248                 },
 249         });
 250         $keys->map('dvorak') or die "Keyboard map not found";
 251
 252         $keys->print_rows;
 253
 254 =head1 DESCRIPTION
 255
 256 Used by https://sheet.shiar.nl to display keyboard sheets.
 257 Assumes specific stylesheets and javascript from this site,
 258 so probably not of much use elsewhere.
 259
 260 =head1 AUTHOR
 261
 262 Mischa POSLAWSKY <perl@shiar.nl>
 263
 264 =head1 LICENSE
 265
 266 Licensed under the GNU Affero General Public License version 3.
 267