tools/mkdigraphlist

   1 #!/usr/bin/env perl
   2
   3 use strict;
   4 use warnings;
   5 use utf8;
   6
   7 use open OUT => ':encoding(utf-8)', ':std';
   8 use JSON ();
   9
  10 our $VERSION = '1.07';
  11
  12 # import and combine various digraph data
  13 push @INC, 'data';
  14 my $rfc = do 'digraphs-rfc.inc.pl'
  15         or die "error reading digraphs include: ", $@ // $!;
  16 my $extra = do 'digraphs-shiar.inc.pl'
  17         or warn "could not include shiar proposals: ", $@ // $!;
  18 my $vim = do 'digraphs-vim.inc.pl'
  19         or warn "could not include vim extensions ", $@ // $!;
  20 my $vimold = do 'digraphs-vim-74.inc.pl'
  21         or warn "could not include vim compatibility ", $@ // $!;
  22 my $di = { %{$vim // {}}, %{$rfc}, %{$extra // {}} };
  23
  24 # optionally get unicode character information
  25 my $uninfo = do 'unicode-char.inc.pl'
  26         or warn "could not include unicode details: ", $@ // $!;
  27
  28 # output json map of character info
  29 my %table;
  30 $table{$_} = 0 for (
  31         grep { !defined $di->{$_} }
  32         map { substr($_, 1, 1).substr($_, 0, 1) } sort keys %{$di}
  33 );
  34 $table{$_} = [
  35         ord $di->{$_},   # original code point
  36         $uninfo->{ $di->{$_} }->[1] // '',  # name
  37         (
  38                 $rfc->{$_}
  39                         ? $vim->{$_} ? 'l5' : 'l1'  # vim+rfc or rfc only
  40                         : $vimold && $vimold->{$_} ? 'l4'  # compat vim if known
  41                         : $vim->{$_} ? 'l3' : 'l2', # vim only or neither
  42         ),
  43         ($uninfo->{ $di->{$_} }->[0] // '') =~ s/ u-di| u-prop//gr,  # class
  44         $uninfo->{ $di->{$_} }->[4] // (),  # string
  45 ] for sort keys %{$di};
  46
  47 print JSON->new->ascii->canonical->encode({
  48         title => 'RFC-1345',
  49         key  => \%table,
  50         intro => join("\n",
  51                 'Character mnemonics following compose key ⎄:',
  52                 'i^k in <a href="/vi">Vim</a>,',
  53                 '^u^\ in <a href="/readline">Emacs</a>,',
  54                 '^a^v in <a href="/screen">Screen</a>.',
  55                 'Similar but different from <a href="/digraphs/xorg">X.Org</a>.',
  56                 'Also see <a href="/unicode">common Unicode</a>.</p>',
  57                 '<p class="aside">Unofficial <span class="u-l2">proposals</span>',
  58                 'are available as <a href="/digraphs.vim">ex commands</a>.',
  59         ),
  60         flag => {
  61                 l5 => 'full support',
  62                 l4 => 'vim extension',
  63                 l3 => 'vim v8.0',
  64                 l2 => 'proposal',
  65                 l1 => 'not in vim',
  66         },
  67         flagclass => {
  68                 l5 => '', # common
  69                 l3 => 'u-l5', # rare
  70         },
  71 });
  72
  73 __END__
  74
  75 =head1 NAME
  76
  77 mkdigraphlist - Output character list of combined digraph data
  78
  79 =head1 SYNOPSIS
  80
  81     mkdigraphlist | jq -r '.key."DO"[0]' | perl -nE 'say chr' # $
  82
  83 =head1 DESCRIPTION
  84
  85 Combines precompiled digraph includes of rfc (1345), vim, and shiar
  86 and outputs a complete map including character details and usage classes.
  87
  88 The C<key> values can either be a scalar string containing another
  89 digraph which can be considered identical (usually inverted),
  90 or an array ref containing at least the resulting character's
  91 Unicode code point value.  If available, the following UCD data
  92 is appended: character name, usage classes, unicode classes,
  93 and replacement output string.
  94 For example:
  95
  96   {
  97    "key": {
  98     "AE" => [198, "LATIN CAPITAL LETTER AE", "u-di", "Latin Lu Xl u-v11"],
  99     "EA" => "AE",
 100    }
 101   }
 102
 103 =head1 AUTHOR
 104
 105 Mischa POSLAWSKY <perl@shiar.org>
 106
 107 =head1 LICENSE
 108
 109 Licensed under the GNU Affero General Public License version 3.
 110