common.inc.plp

   1 <:
   2 use 5.014;
   3 use strict;
   4 use utf8;
   5 use warnings;
   6 no  warnings 'qw';  # you know what you doing
   7 no  warnings 'uninitialized';  # save some useless checks for more legible code
   8 use open ':std' => ':utf8';
   9
  10 use File::stat 'stat';
  11 use HTTP::Date;
  12 use Encode qw( decode_utf8 );
  13
  14 our $Dev;
  15
  16 sub Alert {
  17         my ($html, $debug) = @_;
  18         ref $html eq 'ARRAY' or $html = [$html];
  19         my ($title, @lines) = @{$html};
  20         my $body = "<h2>$title</h2>";
  21         $body .= "\n<p>$_</p>" for @lines;
  22         $body .= "\n<pre>$debug</pre>" if $Dev and $debug;
  23         say "<div class=error>$body</div>\n";
  24 }
  25
  26 sub Abort {
  27         my ($html, $code, $debug) = @_;
  28         unless ($PLP::sentheaders) {
  29                 $header{Status} = $code || 500;
  30         }
  31         elsif ($Dev) {
  32                 ref $html eq 'ARRAY' or $html = [$html];
  33                 push @{$html}, "Also failed to set HTTP status <q>$code</q>"
  34                         . " after output!";
  35         }
  36         Alert($html, $debug);
  37         exit;
  38 }
  39
  40 BEGIN {
  41         require Time::HiRes;
  42         our $Time = [Time::HiRes::gettimeofday()];
  43
  44         push @INC, '.';
  45
  46         # user request
  47         our $Dev = $ENV{HTTP_HOST} =~ /\bdev\./;
  48 }
  49
  50 our $Request //= decode_utf8($ENV{PATH_INFO} =~ s{^/}{}r);
  51
  52 our $style;
  53 our $showkeys //= !exists $get{keys} ? undef :
  54         ($get{keys} ne '0' && ($get{keys} || 'always'));
  55
  56 $header{content_type} = 'text/html; charset=utf-8';
  57
  58 sub stylesheet {
  59         my ($avail) = @_;
  60         my @avail = ref $avail eq 'ARRAY' ? @{$avail} : $avail or return;
  61         my %styles = map {$_ => $_} @avail;
  62
  63         if (defined( my $setstyle = $get{style} )) {
  64                 $style = $styles{ $setstyle };
  65                 eval {
  66                         require CGI::Cookie;
  67                         my $cookie = CGI::Cookie->new(
  68                                 -name    => 'style',
  69                                 -value   => $setstyle || '',
  70                                 -path    => '/',  # site-wide
  71                                 -expires => $setstyle ? '+5y' : '-1d',
  72                         ) or die "empty object returned\n";
  73                         AddCookie($cookie->as_string);
  74                 } or warn "Unable to create style cookie: $@";
  75         }
  76
  77         $style ||= exists $cookie{style} && $styles{ $cookie{style} } || $avail[0];
  78
  79         return map { sprintf(
  80                 '<link rel="%s" type="text/css" media="all" href="%s" title="%s">',
  81                 $_ eq $style ? 'stylesheet' : 'alternate stylesheet', "/$_.css?1.13", $_
  82         ) } @avail;
  83 }
  84
  85 sub checkmodified {
  86         my $lastmod = 0;
  87         for (@_) {
  88                 my $mod = stat $_ or next;
  89                 $mod = $mod->mtime or next;
  90                 $lastmod = $mod if $mod gt $lastmod;
  91         }
  92
  93         for ($ENV{HTTP_IF_MODIFIED_SINCE} || ()) {
  94                 next if str2time($_) < $lastmod;
  95                 $header{status} = '304 Same old';
  96                 exit;
  97         }
  98
  99         $header{'Last-Modified'} = time2str($lastmod);
 100 }
 101
 102 sub Data {
 103         my ($filename) = @_;
 104         my @data = eval {
 105                 open my $cache, '<:raw', "data/$filename.json"
 106                         or return do "./$filename.inc.pl"; # silent fallback to original code
 107                 require JSON;
 108                 local $/; # slurp
 109                 return JSON::decode_json(readline $cache);
 110         };
 111         if ($! or $@ or !@data or !$data[0]) {
 112                 die ['Table data not found', $@ || $!];
 113         }
 114         if (@data == 1 and ref $data[0] eq 'HASH' and not %{$data[0]}) {
 115                 die ['Table data missing'];
 116         }
 117         return wantarray ? @data : $data[0]; # list compatibility like do does
 118 }
 119
 120 sub Html {
 121         my ($meta) = @_;
 122
 123         unless ($meta->{nocache}) {
 124                 # announce and check data modification
 125                 checkmodified(
 126                         $ENV{SCRIPT_FILENAME},
 127                         (grep { /\bShiar_/ } values %INC),
 128                         $meta->{data} ? @{ $meta->{data} } : (),
 129                 );
 130                 $header{'Cache-Control'} = 'max-age='.(24*60*60);
 131         }
 132
 133         # default fallbacks
 134         $meta->{stylesheet} ||= [qw( light dark circus mono red )];
 135         $meta->{charset} ||= 'utf-8';
 136
 137         # convert options to arrays
 138         ref $_ eq 'ARRAY' or $_ = [$_]
 139                 for grep {$_} $meta->{raw}, $meta->{description}, $meta->{keywords};
 140
 141         # document headers before output
 142         $header{content_type} = "text/html; charset=$meta->{charset}"
 143                 unless $PLP::sentheaders;
 144         unshift @{ $meta->{raw} }, stylesheet($meta->{stylesheet});
 145
 146         push @{ $meta->{raw} }, (
 147                 '<link rel="stylesheet" type="text/css" media="monochrome" href="/mono.css?1.11" title="light">',
 148         );
 149
 150         # optional amends
 151         push @{ $meta->{raw} }, (
 152                 '<!--[if lte IE 6]><style> .help dl.legend dt {margin:0 0 1px} </style><![endif]-->',
 153                 '<!--[if lte IE 7]><style> .help dl.legend dd {float:none} </style><![endif]-->',
 154                 !$showkeys ? '<style> .no {visibility:hidden} </style>' :
 155                 $showkeys eq 'ghost' ? '<style> .no, .alias {opacity:.5} </style>' : (),
 156                 '<script type="text/javascript" src="/keys.js?1.6" async></script>',
 157         ) if $meta->{keys};
 158
 159         my ($file) = $ENV{SCRIPT_FILENAME} =~ m{ ([^/]+) \.plp$ }x;
 160
 161         PLP_START {
 162                 # leading output
 163                 say '<!DOCTYPE html>';
 164                 say '<html lang="en">';
 165                 say '';
 166                 say '<head>';
 167                 say sprintf '<meta http-equiv="content-type" content="%s">', $_
 168                         for $header{content_type};
 169                 say sprintf '<title>%s</title>', $meta->{title};
 170                 say sprintf '<meta name="description" content="%s">', EscapeHTML($_)
 171                         for join(' ', @{ $meta->{description} // [] }) || ();
 172                 say sprintf '<meta name="keywords" content="%s">', EscapeHTML($_)
 173                         for join(', ', @{ $meta->{keywords} // [] }) || ();
 174                 say '<meta name="viewport" content="width=device-width, initial-scale=1">';
 175                 say '<link rel="icon" type="image/png" href="/clip.png">';
 176                 say for map { @{$_} } $meta->{raw} || ();
 177                 say '<meta name="robots" content="noindex">' if $Dev;
 178                 say '</head>';
 179                 say '';
 180                 say sprintf '<body id="%s">', $file;
 181
 182                 # development version indicator
 183                 printf '<p style="%s">beta</p>', join('; ',
 184                         'position: fixed',
 185                         'right: 1em',
 186                         'opacity: .5',
 187                         'border: 1ex solid red',
 188                         'border-width: 1ex 0',
 189                         'z-index: 1',
 190                         'background: inherit',
 191                 ) if $Dev;
 192         };
 193
 194         # prepare trailing output
 195         PLP_END {
 196                 print <<"EOT";
 197 <p class="footer">
 198         <a href="/" rel="start">sheet.shiar.nl</a>/$file.<a href="/source/$file.plp"
 199          rel="source" title="Written in Perl">plp</a>
 200         version <a href="http://git.shiar.nl/sheet.git/history/HEAD:/$file.plp"
 201          rel="vcs-git" title="Git repository">$meta->{version}</a>
 202         created by <a href="http://shiar.nl/" rel="author">Shiar</a> •
 203         <a href="http://www.fsf.org/licensing/licenses/agpl-3.0.html"
 204          title="Licensed under the GNU Affero General Public License, version 3"
 205          rel="license">AGPLv3</a>
 206 EOT
 207                 our $Time;
 208                 say sprintf '• %.3fs', Time::HiRes::tv_interval($Time) if $Dev and $Time;
 209                 say '</p>';
 210                 say '';
 211                 say '</html>';
 212         };
 213 }
 214
 215 BEGIN {
 216         $PLP::ERROR = sub {
 217                 my ($message, $html) = @_;
 218                 if (ref $message) {
 219                         warn join ': ', @{$message};
 220                         $html = shift @{$message};
 221                 }
 222                 else {
 223                         warn $message;
 224                         $message = [];
 225                 }
 226                 unless ($PLP::sentheaders) {
 227                         Html({nocache => 1});
 228                         say '<h1>Page unavailable</h1>';
 229                 }
 230                 Alert("Fatal error: $html.", @{$message});
 231         };
 232 }
 233
 234 sub showlink {
 235         my ($title, $href, $selected) = @_;
 236         EscapeHTML($title);
 237         return $title if not $href;
 238         return "<strong>$title</strong>" if $selected;
 239         return sprintf '<a href="%s">%s</a>', EscapeHTML($href), $title;
 240 }
 241