t/50-cgi.t

   1 use strict;
   2 use warnings;
   3
   4 use Cwd qw(cwd);
   5 use Test::More;
   6
   7 eval { require PerlIO::scalar };
   8 plan skip_all => "PerlIO required (perl 5.8) to test PLP" if $@;
   9
  10 plan tests => 18;
  11
  12 require_ok('PLP::Backend::CGI') or BAIL_OUT();
  13
  14 $PLP::use_cache = 0 if $PLP::use_cache;
  15 #TODO: caching on (change file names)
  16
  17 my $base = -w '/tmp' ? '/tmp' : cwd();
  18 my $testfile = 'testfile.plp';
  19 not -f "$base/$testfile" or BAIL_OUT("$testfile exists");
  20
  21 open ORGOUT, '>&', STDOUT;
  22
  23 sub plp_is {
  24         my ($test, $plp, $expect) = @_;
  25         chomp $expect;
  26         local $Test::Builder::Level = $Test::Builder::Level + 1;
  27
  28         eval {
  29                 open my $testfh, '>', "$base/$testfile" or die $!;
  30                 print {$testfh} $plp or die $!;
  31                 close $testfh or die $!;
  32         };
  33         not $@ or fail("write $testfile"), diag("    Error: $@"), return;
  34
  35         close STDOUT;
  36         open STDOUT, '>', \my $output;  # STDOUT buffered to scalar
  37         eval {
  38                 local $SIG{__WARN__} = sub { print $_[0] }; # enables warnings
  39                 PLP::everything();
  40         };
  41         select ORGOUT;  # return to original STDOUT
  42
  43         not $@ or fail($test), diag("    Error: $@"), return;
  44         $output =~ s{((?:.+\n)*)}{ join "", sort split /(?<=\n)/, $1 }e; # order headers
  45         is($output, $expect, $test);
  46 }
  47
  48 %ENV = (
  49         REQUEST_METHOD => 'GET',
  50         REQUEST_URI => "/$testfile/test/123",
  51         QUERY_STRING => 'test=1&test=2',
  52         GATEWAY_INTERFACE => 'CGI/1.1',
  53
  54         SCRIPT_NAME => '/plp.cgi',
  55         SCRIPT_FILENAME => "$base/plp.cgi",
  56         PATH_INFO => "/$testfile/test/123",
  57         PATH_TRANSLATED => "$base/$testfile/test/123",
  58         DOCUMENT_ROOT => $base,
  59 ); # Apache/2.2.4 CGI environment
  60
  61 my $HEAD = <<EOT;  # common header output
  62 Content-Type: text/html
  63 X-PLP-Version: $PLP::VERSION
  64 EOT
  65
  66 plp_is('print', '0<: print print 2 :>3', "$HEAD\n0213");
  67
  68 plp_is('exit', '1<:exit:>not <(reached)>', "$HEAD\n1");
  69
  70 plp_is('<:=', '1<:=$foo=2:>3<:= $foo', "$HEAD\n1232");
  71
  72 plp_is('%get', '<: print $get{test} if defined $get{test} and not exists $get{test2}', "$HEAD\n2\n");
  73
  74 plp_is('%get array', '<:= @{$get{q/@test/}}', "$HEAD\n12\n");
  75
  76 plp_is('%header',
  77         '<: $headers{_test}=2; print $header{x_PLP_version}; BEGIN { $header{"-tesT"}=1 }',
  78         "-tesT: 2\n$HEAD\n$PLP::VERSION"
  79 );
  80
  81 plp_is('%header repetition', '.<: BEGIN{$header{A}="1\n2"} $header{A}=3', <<TEST);
  82 A: 1
  83 A: 2
  84 $HEAD
  85 .<table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>Can't set headers after sending them at testfile.plp line 1.
  86 (Output started at testfile.plp line 1.)
  87 </td></tr></table>
  88 TEST
  89
  90 #TODO: %post
  91 #TODO: %fields
  92 #TODO: %cookie
  93
  94 plp_is('PLP_END', '<: PLP_END{print 1}; PLP_END{print 2}; print 3', "$HEAD\n321");
  95
  96 plp_is('no warnings by default', '<: ignoreme :>ok', "$HEAD\nok");
  97
  98 rename "$base/$testfile", "$base/$testfile.inc";
  99 plp_is('include', "<($testfile.inc)> <: include '$testfile.inc'", "$HEAD\nok ok");
 100 unlink "$base/$testfile.inc";
 101
 102 plp_is('fatal error', "runtime\n<: syntax(error :>\nruntime", <<TEST);
 103 $HEAD
 104 <table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>syntax error at $testfile line 2, at EOF
 105   (Might be a runaway multi-line \cq\cq string starting on line 1)
 106 </td></tr></table>
 107 TEST
 108
 109 plp_is('warnings', split /\n\n/, <<TEST, 2);
 110 1
 111 <: use warnings :>
 112 2
 113 <: 42 :>
 114 3
 115 <: warn "warning" :>
 116 4
 117 <: include "missinginclude" :>
 118 5
 119 <(missinginclude)>
 120 6
 121
 122 $HEAD
 123 Useless use of a constant in void context at $testfile line 4.
 124 1
 125
 126 2
 127
 128 3
 129 warning at $testfile line 6.
 130
 131 4
 132 <table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>Can't open "$base/missinginclude" (No such file or directory) at $testfile line 8.
 133 </td></tr></table>
 134 5
 135 <table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>Can't open "$base/missinginclude" (No such file or directory) at $testfile line 10.
 136 </td></tr></table>
 137 TEST
 138
 139 plp_is('$PLP::ERROR',
 140         '<: $PLP::ERROR = sub {print "Oh no: $_[0]"} :> <(missinginclude)>.',
 141         qq{$HEAD\n Oh no: Can't open "$base/missinginclude" (No such file or directory) at $testfile line 1.\n\n}
 142 );
 143
 144 #TODO: 404
 145 #TODO: 403
 146
 147 plp_is('$PLP::DEBUG',
 148         '<: $PLP::DEBUG = 2; delete $header{x_plp_version} :>1<(missinginclude)>2',
 149         "Content-Type: text/plain\n\nContent-Type: text/html\n\n1"
 150 );
 151
 152 plp_is('utf8', '<: use open qw/:std :utf8/; print chr 191', <<TEST);
 153 Content-Type: text/html; charset=utf-8
 154 X-PLP-Version: $PLP::VERSION
 155
 156 \302\277
 157 TEST
 158
 159 my @envtest = (
 160         'ok <:=$ENV{SCRIPT_NAME}:> <:=$ENV{SCRIPT_FILENAME}',
 161         "$HEAD\nok /$testfile $base/$testfile"
 162 );
 163
 164 plp_is('%ENV (on apache)', @envtest);
 165
 166 %ENV = (
 167         REQUEST_METHOD => 'GET',
 168         REQUEST_URI => "/$testfile/test/123",
 169         QUERY_STRING => 'test=1&test=2',
 170         GATEWAY_INTERFACE => 'CGI/1.1',
 171
 172         SCRIPT_NAME => "/$testfile", #XXX: .plp?
 173         SCRIPT_FILENAME => "$base/$testfile",
 174         PATH_INFO => '/test/123',
 175 ); # lighttpd/1.4.7 CGI environment
 176
 177 plp_is('%ENV on lighttpd', @envtest);
 178
 179 unlink "$base/$testfile";
 180