t/50-cgi.t

   1 use strict;
   2 use warnings;
   3
   4 use Cwd;
   5 use File::Spec;
   6 use Test::More;
   7
   8 eval { require PerlIO::scalar };
   9 plan skip_all => "PerlIO required (perl 5.8) to test PLP" if $@;
  10
  11 plan tests => 20;
  12
  13 require_ok('PLP::Backend::CGI') or BAIL_OUT();
  14
  15 $PLP::use_cache = 0 if $PLP::use_cache;
  16 #TODO: caching on (change file names)
  17
  18 my $base = Cwd::abs_path(File::Spec->tmpdir || File::Spec->curdir);
  19 -w $base or BAIL_OUT("$base not writable");
  20 my $testfile = 'testfile.plp';
  21 not -f "$base/$testfile" or BAIL_OUT("$testfile exists");
  22
  23 open ORGOUT, '>&', *STDOUT;
  24
  25 sub plp_is {
  26         my ($test, $plp, $expect) = @_;
  27         chomp $expect;
  28         local $Test::Builder::Level = $Test::Builder::Level + 1;
  29
  30         if (defined $plp) {
  31                 eval {
  32                         open my $testfh, '>', "$base/$testfile" or die $!;
  33                         print {$testfh} $plp or die $!;
  34                         close $testfh or die $!;
  35                 };
  36                 not $@ or fail("write $testfile"), diag("    Error: $@"), return;
  37         }
  38
  39         close STDOUT;
  40         open STDOUT, '>', \my $output;  # STDOUT buffered to scalar
  41         select STDOUT;  # output before start() (which selects PLPOUT)
  42         eval {
  43                 local $SIG{__WARN__} = sub { print $_[0] }; # enables warnings
  44                 PLP::everything();
  45         };
  46         select ORGOUT;  # return to original STDOUT
  47
  48         not $@ or fail($test), diag("    Error: $@"), return;
  49         $output =~ s{((?:.+\n)*)}{ join "", sort split /(?<=\n)/, $1 }e; # order headers
  50         is($output, $expect, $test);
  51 }
  52
  53 sub getwarning {
  54         # captures the first warning produced by the given code string
  55         my ($code, $line, $file) = @_;
  56
  57         local $SIG{__WARN__} = sub { die @_ };
  58         # warnings module runs at BEGIN, so we need to use icky expression evals
  59         eval qq(# line $line "$file"\n$code; return);
  60         return $@;
  61 };
  62
  63 %ENV = (
  64         REQUEST_METHOD => 'GET',
  65         REQUEST_URI => "/$testfile/test/123",
  66         QUERY_STRING => 'test=1&test=2',
  67         GATEWAY_INTERFACE => 'CGI/1.1',
  68
  69         SCRIPT_NAME => '/plp.cgi',
  70         SCRIPT_FILENAME => "$base/plp.cgi",
  71         PATH_INFO => "/$testfile/test/123",
  72         PATH_TRANSLATED => "$base/$testfile/test/123",
  73         DOCUMENT_ROOT => $base,
  74 ); # Apache/2.2.4 CGI environment
  75
  76 my $HEAD = <<EOT;  # common header output
  77 Content-Type: text/html
  78 X-PLP-Version: $PLP::VERSION
  79 EOT
  80
  81 plp_is('print', '0<: print print 2 :>3', "$HEAD\n0213");
  82
  83 plp_is('exit', '1<:exit:>not <(reached)>', "$HEAD\n1");
  84
  85 plp_is('<:=', '1<:=$foo=2:>3<:= $foo', "$HEAD\n1232");
  86
  87 plp_is('%get', '<: print $get{test} if defined $get{test} and not exists $get{test2}', "$HEAD\n2\n");
  88
  89 plp_is('%get array', '<:= @{$get{q/@test/}}', "$HEAD\n12\n");
  90
  91 plp_is('%header',
  92         '<: $headers{_test}=2; print $header{x_PLP_version}; BEGIN { $header{"-tesT"}=1 }',
  93         "-tesT: 2\n$HEAD\n$PLP::VERSION"
  94 );
  95
  96 plp_is('%header repetition', '.<: BEGIN{$header{A}="1\n2"} $header{A}=3', <<TEST);
  97 A: 1
  98 A: 2
  99 $HEAD
 100 .<table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>Can't set headers after sending them at testfile.plp line 1.
 101 (Output started at testfile.plp line 1.)
 102 </td></tr></table>
 103 TEST
 104
 105 #TODO: %post
 106 #TODO: %fields
 107 #TODO: %cookie
 108
 109 plp_is('PLP_END', '<: PLP_END{print 1}; PLP_END{print 2}; print 3', "$HEAD\n321");
 110
 111 plp_is('no warnings by default', '<: ignoreme :>ok', "$HEAD\nok");
 112
 113 rename "$base/$testfile", "$base/$testfile.inc";
 114 plp_is('include', "<($testfile.inc)> <: include '$testfile.inc'", "$HEAD\nok ok");
 115 unlink "$base/$testfile.inc";
 116
 117 my $SYNTAXERR = getwarning("q\cq\n\cq; syntax(error", 1, $testfile);
 118 plp_is('fatal error', "runtime\n<: syntax(error :>\nruntime", <<TEST);
 119 $HEAD
 120 <table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>$SYNTAXERR</td></tr></table>
 121 TEST
 122
 123 SKIP: {
 124
 125 my $INCFILE = File::Spec->rel2abs("$base/missinginclude");
 126 if (open my $dummy, "<", $INCFILE) {  # like PLP::source will
 127         fail("file missinginclude shouldn't exist");
 128         skip("missinginclude tests", 2);
 129 }
 130 my $INCWARN = qq{Can't open "$INCFILE" ($!)};
 131
 132 my $VOIDWARN = getwarning('42', 2, $testfile);
 133
 134 plp_is('warnings', split /\n\n/, <<TEST, 2);
 135 1<: use warnings :>
 136 2<: 42 :>
 137 3<: warn "warning" :>
 138 4<: include "missinginclude" :>
 139 5<(missinginclude)>
 140 6
 141
 142 $HEAD
 143 ${VOIDWARN}1
 144 2
 145 3warning at $testfile line 3.
 146
 147 4<table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>$INCWARN at $testfile line 4.
 148 </td></tr></table>
 149 5<table border=1 class="PLPerror"><tr><td><b>Debug information:</b><br>$INCWARN at $testfile line 5.
 150 </td></tr></table>
 151 TEST
 152
 153 plp_is('$PLP::ERROR',
 154         '<: $PLP::ERROR = sub {print "Oh no: $_[0]"} :> <(missinginclude)>.',
 155         qq{$HEAD\n Oh no: $INCWARN at $testfile line 1.\n\n}
 156 );
 157
 158 plp_is('$PLP::DEBUG',
 159         '<: $PLP::DEBUG = 2; delete $header{x_plp_version} :>1<(missinginclude)>2',
 160         "Content-Type: text/plain\n\nContent-Type: text/html\n\n1"
 161 );
 162
 163 }
 164
 165 plp_is('utf8', '<: use open qw/:std :utf8/; print chr 191', <<TEST);
 166 Content-Type: text/html; charset=utf-8
 167 X-PLP-Version: $PLP::VERSION
 168
 169 \302\277
 170 TEST
 171
 172 my @envtest = (
 173         'ok <:=$ENV{SCRIPT_NAME}:> <:=$ENV{SCRIPT_FILENAME}',
 174         "$HEAD\nok /$testfile $base/$testfile"
 175 );
 176
 177 plp_is('%ENV (on apache)', @envtest);
 178
 179 SKIP: {
 180 chmod 0244, $testfile or skip("changed permissions", 1);
 181 plp_is('permission denied', undef, <<TEST);
 182 Content-Type: text/html
 183 PLP: Can't read: $base/$testfile (/$testfile/test/123)
 184 Status: 403
 185
 186 <!DOCTYPE HTML PUBLIC "-//IETF//DTD HTML 2.0//EN">
 187 <html><head>
 188 <title>403 Forbidden</title>
 189 </head></body>
 190 <h1>Forbidden</h1>
 191 You don't have permission to access /$testfile/test/123 on this server.<p>
 192 <hr>
 193 </body></html>
 194 TEST
 195 chmod 0644, $testfile;
 196 }
 197
 198 $ENV{PATH_TRANSLATED} = "$base/missinginclude/test/123";
 199 plp_is('not found', undef, <<TEST);
 200 Content-Type: text/html
 201 PLP: Not found: $base/missinginclude/test/123 (/$testfile/test/123)
 202 Status: 404
 203
 204 <!DOCTYPE HTML PUBLIC "-//IETF//DTD HTML 2.0//EN">
 205 <html><head>
 206 <title>404 Not Found</title>
 207 </head></body>
 208 <h1>Not Found</h1>
 209 The requested URL /$testfile/test/123 was not found on this server.<p>
 210 <hr>
 211 </body></html>
 212 TEST
 213
 214 %ENV = (
 215         REQUEST_METHOD => 'GET',
 216         REQUEST_URI => "/$testfile/test/123",
 217         QUERY_STRING => 'test=1&test=2',
 218         GATEWAY_INTERFACE => 'CGI/1.1',
 219
 220         SCRIPT_NAME => "/$testfile", #XXX: .plp?
 221         SCRIPT_FILENAME => "$base/$testfile",
 222         PATH_INFO => '/test/123',
 223 ); # lighttpd/1.4.7 CGI environment
 224
 225 plp_is('%ENV on lighttpd', @envtest);
 226
 227 unlink "$base/$testfile";
 228