bf4e04db592dabcf488ab9a2dfd5386bbd3a4668
[perl/list-index.git] / lib / List / Index.pm
1 package List::Index;
2
3 use 5.010;
4 use strict;
5 use warnings;
6
7 use Exporter 'import';
8
9 our $VERSION = '1.01';
10 our @EXPORT_OK = qw(rangematch);
11
12 sub new {
13         my ($class, $values) = @_;
14         bless [sort map { s/[^a-z]/./g; $_ } @$values], $class;
15 }
16
17 sub ranges {
18         my $self = shift;
19         my $options = shift || {};
20         my $pagesize = $options->{pagesize} || 50;
21         my $context  = $options->{context } // 1 + ($pagesize >> 4);
22         my $length   = $options->{length  } || 4;
23         my $pages    = $options->{pages   } || 1 + int $#$self / $pagesize;
24
25         $pagesize = @$self / $pages;
26         my $offset = $pagesize;
27         my @links = (['']);
28         while ($offset < @$self) {
29                 my $link = substr $self->[$offset], 0, $length;
30                 if ($context) {
31                         {
32                                 # take a value slightly before the current offset
33                                 my $before = $offset > $context ? $self->[$offset - $context] : '.';
34                                 # see how much of it matches the current link
35                                 my $trim = 1;
36                                 for my $match (split //, $before) {
37                                         scalar $link =~ /\G\Q$match/g or last;
38                                         $trim++;
39                                 }
40                                 # truncate link upto where the earlier value starts to differ
41                                 substr($link, $trim) = '' unless $trim > length $link;
42                         }
43
44                         if ($offset + $context < $#$self) {
45                                 # take a value after the current offset
46                                 my $after = $self->[$offset + $context];
47                                 # see how much of it matches the current link
48                                 my $trim = 1;
49                                 for my $match (split //, $after) {
50                                         scalar $link =~ /\G\Q$match/g or last;
51                                         $trim++;
52                                 }
53                                 # use this link if it's shorter
54                                 if ($trim < length $link) {
55                                         $link = substr $after, 0, $trim;
56                                 }
57                         }
58                 }
59
60                 push @links, [$link];
61                 $offset += $pagesize;
62         }
63
64         for my $i (0 .. $#links - 1) {
65                 my ($link, $lastchar) = $links[$i + 1]->[0] =~ /(.*)(.)/;
66                 $link .= $lastchar le 'a' ? '.' : chr( ord($lastchar) - 1 );
67                 next if $link eq $links[$i]->[0] and $i;
68                 $links[$i]->[1] = $link;
69         }
70         $links[-1]->[1] = '';
71
72         return \@links;
73 }
74
75 sub rangematch {
76         my ($link) = @_;
77         my ($s1, $s2) = $link =~ /([^-]*) - ([^-]*)/x
78                 or return qr/^\Q$link/i;
79         my @allow;
80
81         if (length $s1) {
82                 if (length $s2) {
83                         $s1 le $s2 or $s1 =~ /^\Q$s2/ or return undef;
84                 }
85
86                 my $prefix = '';
87                 my $char;
88                 for my $i (0 .. length($s1) - 1) {
89                         $char = substr $s1, $i, 1;
90                         my $next = $char;
91                         $next = chr( ord($char) + 1 ) if length $s1 > $i + 1;
92                         my $last = 'z';
93                         if (length $s2 > $i) {
94                                 if ($s2 =~ /^\Q$prefix/) {
95                                         $last = substr $s2, $i, 1;
96                                         next if $char eq $last;
97                                         $last = chr( ord($last) - (length $s2 > 1) );
98                                         next if $next gt $last;
99                                 }
100                         }
101                         push @allow, $prefix."[$next-$last]";
102                 }
103                 continue {
104                         $prefix .= $char;
105                 }
106         }
107
108         if (length $s2) {
109                 my $prefix = '';
110                 my $char;
111                 for my $i (0 .. length($s2) - 1) {
112                         $char = substr $s2, $i, 1;
113                         my $last = 'z';
114                         if (length $s1 > $i) {
115                                 my $c1 = substr $s1, $i, 1;
116                                 if ($s1 =~ /^\Q$prefix/) {
117                                         next if $c1 le $char;
118                                 }
119                         }
120                         push @allow, $prefix."(?![$char-$last])"
121                                 if $i or $s1 eq '';
122                 }
123                 continue {
124                         $prefix .= $char;
125                 }
126
127                 push @allow, $prefix
128                         if $s2 =~ /^\Q$prefix/ and $s1 le $s2
129                         and not (length $s2 == 1 && length $s1 >= length $s2 && $s1 ne $s2);
130         }
131
132         my $match = sprintf @allow <= 1 ? '%s' : '(?:%s)', join('|', @allow);
133         return qr/^$match/i;
134 }
135
136 1;
137
138 __END__
139
140 =head1 NAME
141
142 List::Index - Paginate alphabetic entries by finding minimal prefixes
143
144 =head1 SYNOPSIS
145
146         use List::Index;
147         my $index = List::Index->new(\@values);
148         my @pages = $index->ranges({pagesize => 50});
149         printf '<a href="?q=%s-%s">%1$s</a> ', @$_ for @pages;
150
151         use List::Index 'rangematch';
152         my $limit = rangematch('b-bmq');  # matches prefix like 'baa'..'bmq'
153         @results = grep { $limit } @results;
154
155 =head1 DESCRIPTION
156
157 TODO
158
159 =head1 SEE ALSO
160
161 L<List::Maker|List::Maker> for complex ranges of numeric lists.
162
163 =head1 AUTHOR
164
165 Mischa POSLAWSKY <perl@shiar.org>
166
167 =head1 LICENSE
168
169 Copyright. All rights reserved.
170