lib/List/Index.pm

   1 package List::Index;
   2
   3 use 5.010;
   4 use strict;
   5 use warnings;
   6
   7 use Exporter 'import';
   8
   9 our $VERSION = '1.01';
  10 our @EXPORT_OK = qw(rangematch);
  11
  12 sub new {
  13         my ($class, $values) = @_;
  14         bless [sort map { s/[^a-z]/./g; $_ } @$values], $class;
  15 }
  16
  17 sub ranges {
  18         my $self = shift;
  19         my $options = shift || {};
  20         my $pagesize = $options->{pagesize} || 50;
  21         my $context  = $options->{context } // 1 + ($pagesize >> 4);
  22         my $length   = $options->{length  } || 4;
  23         my $pages    = $options->{pages   } || 1 + int $#$self / $pagesize;
  24
  25         $pagesize = @$self / $pages;
  26         my $offset = 0;
  27         my @links;
  28         while ($offset < @$self) {
  29                 my $link = substr $self->[$offset], 0, $length;
  30                 if ($context) {
  31                         my $trim = 1;
  32                         my $before = $offset > $context ? $self->[$offset - $context] : '';
  33                         for my $match (split //, $before) {
  34                                 scalar $link =~ /\G\Q$match/g or last;
  35                                 $trim++;
  36                         }
  37                         substr($link, $trim) = '' unless $trim > length $link;
  38                 }
  39
  40                 push @links, [$link];
  41                 $offset += $pagesize;
  42         }
  43
  44         for my $i (0 .. $#links - 1) {
  45                 my ($link, $lastchar) = $links[$i + 1]->[0] =~ /(.*)(.)/;
  46                 $link .= $lastchar eq '.' ? 'z' : chr( ord($lastchar) - 1 )
  47                         unless $lastchar eq 'a';
  48                 $links[$i]->[1] = $link;
  49         }
  50         $links[-1]->[1] = '';
  51
  52         return \@links;
  53 }
  54
  55 sub rangematch {
  56         my ($link) = @_;
  57         my ($s1, $s2) = $link =~ /([^-]*) - ([^-]*)/x
  58                 or return qr/^\Q$link/i;
  59         my @allow;
  60
  61         if (length $s1) {
  62                 my $prefix = '';
  63                 my $char;
  64                 for my $i (0 .. length($s1) - 1) {
  65                         $char = substr $s1, $i, 1;
  66                         my $next = $char;
  67                         $next = chr( ord($char) + 1 ) if length $s1 > $i + 1;
  68                         my $last = 'z';
  69                         if (length $s2 > $i) {
  70                                 if ($s2 =~ /^\Q$prefix/) {
  71                                         $last = substr $s2, $i, 1;
  72                                         next if $char eq $last;
  73                                         $last = chr( ord($last) - (length $s2 > 1) );
  74                                         next if $next gt $last;
  75                                 }
  76                         }
  77                         push @allow, $prefix."[$next-$last]";
  78                 }
  79                 continue {
  80                         $prefix .= $char;
  81                 }
  82         }
  83
  84         if (length $s2) {
  85                 my $prefix = '';
  86                 my $char;
  87                 for my $i (0 .. length($s2) - 1) {
  88                         $char = substr $s2, $i, 1;
  89                         my $last = 'z';
  90                         if (length $s1 > $i) {
  91                                 my $c1 = substr $s1, $i, 1;
  92                                 if ($s1 =~ /^\Q$prefix/) {
  93                                         next if $c1 eq $char;
  94                                 }
  95                         }
  96                         push @allow, $prefix."(?![$char-$last])"
  97                                 if $i or $s1 eq '';
  98                 }
  99                 continue {
 100                         $prefix .= $char;
 101                 }
 102
 103                 push @allow, $prefix
 104                         if $s2 =~ /^\Q$prefix/ and $s1 le $s2
 105                         and not (length $s2 == 1 && length $s1 >= length $s2 && $s1 ne $s2);
 106         }
 107
 108         my $match = sprintf @allow <= 1 ? '%s' : '(?:%s)', join('|', @allow);
 109         return qr/^$match/i;
 110 }
 111
 112 1;
 113
 114 __END__
 115
 116 =head1 NAME
 117
 118 List::Index - Paginate alphabetic entries by finding minimal prefixes
 119
 120 =head1 SYNOPSIS
 121
 122         use List::Index;
 123         my $index = List::Index->new(\@values);
 124         my @pages = $index->ranges({pagesize => 50});
 125         printf '<a href="?q=%s-%s">%1$s</a> ', @$_ for @pages;
 126
 127         use List::Index 'rangematch';
 128         my $limit = rangematch('b-bmq');  # matches prefix like 'baa'..'bmq'
 129         @results = grep { $limit } @results;
 130
 131 =head1 DESCRIPTION
 132
 133 TODO
 134
 135 =head1 SEE ALSO
 136
 137 L<List::Maker|List::Maker> for complex ranges of numeric lists.
 138
 139 =head1 AUTHOR
 140
 141 Mischa POSLAWSKY <perl@shiar.org>
 142
 143 =head1 LICENSE
 144
 145 Copyright. All rights reserved.
 146