use utf8;

sub disptap {
	return map {
		m/\A(-?)(\d)(\d)/;
		sprintf('<small style="line-height:2ex">%s</small>&nbsp;',
			#TODO: prepend $1
			join "<br>\n", '•' x $2, '•' x $3,
		);
	} @_;
}

my %C = qw(red #EC1C24  blue #3953A3  yellow #F9EC31  black #231F20);

(
'Uppercase' => [qw{ A B C D E F G H I J K L M N O P Q R S T U V W X Y Z }],
'Lowercase' => [qw{ a b c d e f g h i j k l m n o p q r s t u v w x y z }],
'Sütterlin' => [qw{ a b c d e f g h i j k l m n o p q r ſ s t u v w x y z }],
'<abbr title="American Sign Lanugage">ASL</abbr>' => [
	# American manual alphabet in Sutton (U+1D800+) notation
	map { pack 'W*', map { hex "1D$_" } unpack '(A3)*', $_ } qw{
	8F7a9c    847a9c    86Da9c    801a9c    84Aa9c
	8CEa9c    8F0       815aa2    892a9c    892a9c9A2aac
	840a9c    8DCa9c    88Da9c
	819a9c    876a9c    840a9caA1 8F0a9caA1 81Aa9c
	903a9c    8FBa9c    815a9c    80Ea9c    887a9c
	806a9c    89Aa9c    800a9c945aaa
}],
'Braille' => [qw{ ⠁ ⠃ ⠉ ⠙ ⠑ ⠋ ⠛ ⠓ ⠊ ⠚ ⠅ ⠇ ⠍ ⠝ ⠕ ⠏ ⠟ ⠗ ⠎ ⠞ ⠥ ⠧ ⠺ ⠭ ⠽ ⠵ }],
'Morse' => [map {tr/.-/‧‑/r} qw{
	.- -... -.-. -.. . ..-. --. .... .. .--- -.- .-.. --
	-. --- .--. --.- .-. ... - ..- ...- .-- -..- -.-- --..
}],
'Tap code' => [disptap(qw{
	11 12 13 14 15 21 22 23 24 -24 25 31 32
	33 34 35 41 42 43 44 45 51 52 53 54 55
})],
'Tap simplified' => [disptap(qw{
	11 12 13 14 21 22 23 24 31 -31 -13 32 33
	34 41 42 -13 43 44 15 51 52 53 -25 -31 54
})],
'Maritime flags' => [
	# International Code of Signals, SVG fills
	map { '<svg width="20" height="20" viewBox="0 0 30 30">'.$_.'</svg>' }
	split /\n\n/, qq{
		<path fill="$C{blue}" d="M0,0 h30 l-7.5,15 7.5,15 h-30 z"/>
		<path fill="white" d="M0,0 h15 v30 h-15"/>

		<path fill="$C{red}" d="M0,0 h30 l-7.5,15 7.5,15 h-30 z"/>

		<path fill="$C{blue}" d="M0,0 h30v30 h-30z"/>
		<path fill="white" d="M0,6  h30 v18 h-30" />
		<path fill="$C{red}" d="M0,12 h30 v6  h-30" />

		<path fill="$C{yellow}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{blue}" d="M0,6 h30 v18 h-30"/>

		<path fill="$C{red}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{blue}" d="M0,0 h30 v15 h-30"/>

		<path fill="white" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{red}" d="M15,0 l15,15 -15,15 -15,-15"/>

		<path fill="$C{blue}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{yellow}" d="M 0,0 h5 v30 h-5"/>
		<path fill="$C{yellow}" d="M10,0 h5 v30 h-5"/>
		<path fill="$C{yellow}" d="M20,0 h5 v30 h-5"/>

		<path fill="$C{red}" d="M0,0 h30v30 h-30z"/>
		<path fill="white" d="M0,0 h15 v30 h-15"/>

		<path fill="$C{yellow}" d="M0,0 h30v30 h-30z"/>
		<circle fill="$C{black}" r="7.5" cx="15" cy="15"/>

		<path fill="$C{blue}" d="M0,0 h30v30 h-30z"/>
		<path fill="white" d="M0,10 h30 v10 h-30"/>

		<path fill="$C{blue}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{yellow}" d="M0,0 h15 v30 h-15"/>

		<path fill="$C{black}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{yellow}" d="M0,0 h15 v15 h-15 M15,15 h15 v15 h-15"/>

		<path fill="white" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{blue}" d="M4,0h22l-11,11 M4,30h22l-11,-11 M0,4v22l11,-11 M30,4v22l-11,-11"/>
		<!--path fill="$C{blue}" d="M3,0h24l-12,12 M3,30h24l-12,-12 M0,3v24l12,-12 M30,3v24l-12,-12"/-->

		<path fill="white" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{blue}" d="
			M0,0     h7.5v7.5h-7.5 m0,7.5h7.5v7.5h-7.5
			m7.5,-15 h7.5v7.5h-7.5 m0,7.5h7.5v7.5h-7.5
			m7.5,-30 h7.5v7.5h-7.5 m0,7.5h7.5v7.5h-7.5
			m7.5,-15 h7.5v7.5h-7.5 m0,7.5h7.5v7.5h-7.5
		"/>

		<path fill="$C{yellow}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{red}" d="M0,0 h30 v30"/>

		<path fill="$C{blue}" d="M0,0 h30v30 h-30z"/>
		<path fill="white" d="M10,10 h10 v10 h-10"/>

		<path fill="$C{yellow}" d="M0,0 h30v30 h-30z"/>

		<path fill="$C{red}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{yellow}" d="M12.5,0 v30 h5 v-30"/>
		<path fill="$C{yellow}" d="M0,12.5 h30 v5 h-30"/>

		<path fill="white" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{blue}" d="M10,10 h10 v10 h-10"/>

		<path fill="white" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{red}" d="M0,0 h10 v30 h-10"/>
		<path fill="$C{blue}" d="M20,0 h10 v30 h-10"/>

		<path fill="white" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{red}" d="M0,0 h15 v15 h-15 M15,15 h15 v15 h-15"/>

		<path fill="$C{red}" d="M0,0 h30v30 h-30z"/>
		<path fill="white" d="M4,0h22l-11,11 M4,30h22l-11,-11 M0,4v22l11,-11 M30,4v22l-11,-11"/>

		<path fill="$C{blue}" d="M0,0 h30v30 h-30z"/>
		<path fill="white" d="M5,5 h20 v20 h-20"/>
		<path fill="$C{red}" d="M10,10 h10 v10 h-10"/>

		<path fill="white" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{blue}" d="M12.5,0 v30 h5 v-30"/>
		<path fill="$C{blue}" d="M0,12.5 h30 v5 h-30"/>

		<path fill="$C{red}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{yellow}" d="M0,0h6l-6,6 M12,0h6l-18,18v-6 M24,0h6l-30,30v-6
			M30,6v6l-18,18h-6 M30,18v6l-6,6h-6"/>

		<path fill="$C{black}" d="M0,0 h30v30 h-30z"/>
		<path fill="$C{blue}" d="M30,0 v31 l-15,-15"/>
		<path fill="$C{yellow}" d="M0,0  h31 l-15,15"/>
		<path fill="$C{red}" d="M0,30 h31 l-15,-15"/>
	},
],
'Flag semaphore' => [
	map {
		local $_ = $_;
		s/[1-4]\K(?=[4-9])/ /;
		tr/1-9/↙←↖↑↗→↘↓/;
		s{(\S)(?=.)}{<span style="position:absolute">$1</span>};
		$_
	}
	qw(
		1 2 3 4 5  6 7 21 31 46  14 51 16 17 23
		24 25 26 27 34  35 47 56 57 36  67
	)
],
'Chappe semaphore' => [
	map {
		my ($r, $pr, $pl) = split //, $_;
		!$_ ? '-' : sprintf(
			join('',
				'<svg width="20" height="20" viewBox="0 0 10 15">',
				'<path stroke="currentColor" d="M5,6 v7"/>',
				'<path stroke="currentColor" fill="none" d="M0,%s h10 %s" transform="rotate(%d 5 6)"/>',
				'</svg>',
			),
			['6', '3v3', '9v-3']->[$pl],
			[ '',  'v3',  'v-3']->[$pr],
			$r * 45,
		);
	}
	# 360° rotation (0-7) and position state (0-2) of left and right bars
	qw(
	  021 121 221 321 421 521 621 721
	  022 022 122 222 322 011 111 211 311
	  001 101 201 301 401 501 601 701 020
	)
],
'Prussian semaphore' => [
	map { !$_ ? '-' : sprintf
		join('',
			'<svg width="20" height="20" viewBox="0 0 8 18">',
			'<path stroke="currentColor" d="M4,1 v18"/>',
			(map {(
				qq(<path stroke="currentColor" d="M0 $_ h4" transform="rotate(%d 4 $_)"/>),
				qq(<path stroke="currentColor" d="M4 $_ h4" transform="rotate(-%d 4 $_)"/>),
			)} 3, 7, 14),
			'</svg>',
		),
		map { ($_ - 2) * 45 % 360 } split //, $_
	}
	# rotation state (0-3) for left and right bar of 3 rows
	qw(
		003000 000200 203300 000030 033030 000130 000330 032330 031330 031330
		022020 130120 001320 233010 030210 022310 203001 233001
		131001 231301 000202 023302 230003 032003 201003 101003
	)
],
'Code 39' => [
	# ISO/IEC 16388
	map { tr/012/ ❘❙/r } qw(
		211012 121012 221011 112012 212011 122011 111022 211021 121021 112021
		211102 121102 221101 112102 212101 122101 111202 211201 121201 112201
		201112 102112 202111 101212 201211 102211
	)
],
'<abbr title="Royal Mail 4-State Customer Code">RM4SCC</abbr>' => [
	map { sprintf
		'<svg width="20" height="20" viewBox="0 0 8 6">'
		. '<path stroke="currentColor" d="M1%s"/></svg>',
		join ' m2',
		map { sprintf ',%dv%dm0,-%d',
			($_ & 1 ? 0 : 2),  2 + ($_ & 2) + ($_ & 1) * 2,
			($_ & 1 ? 0 : 2) + 2 + ($_ & 2) + ($_ & 1) * 2,
		}
		split //, $_
	}
	qw(
		                    2121 2301
		0132 0312 0330 2112 2130 2310
		1023 1203 1221 3003 3021 3201
		1032 1212 1230 3012 3030 3210
		1122 1302 1320 3102 3120 3300
	)
],
'Pigpen' => [
	map {
		qq(<svg width="12" height="12" viewBox="-.5 -.5 7 7">$_</svg>)
	}
	map {
		local $_ = $_;
		s/^H/mX,0/ or s/^V/m0,X/ or s/^/m0,0/;
		s/[hv]\K|X/6/g;
		s/(?:v|,[^0]).*?v\K/-/;
		s/(?:h|m[^0]).*?h\K/-/;
		m/h/ or s/v/l3,/g;
		m/v/ or s/h([^h]*)/l$1,3/g;
		my $dot = s/\.// && qq(<circle cx="3" cy="3" r="1">);
		qq(<path stroke="currentColor" stroke-linecap="square" fill="none" d="$_"/>$dot)
	}
	qw(
		Hvh  vhv  vh  hvh  vhvh  Hhvh  hv  Vvhv  Hhv
		Hvh. vhv. vh. hvh. vhvh. Hhvh. hv. Vvhv. Hhv.
		vv  hh  Hhh  Vvv
		vv. hh. Hhh. Vvv.
	),
],
'Nyctographs' => [
	map { s/M[\d,\hM]+(?=[M"])//gr }  # clean up superfluous moves
	map { sprintf
		'<svg width="14" height="14" viewBox="-.5 -.5 5 5">'
		. '<path%s d="M0,0%s %s4,0 %s4,4 %s0,4 %s0,0"/></svg>',
		' stroke="currentColor" stroke-linecap="round" stroke-linejoin="round" fill="none"',
		'h.5v.5h-.5v-.5',  # start anchor
		map { ['M', 'h0M', 'L']->[$_] }
		split //, $_
	}
	# draw style (0=empty, 1=dot, 2=line connect) to right, down, left, up
	qw(
		0010 0112 2022 2220 2000 2012 0122 0202 0020 0220 0012 0022 2202
		0222 2222 0102 0200 2201 2002 2200 0100 0110 0120 2001 2010 2020
	),
],
'Chromacons' => [
	# Colour Alphabet by Paul Green-Armytage (2010)
	map { sprintf '<span style="background:#%s" title="%s">%s</span>', split(/:/, $_), chr(8195) }
	qw{
		F0A3FF:Amethyst 0075DC:Blue      993F00:Caramel  4C005C:Damson   191919:Ebony
		005C31:Forest   2BCE48:Green     FFCC99:Honeydew 808080:Iron     94FFB5:Jade
		8F7C00:Khaki    9DCC00:Lime      C20088:Mallow
		003380:Navy     FFA405:Orpiment  FFA8BB:Pink     426600:Quagmire FF0010:Red
		5EF1F2:Sky      00998F:Turquoise E0FF66:Uranium  740AFF:Violet   990000:Wine
		FFFF80:Xanthin  FFFF00:Yellow    FF5005:Zinnia
	},
],
);
