perl.plp

   1 <(common.inc.plp)><:
   2
   3 Html({
   4         title => 'perl version cheat sheet',
   5         version => '1.6',
   6         keywords => [qw'
   7                 perl version feature features comparison
   8                 sheet cheat overview summary
   9         '],
  10         stylesheet => [qw'light dark red'],
  11         data => ['perl.inc.pl'],
  12 });
  13
  14 use experimental 'signatures';
  15 :>
  16 <h1>Perl release summary</h1>
  17
  18 <p>The most significant features introduced for recent versions of the Perl
  19 scripting language.
  20 <:
  21 my $info = Data('perl');
  22
  23 use feature 'signatures';
  24 sub vname ($v) {
  25         return sprintf 'v%d%03d', unpack 'C*', $v;
  26 }
  27 sub linkversion ($v) {
  28         return showlink(sprintf('%vd', $v), '#'.vname($v));
  29 }
  30
  31 eval {
  32         use List::Util 'first';
  33         use Time::Piece;
  34         use Time::Seconds;
  35
  36         my $now = Time::Piece->new;
  37         if (my $ts = $get{at}) {
  38                 $now = $now->strptime($ts, '%Y-%m-%d');
  39                 say "Compatibility details emulated for <em>$ts</em>.";
  40         }
  41         my $ts = $now->strftime('%F');
  42         my @versions = sort grep { $info->{$_}{release} le $ts } keys %{$info};
  43
  44         # perlpolicy: «We "officially" support the two most recent stable release
  45         # series. [...] we will attempt to fix critical issues»
  46         $info->{ $versions[-2] }{versum} //= "active core support";
  47         $info->{ $versions[-1] }{versum} //= "latest stable release";
  48
  49         # perlpolicy: «we will attempt to fix critical issues in the two most
  50         # recent stable 5.x release series»
  51         my $coreeol = ($now - ONE_YEAR * 3)->strftime('%F');
  52         my $vcore = first { $info->{$_}{release} ge $coreeol } @versions;
  53         print "<p>Core security support is provided for 3 years";
  54         print ", so typical users should run at least ", linkversion($_)
  55                 for $vcore // ();
  56         say '.';
  57         $info->{$vcore}{versum} //= "official security patches";
  58
  59         # «We encourage vendors to ship the most recent supported release of Perl
  60         # at the time of their code freeze»
  61         # assume debian ships after 1 year, and expires after 5 years LTS
  62         my $vendoreol = ($now - ONE_YEAR * 6)->strftime('%F');
  63         my $vdebian = first {
  64                 $info->{$_}{release} ge $vendoreol && $info->{$_}{distro}{debian}
  65         } @versions;
  66         say sprintf "Stable distributions such as Debian %s maintain %s+.",
  67                 $info->{$_}{distro}{debian}, linkversion($_) for $vdebian // ();
  68         $info->{$vdebian}{versum} //= "still maintained by common vendors";
  69
  70         # extended support given at random
  71         my $nowcmp = $now->strftime('%F');
  72         my $vdino = first { $info->{$_}{support} ge $nowcmp } @versions;
  73         say "Enterprise platforms retain versions up to $_."
  74                 for map { linkversion($_) } $vdino // ();
  75         return 1;
  76 } or Alert('Missing version recommendations', $@);
  77 say '</p>';
  78
  79 for my $vernum (reverse sort keys %{$info}) {
  80         my $verrow = $info->{$vernum};
  81         defined $verrow->{unstable} and next unless exists $get{v};
  82
  83         say sprintf '<div class="section" id="%s">', vname($vernum);
  84         my $title = $verrow->{release} // '?';
  85         $title .= ": $_" for $verrow->{versum} // ();
  86         say sprintf '<h2>%vd <small>%s</small></h2>', $vernum, $title;
  87         say '<dl>';
  88         for (@{ $verrow->{new} }) {
  89                 my ($topic, $desc, $attr) = @{$_};
  90                 $desc .= featattrs($attr);
  91                 my $ref = defined $attr->{name} && sprintf ' id="%s"', $attr->{name};
  92                 say sprintf '<dt%s>%s<dd>%s', $ref, $topic, $desc || '<br/>';
  93         }
  94         if (my $mods = $verrow->{modules}) {
  95                 for (@{$mods}) {
  96                         my ($name, $desc, $attr) = @{$_};
  97                         my $ref = lc $name =~ s/::/_/gr;
  98                         $desc .= featattrs($attr);
  99                         printf '<dt id="%s"><code>use %s</code>', $ref, $name;
 100                         say '<dd>', $desc;
 101                 }
 102         }
 103         say sprintf '<dt>Unicode</dt><dd>v%s', $_ for $verrow->{unicode} || ();
 104         say '</dl>';
 105         say "</div>\n";
 106 }
 107
 108 sub featattrs ($attr) {
 109         $attr or return '';
 110         ref $attr or $attr = {eg => $attr};
 111         my $title;
 112         if (defined $attr->{experimental}) {
 113                 $title = 'experimental';
 114         }
 115         if (defined $attr->{dropped}) {
 116                 return '' unless exists $get{v};
 117                 $title = sprintf 'removed in %vd', $_ for $attr->{dropped} || ();
 118         }
 119         elsif ($attr->{stable}) {
 120                 $title .= sprintf ' until %vd', $attr->{stable};
 121         }
 122         if ($attr->{experimental}) {
 123                 $title = sprintf '<span title="experimental::%s">%s</span>',
 124                         $attr->{experimental}, $title;
 125                 $attr->{name} //= $attr->{experimental};
 126         }
 127         if ($attr->{feature}) {
 128                 my $prefix = sprintf '<span title="%s">feature</span>',
 129                         $attr->{feature};
 130                 $title = join ', ', $prefix, $title // ();
 131                 $attr->{name} //= $attr->{feature};
 132         }
 133         $title = $title ? sprintf ' <em class="ex">(%s)</em>', $title : '';
 134
 135         if (my $eg = $attr->{eg}) {
 136                 my $pre = Entity($eg);
 137                 $pre =~ s<\N{ZERO WIDTH SPACE}>{</code><wbr/><code>}g;
 138                 $pre = " <small>{<code>$pre</code>}</small>";
 139                 $title = $pre . $title;
 140         }
 141         return $title;
 142 }