#!/usr/bin/env perl

use strict;
use warnings;
use Data::StarCraft::PvPGN::Report;
use Data::Dumper;

our $VERSION = '1.00';

our $DBG = 0;
our $TEST = 0;

use Getopt::Long qw(:config bundling auto_version auto_help);
GetOptions(
	"verbose|v!" => \$DBG,
	"test|t!" => \$TEST,
);

my $path = $ARGV[0] or die "Usage: $0 FILE\n";
my ($name) = $path =~ m{([^/]+)$};
my $report = Data::StarCraft::PvPGN::Report->open("$path.txt")
	or die "No report file: $!\n";
my $data = $report->head;
print Dumper $data if $DBG;

my $players = $report->players;
my %resultdelta = qw(WIN 1  DISCONNECT 0  DRAW 0  LOSS -1);
for (@$players) {
	defined $resultdelta{ $_->{result} }
		or die "Invalid player result '$_->{result}' for $_->{name}\n";
	$_->{delta} = $resultdelta{ $_->{result} };
}
print Dumper $players if $DBG;

my %placetxt = (
	bn => "bnet",
	gr => "groningen",
	md => "mdhq",
);
my ($placeid) = $name =~ /.*([a-z]{2})/;
my $place = $placetxt{$placeid} or die "Unknown place id: $placeid\n";
print "Resolved place '$placeid' to $place\n" if $DBG;

use Games::StarCraft::DB;
my $Db = Games::StarCraft::DB->connect
	or die "No database: $DBI::errstr\n";

$TEST and exit;

$Db->begin;

use Date::Parse;
my ($start, $end) = map str2time($data->{$_}), qw(started ended);
use Date::Format;
$Db->insert("game", {
	name => $name,
	place => $place,
	map => $data->{mapfile},
	type => $data->{type},
	start => time2str('%Y-%m-%d %X', $start),
	duration => sprintf('%d seconds', $end - $start),
})->rows or die "Game insert failed: ".$Db->error."\n";
my $gameid = $Db->last_insert_id((undef) x 4, {sequence => "game_id_seq"})
	or die "Couldn't find our game insertion: ".$Db->error."\n";
print "Game inserted as # $gameid\n";

$Db->insert("play", {
	game => $gameid,
	slot => $_,
	name => $players->[$_]->{name},
	account => $players->[$_]->{name},
	result => $players->[$_]->{delta},
	race => substr($players->[$_]->{race}, 0, 1),
})->rows or die "Player insert failed: ".$Db->error."\n"
	for 0 .. $#$players;

$Db->commit;