lib/HTML/Form/Simple.pm

   1 package HTML::Form::Simple;
   2
   3 use strict;
   4 use warnings;
   5
   6 use XML::Quote;
   7
   8 our $VERSION = '1.00';
   9
  10
  11 sub new {
  12         bless {}, $_[0];
  13 }
  14
  15 sub _attr {
  16         my $self = shift;
  17         my $expect = shift;
  18         my $attr = ref $_[-1] eq 'HASH' ? pop : {};
  19         push @_, undef for @_+1 .. $expect;
  20         push @_, $attr;
  21         return @_;
  22 }
  23
  24 sub quote {
  25         my $self = shift;
  26         return XML::Quote::xml_quote_min($_[0]);
  27 }
  28
  29 sub tag {
  30         my ($self, $tag, $attr) = @_;
  31
  32         # strip empty if it shouldn't be
  33         defined $attr->{$_} and $attr->{$_} eq '' and delete $attr->{$_}
  34                 for qw(id type class style);
  35
  36         my $return = '<' . $tag;
  37
  38         # add booleans
  39         delete $attr->{$_} and $return .= ' '.$_
  40                 for qw(selected checked disabled readonly);
  41
  42         $return .= sprintf ' %s="%s"', $_, $self->quote($attr->{$_})
  43                 for sort grep { defined $attr->{$_} } keys %$attr;
  44
  45         return $return . '>';
  46 }
  47
  48
  49 sub start {
  50         my ($self, $attr) = @_;
  51
  52         return $self->tag(form => $attr);
  53 }
  54
  55 sub stop {
  56         return '</form>';
  57 }
  58
  59
  60 sub submit {
  61         my $self = shift;
  62         my ($value, $attr) = $self->_attr(1, @_);
  63
  64         $attr->{value} = $value if defined $value;
  65         $attr->{type} = 'submit' unless defined $attr->{type};
  66
  67         return $self->tag(input => $attr);
  68 }
  69
  70 sub hidden {
  71         my $self = shift;
  72         my ($name, $value, $attr) = $self->_attr(2, @_);
  73
  74         if (ref $name eq 'HASH') {
  75                 my @return = map { $self->hidden($_, $name->{$_}, $attr) } sort keys %$name;
  76                 return wantarray ? @return : join(defined $, ? $, : '', @return);
  77         }
  78
  79         if (ref $value eq 'ARRAY') {
  80                 my @return = map { $self->hidden($name, $_, $attr) } @$value;
  81                 return wantarray ? @return : join(defined $, ? $, : '', @return);
  82         }
  83
  84         $attr->{name } = $name  if defined $name;
  85         $attr->{value} = $value if defined $value;
  86         $attr->{type} = 'hidden' unless defined $attr->{type};
  87
  88         return $self->tag(input => $attr);
  89 }
  90
  91 sub input {
  92         my $self = shift;
  93         my ($name, $value, $attr) = $self->_attr(2, @_);
  94
  95         $attr->{name } = $name  if defined $name;
  96         $attr->{value} = $value if defined $value;
  97         $attr->{id}   = $attr->{name} unless defined $attr->{id};
  98         $attr->{type} = 'text' unless defined $attr->{type} or defined $attr->{rows};
  99         $value = delete $attr->{value} if defined $attr->{rows};
 100
 101         return defined $attr->{rows} ? sprintf(
 102                 '%s%s</textarea>',
 103                 $self->tag(textarea => $attr),
 104                 $self->quote(defined $value ? $value : '')
 105         ) : $self->tag(input => $attr);
 106 }
 107
 108 sub select {
 109         my $self = shift;
 110         my ($name, $rows, $default, $attr) = $self->_attr(3, @_);
 111
 112         $default = $attr->{value} unless defined $default;
 113         delete $attr->{value};  # never a parent attribute
 114
 115         $attr->{name} = $name;
 116         $attr->{id}   = $attr->{name} unless defined $attr->{id};
 117         $attr->{type} = 'select' unless defined $attr->{type};
 118
 119         my @options = map { ref $_ ? $_ : {value => $_} } @$rows;
 120
 121         my @return;
 122
 123         if ($attr->{type} eq 'select') {
 124                 delete $attr->{type};
 125                 if (defined $default) {
 126                         for (@options) {
 127                                 $_->{selected} = 1 if defined $_->{value} and $_->{value} eq $default;
 128                         }
 129                 }
 130                 @return = (
 131                         $self->tag(select => $attr),
 132                         (map { $self->tag(option => $_) } @options),
 133                         '</select>',
 134                 );
 135         }
 136         else {
 137                 if (defined $attr->{id} and $attr->{id} ne '') {
 138                         defined $_->{id}
 139                                 or defined $_->{value} and $_->{id} = $attr->{id}.'_'.$_->{value}
 140                                         for @options;
 141                 }
 142                 if (defined $attr->{label}) {
 143                         defined $_->{value} and not defined $_->{label}
 144                                 and $_->{label} = $attr->{label}->{$_->{value}}
 145                                         for @options;
 146                         delete $attr->{label};
 147                 }
 148                 if (defined $default) {
 149                         for (@options) {
 150                                 $_->{checked} = 1 if defined $_->{value} and $_->{value} eq $default;
 151                         }
 152                 }
 153                 $_ = {%$attr, %$_} for @options;
 154                 @return = map {
 155                         my $label = delete $_->{label};
 156                         defined $label && $label ne ''
 157                                 ? '<label>'.$self->tag(input => $_)." $label</label>"
 158                                 :           $self->tag(input => $_)
 159                 } @options;
 160         }
 161
 162         return wantarray ? @return : join(defined $, ? $, : '', @return);
 163 }
 164
 165 sub radio {
 166         my $self = shift;
 167         my ($name, $label, $value, $attr) = $self->_attr(3, @_);
 168
 169         if (not defined $value) {
 170                 if (defined $label) {
 171                         $value = ref $label eq 'ARRAY' ? [1 .. $#$label+1] : [1];
 172                 }
 173                 else {
 174                         $value = [{}];
 175                 }
 176         }
 177         elsif (ref $value ne 'ARRAY') {
 178                 $value = [$value];
 179         }
 180
 181         if (defined $label) {
 182                 $_ = ref $_ eq 'HASH' ? {%$_} : {value => $_} for @$value;
 183                 $_->{label} = ref $label eq 'ARRAY' ? shift @$label : $label for @$value;
 184         }
 185
 186         $self->select($name, $value, {%$attr, type => 'radio'});
 187 }
 188
 189 sub check {
 190         my $self = shift;
 191         my ($name, $label, $checked, $attr) = $self->_attr(3, @_);
 192
 193         my $rows = defined $label ? ref $label eq 'ARRAY' ? $label : [$label] : [{}];
 194         ref $_ eq 'HASH' or $_ = {label => $_} for @$rows;
 195         if (defined $checked) {
 196                 if (ref $checked eq 'ARRAY') {
 197                         $_->{checked} = shift @$checked for @$rows;
 198                         push @$rows, map { {checked => $_} } @$checked;
 199                 }
 200                 else {
 201                         $_->{checked} = $checked for @$rows;
 202                 }
 203         }
 204         exists $rows->[$_]->{value} or $rows->[$_]->{value} = $_ + 1 for 0 .. $#$rows;
 205
 206         $self->select($name, $rows, {%$attr, type => 'checkbox'});
 207 }
 208
 209 1;
 210
 211 =head1 NAME
 212
 213 HTML::Form::Simple - Generate HTML form elements
 214
 215 =head1 SYNOPSIS
 216
 217         my $input = HTML::Form::Simple->new;
 218         say $input->start; # <form>
 219         printf "<label>%s: %s</label>\n", @$_ for (
 220                 [ 'Your Name' => $input->text(
 221                         user => 'Mr. Default'
 222                 ) ],
 223                 [ Message => $input->text(
 224                         msg => 'Textarea default', {rows => 4, style => 'background:red'}
 225                 ) ],
 226                 [ Gender => join ' or ', $input->radio(
 227                         sex => ['m', 'f']
 228                 ) ],
 229                 [ Colour => scalar $input->select(
 230                         favcolour => [qw(Blue Green Red)], 'Green'
 231                 ) ],
 232                 [ Options => $input->check(
 233                         spam => 'Receive weekly newsletter'
 234                 ) ],
 235         );
 236         say $input->stop; # </form>
 237
 238 =head1 AUTHOR
 239
 240 Mischa POSLAWSKY <perl@shiar.org>
 241
 242 =head1 LICENSE
 243
 244 This module is free software; you can redistribute it and/or modify it
 245 under the same L<terms|perlartistic> as Perl itself.
 246