;------------------------------------------------------------------------------
;---------------------- NEMESIS -----------------------------------------------
;------------------------------------------------------------------------------

; Title				: Nemesis
; Version			: 0.96
; Release Date			: 30.X.99
; Filename			: nemesis.86p (5kb)
; Author(s)			: Shiar
; Email Address			: shiar0@hotmail.com
; ICQ				; #43840958
; Web Page			: www.shiar.org
; Description			: cool arcade-shoot-em-up-game
; Where to get this game	: www.shiar.org | www.ticalc.org
; Other games by author		: Worm

; ABOUT:       This source should only be used for learning practises, do not
;	       alter it, and certainly do not distribute an altered version!!
; NOTE:				&&& marks uncertainties or things to optimize

;---------------------- nemesis.z80 start -----------------------------------

#include	"asm86.h"
#include	"ti86asm.inc"	;standard ti86 romcalls
#include	"ti86abs.inc"	;used to save hiscores and so

	.org _asm_exec_ram

#define		  cal	call	;just to make it harder for you to understand
#define		  psh	push	; ^:D
#define		  dnz	djnz	;Dec&Jump while NonZero becomes Do w.Non-Zero

TEXT_MEM	= _textShadow	;167 bytes ($A7): C0F9-C1A0
_clrWindow	= $4a86		;a new procedure from AsmStudio86 inc. files
_ex_ahl_bde	= $45f3
_shracc		= $4383
_dispahl	= $4a33
_asapvar	= $d6fc

storepos	= _asm_exec_ram+6000		;120 OF 165
storepos2	= _asm_exec_ram+6200		;141 OF 167

;---------------------- in-game vars ----------------------------------------

just_fired	= storepos+2		; +2	;counts how long a blast lasts
curline		= storepos+2		; +2	;used to display SFX
menuitem	= storepos+2		; +2	;used to store menu location
hiscorepos	= storepos+2		; +2
RanPos		= storepos+3		; +3	;used for making random values
timer		= storepos+4		; +4	;frame counter
						;--------YOU
x		= storepos+5		; +5	;your ship's position
y		= x+1			; +6	;your y-pos
firex		= y+1			; +7	;(1 byte)
firey		= firex+1		; +8	;(1 byte)
					; **
						;--------LEVEL
eventtime	= storepos+10		;+10	;enemy frequency
eventleft	= eventtime+1		;+11	;nr. of enemies still to come
nextevent	= eventleft+1		;+12	;time to next event
level_enemy	= nextevent+1		;+13	;enemy type
level_info	= level_enemy+1		;+14	;info (see below)
level_move	= level_info+1		;+15	;=
level_fire	= level_move+1		;+16
					; **
						;--------OBJECTS
spacespace	= storepos+19		;+19
groundinfo	= spacespace+1		;+20
groundpos	= groundinfo+1		;+21	$10
ceilingpos	= groundpos+16		;+37	$10
					; ^^	;--------STARS
stars1		= ceilingpos+16		;+53
stars2		= stars1+1		;+54
nrstars1	= 7
starx1		= storepos+55		;+55
nrstars2	= 7
starx2		= starx1+(nrstars1*2)	;+69
					; ^^	;--------MULTIPLES
mx		= starx2+(nrstars2*2)	;+83	;position of multiple#1
my		= mx+1			;+84	;multiple y-pos
m2x		= my+1			;+85
m2y		= m2x+1			;+86
your_locpos	= m2y+1			;+87	;position in your_prevpos tabl
your_prevpos	= your_locpos+1		;+88	;save previous positions (32d)

;^-----------------------------------<1	;-120=$78

enemies		= storepos2		;  +0	;info about each enemy
enemysize	= 7				;infobytes per enemy
nrenemies	= 16				;max. nr of enemies

ybullets	= enemies+(nrenemies*enemysize)	;60 bytes = 20(state,damg,x,y)
nrybuls		= 32			; +80\
ebullets	= ybullets+(nrybuls*4)	;+110	;30 bytes = 10(state,x,y)
nrebuls		= 16

ybuls		= ebullets+(nrebuls*3)	;+140
maxbullets = 32

;^-----------------------------------<2	;-141=$8D
;level_info:
;	[0000:damage 0:directfire 0:ground 0:ceiling 0:diagfire]
;enemies:
;	[HP64] [000000:HP left 00:(00=no enemy 01=exploding 10=normal 11=moving)]
;	[ship type or explosion frame] [x] [y] [move] [fire]

;---------------------- introduction ----------------------------------------

	 nop			;hello yas/ase/rascall/whathever
	 jp init		;here's the program, but first: a description
	.dw $0001		;description type 2 (description + YASicon)
	.dw Title		;pointer to description (all shells)
	.dw Icon		;pointer to YAS icon

Title:	.db "Nemesis v0.96 by Shiar",0

Icon:	.db 8,1			;icon for YAS: width = 1byte; height = 9bytes
	.db %11100000		; ███
	.db %01111000		;  ████
	.db %00111110		;   █████
	.db %01111001		;  ████  █
	.db %00111110		;   █████
	.db %01111000		;  ████
	.db %11100000		; ███		;recommend 80x50 screen mode
	.DB 0	;clear stupid YAS-line

;---------------------- init ------------------------------------------------

level_name: .db 8,"nemesis0"

int_handler:
	ex  af,af'
	in  a,($03)
	bit 3,a
	jp  z,$0039
	res 0,a
	out ($03),a
	jp  $0039
int_end:

init:	cal BUSY_OFF		;turns the run-indicator off, obviously
	cal _clrScrn		;clean the screen
	xor a			;ld a,0
	ld (iy+13),a		;don't affect TEXT_MEM and don't scroll screen
	cal _flushallmenus	;remove TI menus
	ld (_asapvar+1),a	;Asm( thinks it's the first time it runs Nems.

FixKeys:			;fixes some key problems like left+down bug
	im  1
	ld  a,$D4
	ld  bc,$0100
	ld  h,a
	ld  l,c			;ld hl,$D400
	ld  d,a
	ld  e,b			;ld de,$D401
	dec a			;ld a,$D3
	ld  (hl),a
	ldir
	ld  hl,int_handler
	ld  d,a
	ld  e,a			;ld de,$D3D3
	ld  bc,int_end-int_handler
	ldir
	inc a			;ld a,$D4
	ld  i,a
	im  2

;---------------------- main menu -------------------------------------------

LogoPut:
	xor a			;white bitmask (a=0)
	ld  hl,logo_nemesis	;from...
	ld  de,VIDEO_MEM+16	;...to one line from top
	ld  b,e			;ld b,16: one line
AboveLogo:
	ld  (de),a		;clear/n byte
	inc de			;next
	dnz AboveLogo		;repeat for the first line

	ld  bc,16*19		;logo size
	ldir			;display one line of logo

	ld  hl,VIDEO_MEM+(16*$39)+4	;$39 rows down, 4 cols right (4*8=$20)
	ld  b,8			;draw 8x one byte = 8*8 = 64 pixels wide
	ld  a,%11111111		;horizontal line mask
underline:
	ld  (hl),a		;draw one piece of the divider-line
	inc hl			;move right (8 pixels = 1 byte)
	dnz underline		;repeat

	set 3,(iy+5)		;set white on black
	ld  hl,$3320		;near the bottom of the screen
	ld  (_penCol),hl
	ld  hl,txt_about	;display version and author (yes, that's me!)
	cal _vputs		;useful procedure if you want to display somtn
	res 3,(iy+5)		;return to default black on white

	ld  hl,$3a1e		;below previous stuff
	ld  (_penCol),hl
	ld  hl,txt_email	;hey, my e-mail address so SEND ME SOMETHING!!
	cal _vputs		;VERY important, so display in small font ?:}

dispmenu:
	ld  de,$0304
	ld  (_curRow),de
	ld  hl,txt_menu1
	cal _puts
	ld  de,$0305
	ld  (_curRow),de
	ld  hl,txt_menu2
	cal _puts

	xor a
	ld  (menuitem),a

menuloop:
	ld  a,(menuitem)
	ld  h,$01
	add a,4
	ld  l,a

	ld  a,5
	ld  (_curRow),hl
	cal _putc

	ld  a,(menuitem)
	ld  h,$01
	sub 5
	neg
	ld  l,a

	ld  a,32
	ld  (_curRow),hl
	cal _putc

	halt \ halt

	cal GET_KEY		;wait for keypress
	cp  K_UP
	jr  z,menuchange
	cp  K_DOWN
	jr  z,menuchange
	cp  K_EXIT
	jp  z,game_over_nopop
	ld  hl,_invert
	cp  K_F1
	cal z,undo_invert
	cp  K_F2
	cal z,do_invert
	cp  K_ENTER
	jr  nz,menuloop

	ld  a,(menuitem)
	dec a
	jr  nz,startnewgame
	cal samelevel
	jr  game_main_loop

menuchange:
	ld  a,(menuitem)
	xor 1
	ld  (menuitem),a
	jr  menuloop

do_invert:
	ld  (hl),$2F ;cpl
	ret
undo_invert
	ld  (hl),$B7 ;or a
	ret

startnewgame:
	cal New_game

;----------------------------------------------------------------------------
;---------------------- game loop -------------------------------------------
;----------------------------------------------------------------------------

game_main_loop:			;REPEATS FROM HERE EVERY FRAME
	ld  hl,timer		;update time
	inc (hl)		;increase by 1
	ld  b,(hl)		;new time, save for rand# upd. (no flag change)
	jr  nz,updaterandom	;continue when new time <> 0
	ld  hl,1		;once every 256 frames, increase score by 1
	cal scoreInc		;do it

updaterandom:
	ld  hl,RanPos		;random counter
	ld  a,r			;add r register to randomize
	add a,(hl)		;add previous random value
	add a,b			;even more random by adding timer
	ld  (hl),a		;save even more random value back

Clear_screen:
	ld  hl,GRAPH_MEM	;move from (hl) = top left
	ld  (hl),$00		;first pixel will be copied all over the screen
	ld  de,GRAPH_MEM+1	;(de) = next pixel, thus clearing whole screen
	ld  bc,896		;loop 896 times = (128/8) * (64-8 for scorebar)
	ldir			;clear!

	ld  a,(timer)
	and %11
	jr  z,movestarsdone	;don't move stars once every 4 frames

	cal movestars1		;move the stars on the FRONT layer
	cal movestars2		;move the distant stars

movestarsdone:
	ld  a,(stars1)		;star positions (the missing byte...)
	ld  b,nrstars1		;how many stars? now we know.
	ld  hl,starx1		;points to the position of the stars
	cal DisplayStars	;display front layer stars

	ld  a,(stars2)		;weren't you paying attention five lines ago?
	ld  b,nrstars2		;that many?! whow!
	ld  hl,starx2		;and there they are
	cal DisplayStars	;use the same procedure to display back layer

	ld  a,(level_info)	;level info
	and %00000110		;isolate ground&ceiling
	jr  z,game_stuff	;both non-present
	and %00000010		;bit representing the presence of any ceiling
	cal nz,Handle_ceiling	;scroll the ceiling (if any)
	cal Handle_ground	;scroll the ground

game_stuff:
	ld  a,(your_occ)	;are you 100% OK?
	or  a			;a=0??
	jr  nz,_gamestuff1	;then don't check for movements/fires/...

	ld  a,(level_info)	;the same level info
	and %00000110		;isolate ground&ceiling again
	jr  z,check_keys	;no ceiling nor ground
	and %00000010		;this bit will tell us if there is a ceiling
	cal nz,CheckCeiling	;if there is, check it
	cal CheckGround		;check for collision with the ground

check_keys:
	ld  a,%10111111		;function keys (MORE,EXIT,2ND,F1,F2,F3,F4,F5)
	out (1),a		;ask for them
	nop \ nop		;delay 8 clocks
	in  a,(1)		;get zem!

check_exitkey:
	bit 6,a			;test bit 6 = exit-key = EXIT
	jp  z,game_over_nopop	;<exit> pressed, so be it
check_morekey:			;another unused label... poor compiler
	bit 7,a			;test bit 7 = more-key = PAUSE
	cal z,Pause		;yes, go to pause

check_firekey:
	bit 5,a			;test bit 5 = 2nd-key = FIRE
	ld  hl,check_selkey	;where to continue after executing Fire_bullet
	psh hl			;push hl on stack (instead of cal Fire_bullet)
	jp  z,Fire_bullet	;fire smtn (bulletstorplasermultiples+stuff..)
	pop hl			;no cal to Fire_bullet made, so pop stack
	xor a			;no:
	ld  (just_fired),a	;reset just_fired

check_selkey:
	ld  a,%01011111		;look at first column of keys (ALPHA to STO)
	out (1),a		;gimme
	nop \ nop		;what's taking you so long
	in  a,(1)		;at last... our precious keyzzz...

	bit 6,a			;'bout the GRAPH key...
	cal z,Teacher		;you didn't _press_ it, did you?!?

	rla			;test bit7 so we know f ALPHA has been pressed
	cal nc,select		;yeppy, select the currently selected upgrade

	cal Enemies_hit		;check for collision with enemies
	cal inc_weapdamage

_gamestuff1:
	cal Handle_Ship		;move you
	cal Handle_bullets	;move your bullets
	cal Handle_torp		;move your torpedo

	cal Handle_enemies	;move enemies
	cal Enemy_bullets	;move enemy bullets

	cal Level_event		;insert enemies
	cal Display_Screen	;display all
	halt			;delay

	jp  game_main_loop	;LOOP ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

inc_weapdamage:
	ld  a,0
weapincs =$-1
	inc a
	cp  31
	ret nc			;return if increased 16 times or more already
	ld  (weapincs),a

	ld  b,1
weapdamage =$-1
	add a,b

	ld  (curweapdamage),a
	ret

;--------------------------- ground -----------------------------------------

Handle_ground:
	ld  a,(timer)
	and %111		;once every 8 frames
	jr  nz,Display_ground	;otherwise skip the scroll
	ld  bc,15		;scroll all 16 bytes minus one (teh new byte)
	ld  hl,groundpos+1	;from..
	ld  de,groundpos	;to (one byte to the left)
	ldir			;LoaDIncreaseRepeat = scroll!

	ld  a,(groundinfo)	;what kind of ground
	dec a			;type 1:
	jr  z,ground_tunnel	;tunnel effect
	jr  ground_boring

ground_tunnel:
	ld  a,(groundpos+14)
	ld  (groundpos+15),a
	ld  hl,spacespace

	ld  a,(RanPos)
	ld  b,a
	bit 1,a
	jr  z,ground_previous
	bit 2,a
	jr  z,gtunneldown
gtunnelup:
	ld  a,(hl)
	or  a
	jr  z,ground_previous	;a>=0 (a=0 actually)
	inc (hl)
	ld  a,(groundpos+15)
	inc a
	jr  newground
gtunneldown:
	ld  a,(groundpos+15)
	dec a
	jr  z,ground_previous
	dec (hl)
	jr  newground

ground_previous:
	ld  a,(groundpos+14)	;type 1
	jr  newground
ground_boring:
	ld  a,(groundpos)	;type 0
newground:
	ld  (groundpos+15),a	;save new byte on the right
	ld  a,(hl)
	cp  -25
	jr  nc,Display_ground
	ld  a,b
	and %1
	ld  b,0
	jr  nz,gtunnelup

Display_ground:
	ld  b,16		;screen width
	ld  de,groundpos-1	;height of current byte (previous actually)
	psh de			;use later
	ld  hl,GRAPH_MEM+(56*16)-1 ;screen position
	psh hl

groundloopright:
	ld  c,b			;push b for groundloopup
	pop hl \ inc hl		;get screen position and go one right
	pop de \ inc de		;get height info and set to the next byte
	psh de \ psh hl		;save these for the next time
	ld  a,(de)		;height of current byte
	ld  b,a			;save in b

	ld  de,16		;to substract to go one line up
	ld  a,%11111111		;bitmask black
	or  a
groundloopup:
	ld  (hl),a		;display black byte
	sbc hl,de		;go up (sbc must be used for 16-bit sub)
	dnz groundloopup	;and loop >groundpos< times

	ld  b,c			;pop b used by groundloopup
	dnz groundloopright	;loop right for entire screen (16x)
	pop hl \ pop hl		;restore stack
	ret

CheckGround:			;check for collision with the ground
	ld  a,(x)
	srl a
	srl a
	srl a
	inc a
	ld  l,a
	ld  h,0
	ld  de,groundpos
	add hl,de
	ld  a,(y)
	sub 57-7
	neg
	cp  (hl)
	ret nc
	ld  b,5
	jp  damage_you

;--------------------------- ceiling ----------------------------------------

Handle_ceiling:
	ld  a,(timer)
	and %111		;once every 8 frames
	jr  nz,Display_ceiling	;otherwise skip the scroll
	ld  bc,15		;scroll all 15 bytes (16th is new position)
	ld  hl,ceilingpos+1	;from..
	ld  de,ceilingpos	;to (one byte to the left)
	ld  a,(de)		;load byte on left (will be lost after scroll)
	ldir			;LoaDIncreaseRepeat = scroll!

	ld  a,(groundinfo)	;what kind of ceiling
	dec a			;type 1:
	jr  z,ceiling_tunnel	;tunnel effect
	jr  ceiling_boring

ceiling_tunnel:
	ld  a,(ceilingpos+14)
	ld  (ceilingpos+15),a
	ld  hl,spacespace

	ld  a,(RanPos)
	ld  b,a
	bit 4,a
	jr  z,ceiling_previous
	bit 5,a
	jr  z,ctunnelup
ctunneldown:
	ld  a,(hl)
	or  a
	jr  z,ceiling_previous
	inc (hl)
	ld  a,(ceilingpos+15)
	inc a
	jr  newceiling
ctunnelup:
	ld  a,(ceilingpos+15)
	dec a
	jr  z,ceiling_previous
	dec (hl)
	jr  newceiling

ceiling_previous:
	ld  a,(ceilingpos+14)	;type 1
	jr  newceiling
ceiling_boring:
	ld  a,(ceilingpos)	;type 0
newceiling:
	ld  (ceilingpos+15),a	;save the new byte
	ld  a,(hl)
	cp  -25
	jr  nc,Display_ceiling
	ld  a,b
	and %1
	ld  b,0
	jr  nz,ctunneldown

Display_ceiling:
	ld  b,16		;screen width
	ld  de,ceilingpos-1	;height of current byte
	psh de			;use later
	ld  hl,GRAPH_MEM-17	;screen position
	psh hl

ceilingloopright:
	ld  c,b			;push b for groundloopup
	pop hl \ inc hl		;get screen position and go one right
	pop de \ inc de		;get height info and set to the next byte
	psh de \ psh hl		;save these for the next time
	ld  a,(de)		;height of current byte
	ld  b,a			;save in b

	ld  de,16		;to substract to go one line up
	ld  a,%11111111		;bitmask black
	or  a
ceilingloopdown:
	ld  (hl),a		;display black byte
	add hl,de		;go down
	dnz ceilingloopdown	;and loop >groundpos< times

	ld  b,c			;pop b used by groundloopup
	dnz ceilingloopright	;loop right for entire screen (16x)
	pop hl \ pop hl		;restore stack
	ret

CheckCeiling:			;check for collision with the ground
	ld  a,(x)		;your x
	srl a			;x/2
	srl a			;x/4
	srl a			;x/8 (current ceiling-byte)
	inc a			;correction

	ld  l,a			;hl = a
	ld  h,0			;"
	ld  de,ceilingpos	;first ceiling-byte
	add hl,de		;current ceiling-byte
	ld  a,(y)		;your y-pos
	inc a
	cp  (hl)		;compare with ceiling
	ret nc			;carry if ceiling is above you
	ld  b,5
	jp  damage_you		;otherwise you don't wanna be in that ship

;--------------------------- move stars -------------------------------------

DisplayStars:			;inputs: hl=starx# a=stars# b=nrstars#
	ld  e,(hl)
	inc hl
	ld  d,(hl)
	ld  (de),a
	inc hl
	dnz DisplayStars
	ret			;let's comment this: returns

movestars2:
	ld  ix,starx2
	ld  a,(stars2)
	rlca
	ld  (stars2),a
	ret nc
	ld  b,nrstars2
	jr  movestars_loop

movestars1:
	ld  ix,starx1
	ld  a,(timer)
	rra
	ld  a,(stars1)
	ret c
	rlca
	ld  (stars1),a
	ret nc
	ld  b,nrstars1

movestars_loop:
	ld  h,(ix+1)
	ld  l,(ix)
	dec hl

	ld  a,l
	and %00001111
	cp  9			;(GRAPH_MEM&%00001111)-- = $C9FAand15-1 = $A-1
	jr  nz,newstarok
	cal Random5016

newstarok:
	ld  (ix),l
	ld  (ix+1),h
	inc ix \ inc ix
	dnz movestars_loop
	ret			;for stupid people, here's another comment...

;--------------------------- pause ------------------------------------------

Pause:
	ld  hl,$0200		;top left
	ld  (_curRow),hl
	ld  hl,txt_pressenter	;"Enter to continue"
	cal _puts		;display message
pause:
	cal _getkey		;enter low-power mode and wait for key
	cp  kEnter		;keypressed = enter?
	jr  nz,pause		;no, wait some more
	ret			;continue

;--------------------------- teacher ----------------------------------------

Teacher:
	ld  (iy+12),5		;enable flashing cursor
	cal _clrScrn
	cal _homeup		;top left
	ld  hl,txt_teacher
	cal _puts		;display message

teacherloop:
	cal _getkey		;enter low-power mode and wait for key
	cp  kEnter		;enter pressed?
	jr  z,teacherans
	cp  kGrMenu		;keypressed = graph?
	jr  nz,teacherloop	;no, wait some more

	ld  (iy+12),0		;disable cursor
	jp  disp_icons		;+ret

teacherans:
	ld  a,' '
	cal _putc

	ld  hl,$0701
	ld  (_curRow),hl
	ld  hl,txt_teacherans
	cal _puts
	jr  teacherloop


;--------------------------- exit -------------------------------------------

quit:
	im  1			;release keyfix procedure
	ld  (iy+13),3		;use textshadow (TEXT_MEM) and scrolling

	ld  hl,GRAPH_MEM	;graph-screen location
	ld  de,GRAPH_MEM+1
	ld  (hl),0
	ld  bc,1024-1		;do it 1024 times = entire screen
	ldir

	jp  _clrWindow		;as _clrLCD but also clears TEXT_MEM (like the
				;_clrScrn) AND also executes _homeup and ret

;--------------------------- display ----------------------------------------

Display_Screen:
	ld  hl,GRAPH_MEM	;from storage (top left)
	ld  de,VIDEO_MEM	;to screen (top left)
	ld  c,56		;display height = 64 bytes (minus 8 for bar)
displayloop:
	ld  b,16		;display width = 16 bytes (16*8bits=256pixels)
displaytloop:
	ld  a,(hl)		;copy byte from (hl)
_invert:
	cpl                     ;xor $ff: invert byte (white<=>black)
	ld  (de),a		;to (de)
	inc hl \ inc de		;next byte
	dnz displaytloop	;16x hl >> de
	dec c			;next line
	jr  nz,displayloop	;loop 64x

	ld  hl,$396b		;Display Score
	ld  (_penCol),hl	;bottom right of screen
	ld  hl,(score)

_D_HL_DECI:			;------- display 5-digit value -------
	ld  de,savestr+4	;savenr saves number string
	ld  b,5			;five digits
ldhld:	cal UNPACK_HL		;one digit of hl
	add a,'0'		;make number
	ld  (de),a		;save into savenr
	dec de			;point to next digit
	dnz ldhld		;repeat for all digits

	ld  hl,savestr		;we (the program) saved the value righthere
	jp  _vputs		;the only thing left to do is to display it

savestr:			;@here the score will be stored
	.db "00000",0		;don't worry, it's just temporary

;------------------------- handle ship --------------------------------------

Handle_Ship:
	ld  a,(your_occ)	;are
	or  a			;you
	jr  z,ok		;ok?

	inc a			;no! next (explosion)frame
	ld  (your_occ),a	;save

	cp  34			;last explosion frame?
	jp  c,exploding_you	;not yet: display explosion
	cp  40			;delay finished?
	jp  z,You_die		;yes = game over
	ret			;don't display anything

ok:				;we are
	ld  a,%01111110		;get arrow keys
	out (1),a		;it's cold outside
	ld  hl,y		;instead of nop\nop do something usefull
	in  a,(1)		;come back in

	ld  b,a			;psh a (keys)
	xor %11111111		;inverted a = 0 if arrow-key has been pressed
	ld  a,(your_multiples)
	jr  z,no_adv		;if so, leave the multiples where they are
	or  %100		;set move bit
	jr  adv_ok
no_adv:	and %11111011		;reset move bit

adv_ok:	ld  (your_multiples),a

	ld  a,(timer)		;framecounter
	and %1			;switches 0<>1 each frame
	inc a			;a = 1 or 2 (1.5 avg)
	ld  c,a			;c = your_speed

	ld  a,b			;pop a (keys)
	rra			;rotate right (put last bit in c)
	ld  b,a			;we need a later

	jr  c,no_down
	ld  a,(hl)
	add a,c
	cp  50			;56-6 = bottom of screen
	jr  nc,no_down
	ld  (hl),a
no_down:
	dec hl
	rr  b			;because we now use b, it's rr instead of rra
	jr  c,no_left
	ld  a,(hl)
	sub c			;<dec a> doesn't affect c-flag
	jr  c,no_left		;-1 = left side
	ld  (hl),a
no_left:
	rr  b
	jr  c,no_right
	ld  a,(hl)
	add a,c
	cp  122			;128-6 = right side
	jr  nc,no_right
	ld  (hl),a
no_right:
	ld  d,(hl)
	inc hl
	rr  b
	jr  c,no_up
	ld  a,(hl)
	sub c			;<dec a> doesn't affect carry-flag
	jr  c,no_up		;-1 = top of screen
	ld  (hl),a		;save new y

no_up:	ld  e,(hl)
	ld  ix,spr_ship01	;ship sprite
	ld  hl,your_inv		;invulnerable?
	ld  a,(hl)		;load time in a
	or  a			;is it 0?
	jr  z,handle_multiples	;yes so ship = normal (display \ continue)

	ld  a,(timer)		;load frame nr.
	and %00000111		;a=0 once every four frames
	jr  nz,not_time		;a<>0 = not time to update counter
	dec (hl)		;decrease inv-time left
not_time:
	and %00000100		;a switches 0<->1 every 2 frames
	jr  z,handle_multiples	;show normal ship
inv_flicker:
	ld  ix,spr_ship01i	;don't display ship

handle_multiples:
	cal putsprite		;display your ship

	ld  a,(your_multiples)	;do you have multiples
	ld  b,a			;save a for 2nd check
	and %11			;no? (last two bits = nr of multiples)
	ret z			;then don't handle them either

	ld  hl,y
	ld  a,b			;restore a (your_multiples)
	and %100		;move the multiples???
	jr  z,mult_adv		;nope, just let them (saves (y) in y, (x) in x)

	ld  hl,your_locpos	;location to save this position
	ld  a,(hl)		;load a
	inc a			;a=a+1
	and %00001111		;if a>15 then a=a-16
	ld  (hl),a		;save new a
	add a,a			;a=a*2
	ld  c,a			;bc=2a
	ld  b,0

	ld  hl,your_prevpos	;previous positions
	add hl,bc		;16 turns ago
	ld  d,(hl)		;old x-pos
	inc hl			;and
	ld  e,(hl)		;old y-pos
	ld  (mx),de		;save multiple position in (mx)

	ld  a,(y)		;load new y-pos
	ld  (hl),a		;save it for 16 turns in the future
	dec hl			;and
	ld  a,(x)		;load new x-pos
	ld  (hl),a		;save that too

mult_adv:
 ld de,(mx)
	ld  ix,spr_multiple	;sprite of the multiple
	jp  putsprite		;display it + <ret>

exploding_you:
	srl a			;half the framerate
	dec a			;first frame is 1>inc>srl>dec = 0
	ld  hl,x-1

explosion_stuff:
	rra
	add a,a
	add a,a
	add a,a
	ld  c,a
	ld  b,0
	ld  ix,spr_explosion
	add ix,bc
	inc hl
	ld  d,(hl)
	inc hl
	ld  e,(hl)
	jp  putsprite

damage_you:			;damages you B points
	ld  a,(your_inv)	;invulnerability left?
	or  a
	ret nz			;return if inv>0
	ld  hl,your_armor	;armor left
	ld  a,(hl)		;load hp in A
	sub b			;decrease hp by B
	jp  m,no_armor		;<0hp left so explode
	ld  (hl),a		;no, so save decreased hp
	cal disp_armor		;and display new value

	ld  a,(your_pickup)	;how many pickups do you have?
	dec a			;is the armor-icon selected
	ret nz			;return if not

	psh de \ psh ix		;&&& just2Bsave
	ld  hl,VIDEO_MEM+(16*56)
	ld  (PutWhere),hl
	ld  ix,spr_icon		;if so, highlight armorIcon again
	ld  de,$1901		;position
	cal putwidesprite	;display icon
	ld  hl,GRAPH_MEM
	ld  (PutWhere),hl
	pop ix \ pop de
	ret			;and return

no_armor:
	ld  a,%01		;occ %xxxxxx01 = explode
	ld  (your_occ),a	;set to explode
	ret

;------------------------- place multiples ----------------------------------

Place_multiples:
	ld  (mx),de		;set last multiple-position
	ld  hl,your_prevpos	;place all previous positions
	ld  b,16		;all 16 of them
place_multiples:
	ld  (hl),d		;set prev-x to d
	inc hl			;next
	ld  (hl),e		;set prev-y to e
	inc hl			;next
	dnz place_multiples	;repeat
	ret

;------------------------- select upgrade -----------------------------------

select:
	ld  hl,your_pickup	;select pickups
	ld  a,(hl)		;load pickups taken so far
	dec a			;is it 1?
	ret m			;return if it's 0 (no pickups)
	jr  nz,select2		;no, carry on
select1:
	ld  a,(your_armor)	;load current armor
	cp  25-6		;may not become >=25
	jr  c,select1_		;ok then just add 6
	ld  a,25-6		;set to maximum (6 will be added below)
select1_:
	add a,6			;add 6 to armor
	ld  (your_armor),a	;change armor
	xor a			;ld a,0
	ld  (your_pickup),a	;reset pickups
	jp  disp_icons		;display and return
select2:
	dec a			;is it 2?
	jr  nz,select3		;no, carry on
	ld  (hl),a		;reset pickups
	inc a			;a=1
	ld  (torp_occ),a	;ready torpedoes
	jp  disp_icons		;display 'n return
select3:
	dec a			;is it 3?
	jr  nz,select4		;no, carry on
	ld  (hl),a		;reset pickups
	ld  hl,your_weapon
	ld  a,(hl)
	inc a
	cp  maxnrweapons
	jp  nc,disp_icons	;weapon maxed out
	ld  (hl),a		;set new weapon
        cal loadweapon		;load it (damage and stuff)
	jp  disp_icons		;display n return
select4:
	dec a			;is it 4?
	jr  nz,select5		;no, carry on again
	ld  (hl),a		;reset pickups
	inc a			;a=1
	ld  (your_weapon),a	;ready laser
	jp  disp_icons		;display + return
select5:
	dec a			;is it 5?
	jr  nz,select6		;no, carry on once more
	ld  (hl),a		;reset pickups
	inc a
	ld  (your_multiples),a
	ld  de,(x)
	cal Place_multiples
	jp  disp_icons		;display, return
select6:
	ld  (hl),0		;reset pickups
	jp  disp_icons		;display/return

;------------------------- fire bullet --------------------------------------

Fire_bullet:
	ld  hl,just_fired
	ld  a,(hl)		;just_fired
	cp  5			;already pressed?
	ret z			;return when already pressed (=5)

	inc (hl)		;otherwise increase counter (0 to 4 >> 1 to 5)
	ld  a,(your_weapon)	;if you have bullets.....
	dec a			;(1=laser)
	jr  z,fireOK
	ld  (hl),5		;.....then can't fire next turn (go to 5 imm.)

fireOK:
	ld  hl,(x)		;yes: first fire from ship position (x)
	ld  (firex),hl		;set firepos
	ld  a,(your_multiples)	;any multiples?
	and %11			;nope?
	jr  z,fireany		;then just fire somethin'
	cal fireany		;and blast
	ld  hl,(my)		;then, fire from multiple position (mx)
	ld  a,(mx)		;<ex h,l>
	ld  h,a			; ^^^^^^
	ld  (firex),hl		;set firepos
				;blast again and <ret>
fireany:
	cal fire_torp		;&&&

	ld  a,(your_weapon)	;do you have laser?
	dec a			;1=yes
	jr  z,fire_laser

	ld  ix,weapondata-6
	add a,a			;weap*2
	add a,a			;    *4
	add a,a			;    *8
	ld  c,a
	ld  b,0
	add ix,bc

	ld  c,(ix)
	cal fire_ybullet
	inc ix
	inc ix
	ld  c,(ix)
	xor a
	cp  c
	cal nz,fire_ybullet
	inc ix
	inc ix
	ld  c,(ix)
	xor a
	cp  c
	cal nz,fire_ybullet
	ret

fire_torp:
	ld  de,(firex)
	ld  hl,torp_occ		;torpedo...
	ld  a,(hl)		;load torpInfo
	dec a			;do you have (unused) torpedoes?
	ret nz			;nope (a must be 1)
	ld  (hl),2		;yes; use torpedo
	ld  (torp_pos),de	;save torpedo position (in de)
	ret


fire_laser:			;yes, fire that laser instead
	ld  a,(firex)		;a = your x-pos
	ld  d,a

	ld  hl,GRAPH_MEM	;save-location
	ld  a,(firey)		;y-coord
	add a,3			;at middle of your ship (y+3)
	ld  e,a			;save laser-y in e
	add a,a			;y*2
	add a,a			;y*4
	add a,a			;y*8
	rl  b			;b (=0) =b*2+overflow (if y>32 then bc=bc+256)
	add a,a			;y*16 (width of screen)
	rl  b			;b=b*2+overflow (if y>64 then bc=bc+512)
	inc a			;8 pixels to right (a=even so no overflow)

	srl d			;X/2
	srl d			;X/4
	srl d			;X/8
	add a,d			;a = (Y*16+X/8) mod 256 (c set on overflow)
	jr  nc,_nolc		;jump if no carry = no overflow = a<=255
	inc b			;a>255 so increase bc by 256
_nolc:	ld  c,a			;c = (Y*16+X/8) mod 256
	add hl,bc		;bc = Y*16+X/8

	ld  a,15		;128/8=16=screen width ** minus one (inc a ^^)
	sub d			;minus x-start (d=X/8)
	ld  b,a
drawlaser:
	ld  (hl),%11111111
	inc hl			;Go to next byte
	dnz drawlaser

;	ld  a,(just_fired)	;fired for how long
;	cp  4			;if 4th turn
;	ret nz			;then do damage, otherwise quit

handle_laser:
	ld  a,(firex)
	ld  d,a			;d was divided, so reload the laser-x

check_laserhits:		;de = (x,y)
	ld  b,nrenemies
	ld  hl,enemies+1

laserhits:			;Hits with normal enemies
	psh hl

	ld  a,(hl)
	and %00000010
	jr  z,nolashit		;no hit when enemy_occ <> 2/3

	inc hl			;enemy type
	ld  a,(hl)
	or  a			;enemy #0 = pickup
	jr  z,nolashit		;yes: don't destroy

	inc hl
	ld  a,(hl)		;check x
	sub d
	jp  m,nolashit		;no hit when enemy is left of you

	inc hl
	ld  a,(hl)		;check y
	sub e
	jr  z,enemy_lashit	;a-e=0 = laser on top line of enemy = hit
	jr  nc,nolashit		;a-e>0 = enemy above laser = no hit
	add a,5			;add enemy height
	jp  p,enemy_lashit	;a-e>0 = hit

nolashit:
	pop hl
	ld  a,b			;psh bc
	ld  bc,enemysize
	add hl,bc		;go to next enemy
	ld  b,a			;pop bc
	dnz laserhits		;check all enemies
	ret

enemy_lashit: ;&&&before nolashit
	ld  a,1			;damage
	cal enemy_hit
	jr  nolashit

fire_ybullet:
	ld  hl,ybullets
	ld  de,4
	ld  b,maxbullets
find_ybullet:
	ld  a,(hl)
	or  a
	jr  z,found_ybullet	;0 = no bullet here
	add hl,de
	dnz find_ybullet	;look next bullet
	pop hl			;don't try to fire any other bullets
	ret			;so ret twice

found_ybullet:
	ld  (hl),c		;use the bullet and set correct bullet-type
	inc hl			;@damage
	ld  (hl),1		;set bullet damage
curweapdamage =$-1
	ld  a,(firex)		;your x-pos
	add a,5			;place bullet in front of you
	inc hl			;go to bullet-x
	ld  (hl),a		;set x

	ld  a,(firey)		;your y-pos
	add a,(ix+1)		;place bullet at the middle of your ship
	inc hl			;go to bullet-y
	ld  (hl),a		;set y

	xor a
	ld  (weapincs),a	;reset damage
	ret

;------------------------ handle bullets ------------------------------------

bullet_left:
	ld  a,124
	sub b

	cp  (hl)		;off screen? (x>128-5)
	jr  c,remove_bullet
	ld  a,(hl)		;a = X
	add a,b			;move b to the right
	ld  (hl),a		;save new pos.
	ld  d,a			;d = X

	inc hl			;@y-pos
	ld  a,c
	cal _shracc
	dec a
	jr  z,bullet_noymove
	dec a
	jr  z,bullet_up
	dec a
	jr  z,bullet_halfup
	dec a
	jr  z,bullet_down

bullet_halfdown:
	ld  a,(timer)
	and 1
	jr  z,bullet_noymove
bullet_down:
	ld  a,(hl)
	inc a
	cp  55
	jr  z,bullet_noymove
	ld  (hl),a
bullet_halfup:
	ld  a,(timer)
	and 1
	jr  z,bullet_noymove
bullet_up:
	ld  a,(hl)
	dec a
	jr  z,bullet_noymove
	ld  (hl),a
bullet_noymove:
	ld  e,(hl)		;e = Y
	ret

remove_bullet:
	pop hl			;cal bullet_left
	pop hl			;enemy+type
	ld  (hl),0		;dump this bullet!
	jr  next_ybullet+1	;+1:skip pop hl at next_ybullet

Handle_bullets:
	ld  hl,ybullets
	ld  b,maxbullets
scan_bullets:
	psh bc			;bullet counter
	psh hl			;save enemy+type
	ld  (temp1),hl		;needed for check_bullethits
	ld  a,(hl)		;@bulletType
	inc hl			;@damage
	inc hl			;@x

	or  a
	jp  z,next_ybullet	;bulletType=0 >> no bullet

	ld  c,a			;c=type
	and %1111
	ld  b,a			;b=0000type
	cal bullet_left		;move bullet left

display_bullet:
	psh de			;save de =position
	dec hl			;@x
	dec hl			;@damage
	ld  a,(hl)		;bullet damage=size
	ld  hl,XLbullettable	;pointer to first bullet
	srl a
	srl a			;per 4
	inc a			;must be at least 1
nextbulletlook:
	inc hl			;next bullet sprite pointer
	dec a			;for each 4 points of damage
	jr  nz,nextbulletlook
	ld  d,a			;ld d,0
	ld  a,(hl)		;load pointer offset
	ld  e,a			;convert to 16bit
	ld  ix,spr_bullet01	;first sprite
	add ix,de		;add offset (go to correct sprite)
 	pop de			;saved position
	psh de			;but will be altered so save again
	cal putsprite		;display bullet
	pop de

	cal check_bullethits

next_ybullet:
	pop hl			;restore enemy+type
	inc hl
	inc hl
	inc hl
	inc hl			;skip type,dam,x,y: next enemy+type
	pop bc			;b=counter
	dnz scan_bullets	;next bullet (loop)
	ret

;--------------------------- check bullethits -------------------------------

check_bullethits:		;INPUT: de=X,Y; (temp1)=bullet
	ld  b,nrenemies
	ld  hl,enemies+1

hit_enemies:			;Hits with normal enemies
	psh bc			;enemy counter
	psh hl

	ld  a,(hl)
	and %00000010
	jr  z,nohit		;no hit when enemy_occ <> 2/3

	inc hl			;enemy type
	ld  a,(hl)
	or  a			;enemy #0 = pickup
	jr  z,nohit		;yes: don't destroy

	psh de
	cal find_sprite
	pop de

	inc hl
	ld  a,(hl)		;check x
	sub d
	sub 5
	jp  p,nohit
	add a,5
	add a,(ix)
	jp  m,nohit

	inc hl
	ld  a,(hl)		;check y
	sub e
	sub 3
	jp  p,nohit
	add a,3
	add a,(ix+1)
	jp  m,nohit

	psh hl
	ld  hl,0		;@bulletType
temp1 =$-2
	ld  (hl),0		;remove bullet
	inc hl			;@damage
	ld  a,(hl)		;set damage
	pop hl			;enemy+y
	cal enemy_hit
nohit:
	pop hl
	ld  bc,enemysize
	add hl,bc
	pop bc
	dnz hit_enemies	;check next enemy
	ret

enemy_hit:		;in:a=damage;hl=enemy+y
	add a,a			;a=damage to inflict
	add a,a			;first 2 bits used for occ.
	ld  b,a

	dec hl			;@x
	dec hl			;@type
	dec hl			;@hp00 (occ)
	ld  a,(hl)		;load hp00
	sub b			;decrease HP (if <0xx then c is set)
	ld  (hl),a		;save (no flag-changes)
	dec hl			;@hp64; no change in c
	ld  a,(hl)		;load; no c-change
	sbc a,0			;if cf then decrease a
	ld  (hl),a		;save back the new value
	ret nc			;if a>=0 then return, otherwise explode

	inc hl			;goto occ again
	ld  (hl),%01		;set to explode
	ld  a,(pickuptimer)	;counts enemies destroyed
	dec a			;enough destroyed for a pickup?
	jr  nz,pickupdone	;otherwise just explode
	ld  (hl),%110		;change it into a pickup (with 2 HP)
	ld  a,18		;reset enemies counter (18 hits = next)
pickupdone:
	ld  (pickuptimer),a	;save new enemiescounter value
	inc hl
	ld  (hl),$00		;explosionFrame 0

	ld  hl,1		;increase score by one
	jp  scoreInc		;+ret

;--------------------------- handle torpedo ---------------------------------

Handle_torp:
	ld  a,(torp_occ)
	sub 2
	ret m			;return if occ=0/1

	ld  hl,torp_pos		;x-position
	ld  a,(hl)		;load in a
	inc a			;move right
	cp  125			;right edge reached
	jr  nc,remove_torp	;remove if x>125
	ld  (hl),a		;save new x
	ld  d,a

	inc hl			;y-position
	ld  a,(hl)
	inc a			;move down
	cp  56			;bottom reached
	jr  nc,remove_torp	;remove if y>40
	ld  (hl),a		;save new y
	ld  e,a

	ld  ix,spr_bullett1
	psh de
	cal putsprite		;display torpedo
	pop de
	jp  check_bullethits	;check for hits with enemies

remove_torp:
	ld  a,1
	ld  (torp_occ),a
	ret

;--------------------------- level events -----------------------------------

Level_event:
	ld  hl,nextevent	;time to next event	<ld  a,(nextevent)
	dec (hl)		;decrease counter	<dec a
	ld  a,(hl)		;look at counter	<ld  (nextevent),a
	or  a			;has it reached zero?
	ret nz			;nope: get outta here!

	ld  a,(eventtime)	;enemy frequency (lvl)
	ld  (nextevent),a	;set time to next event
	ld  hl,eventleft
	dec (hl)		;update enemy-counter

	ld  a,(hl)		;look at counter
	or  a			;has it reached 0?
	jp  z,Next_level	;yes: level finished
	dec a			;has it reached 1?
	jr  z,standby_event	;yes: wait until no enemies present/left
	dec a			;has it reached 2?
	jr  z,place_boss	;yep: place the BigBossTM!
	dec a			;has it reached 3?
	jr  nz,do_event		;nope: >3 = place an enemy
	inc hl			;nextevent located behind eventleft
	ld  (hl),123		;set delay
	ret			;don't place any more enemies

place_boss:
	ld  hl,(levelp)		;the leveldata (including the boss)
	dec hl			;points to leveldata\boss\enemynr
	ld  a,(hl)		;load it
	ld  (level_enemy),a	;set new enemy (boss)
	dec hl			;points to level\boss\movement
	ld  a,(hl)		;load
	ld  (level_move),a	;set boss movement
	dec hl			;@level\boss\firefreq
	ld  a,(hl)		;load in a
	ld  (level_fire),a	;set firefrequency
	jp  do_event		;+ret

standby_event:
	ld  b,nrenemies
	ld  hl,enemies+1-enemysize
	ld  de,enemysize
chk_enemyleft:
	add hl,de
	ld  a,(hl)
	or  a			;0 = no enemy present
	jr  nz,enemyleft
	dnz chk_enemyleft
	ret
enemyleft:
	ld  hl,eventleft
	inc (hl)
	ret


do_event:
	ld  hl,enemies+1-enemysize
	ld  bc,enemysize
	xor a			;a=0
chk_noenemy:
	add hl,bc
	cp  (hl)		;(hl) = 0 ??
	jr  nz,chk_noenemy	;jump if enemy present (non-0)
	ex  de,hl		;de=hl=usable enemy

place_enemy:
	ld  a,(level_enemy)	;enemy type to place (lvl)
	ld  hl,XLenemyinfos-4	;enemy "0" specs (1 before enemy #1)
	add a,a			;a=type*2
	add a,a			;a=type*4
	ld  c,a			;c=type
	ld  b,0			;bc = enemy nr.&&&XX
	add hl,bc		;hl = enemy specs
	ld  a,(hl)		;load hitpoints+occ of this enemy class
	ld  (de),a		;save occ

	inc hl			;next enemyInfo byte
	dec de			;goto hp
	ld  a,(hl)		;load hp64
	ld  (de),a		;save hp64
	inc de			;next byte (or previous): occ again

	inc hl			;next enemyInfo byte
	inc de			;next byte of current enemy
	ld  a,(hl)		;load enemy class (nr)
	ld  (de),a		;save enemy type

	inc de			;set x-pos
	psh de
	cal find_sprite
	pop de
	ld  a,128		;appear at right edge of screen
	sub (ix)		;minus the width of this enemy (not offscreen)
	ld  (de),a		;= x-position (save)

	inc de			;set y-pos
	inc hl			;where to place??
	ld  a,(hl)		;load placeInfo
	dec a			;is it 1?
	jr  z,random_enemy	;yes: create random value <51 in a
	dec a			;is it 2?
	jr  z,lure_enemy	;yes: create a 100% luring enemy
				;otherwise?
halflure_enemy:			;yes (of course it is): pick one (50% lure)
	ld  a,(timer)		;look at frame-number
	and %00000001		;make random if odd frame nr.
	jr  nz,random_enemy	;1st possibility: random enemy
lure_enemy:			;2nd possibility: luring enemy
	ld  a,(y)		;place at same y-pos as YOUR ship
	jr  ypos_OK

random_enemy:
	ld  b,e			;b will be added to random-value
	cal Random50		;make a (in a) random value 0-51

ypos_OK:			;random value successfully created
	ld  (de),a		;save y-position

	inc de			;set move
	ld  a,1			;movecounter = 1
	ld  (de),a		;&&&(hl),1 better?

	inc de			;set fire
	ld  a,(level_info)
	and %00000001		;bit meaning directfire
	jr  nz,ffireOK		;(a=time-to-fire) = 1 frame (fires directly)
	ld  a,(level_fire)	;set ttf to normal nr of frames
ffireOK:ld  (de),a		;save fire
	ret			;return

;--------------------------- enemy fires ------------------------------------

Enemy_fires:			;de = x,y
	dec d
	dec d			;d = x-2
	inc e			;e = y+1

	ld  b,nrebuls
	ld  hl,ebullets
find_ebullet:
	ld  a,(hl)
	or  a
	jr  z,found_ebullet	;0 = not used
	inc hl \ inc hl \ inc hl
	dnz find_ebullet	;look next bullet
	ret

found_ebullet:
	ld  b,%1100
	ld  a,(level_info)
	and %00001000
	jr  z,bulletok

	ld  a,(y)
	sub e
	add a,10
	jp  p,bulletnotup
	ld  b,%1011		;yourY-bulY = negative (=bullet below you)
	add a,10
	jp  p,bulletnotup
	ld  b,%1001		;yourY-bulY = even more negative (going up)

bulletnotup:
	sub 20
	jp  m,bulletok
	ld  b,%1010		;bullet going down
	sub 10
	jp  m,bulletok		;even more going down
	ld  b,%1000

bulletok:
	ld  a,(level_info)
	and %11110000
	or  b
	ld  (hl),a		;set bullet direction
	inc hl
	ld  (hl),d		;set x-pos
	inc hl
	ld  (hl),e		;set y-pos
	ret

;----------------------------- enemy bullets --------------------------------

Enemy_bullets:
	ld  hl,ebullets
	ld  b,nrebuls
handle_bullet:
	psh bc
	psh hl
	ld  a,(hl)		;load bulletType in a
	and %1111		;select direction-bits
	jr  nz,enemy_bullet	;non-0: handle bullet
next_bullet:
	pop hl			;do not move the <pop hl>
	pop bc
	inc hl \ inc hl \ inc hl
	dnz handle_bullet
	ret

enemy_bullet:
	ld  b,a			;save type&%1111
	inc hl			;bullet x
	ld  a,(hl)		;check if it has reached the left side of scrn
	and %11111110		;it is <2 (0 or 1)?
	jr  z,remove_ebullet	;yes, remove bullet
	dec (hl)		;move one left
	dec (hl)		;and another one
	ld  d,(hl)		;d=x
	inc hl			;@y

	ld  a,b			;restore type
	cp %1100		;is it a normal bullet? (cp = faster than bit)
	jr  z,ebullet_common	;type %1100: normal bullet
	and %111		;isolate important bits
	jr  z,ebullet_down	;type %1000: moving down
	dec a
	jr  z,ebullet_up	;type %1001: moving up
	ld  b,a

	ld  a,(timer)
	rra
	jr  c,ebullet_common

	ld  a,b
	dec a
	jr  z,ebullet_down	;type %1010: moving down 50%
				;type %1011: moving up 50%
ebullet_up:
	ld  a,(hl)
	dec a
	jp  m,ebullet_common
	ld  (hl),a
	jr  ebullet_common

ebullet_down:
	ld  a,(hl)
	inc a
	cp  55
	jr  z,ebullet_common
	ld  (hl),a

ebullet_common:
	ld  e,(hl)		;e=y
	ld  ix,spr_bullete1	;display enemy bullet
	cal putsprite

ebullet_hits:
	ld  a,(your_occ)
	or  a
	jr  nz,next_bullet	;0 = you're normal

	pop hl
	psh hl
	inc hl			;check x
	ld  a,(x)
	sub (hl)
	add a,6
	jp  m,next_bullet
	cp  9
	jr  nc,next_bullet

	inc hl			;check y
	ld  a,(y)
	sub (hl)
	add a,6
	jp  m,next_bullet
	cp  9
	jr  nc,next_bullet

	pop hl			;points to bullettype again
	psh hl			;and save it again (ivm call to damage_you)
	ld  a,(hl)		;load bullettype
	cal _shracc		;isolate damage-bits (%1111???? -> %00001111)
	ld  b,a			;set damage-amount
	cal damage_you		;HIT!!
remove_ebullet:
	pop hl			;hl could be destroyed by damage_you
	ld  (hl),0		;bullet > unused
	jr  next_bullet+1	;next bullet (SKIP THE <POP HL> = one byte)

;--------------------------- handle enemies ---------------------------------

Handle_enemies:
	ld  hl,enemies+1
	ld  b,nrenemies		;handle all enemies

handle_enemy:
	psh bc
	psh hl

	ld  a,(hl)
	and %00000011
	jr  z,next_enemy	;occ "no enemy" 0
	dec a
	jr  z,exploding_enemy	;occ "exploding" 1
	ld  b,a			;b=2 if moving, otherwise b=1

normal_enemy:			;occ "normal" 2 or "moving" 3
	inc hl
	ld  c,(hl)		;c = enemy type = de
	cal find_sprite

	inc hl
	ld  a,(hl)		;x
	dec a			;move left
	jr  c,remove_enemy	;off screen
	jr  z,remove_enemy	;"
	ld  d,a

	inc hl
	ld  e,(hl)		;y
	ld  a,b			;moving state was stored in b earlier
	dec a			;is it 1?
	cal nz,moving_enemy	;2 = moving enemy

	ld  (hl),e
	dec hl			;@x
	ld  (hl),d		;store new x
	ld  a,c			;a = enemy type
	or  a			;type 0? (pickup)
	jr  nz,check_enemyfire	;no, a normal enemy; let em fire
	ld  a,(timer)		;load time
	and %1			;move left once every 2 turns
	jr  z,firing_done	;don't move now
	inc d			;increase x-position (don't move this turn)
	inc (hl)		;and save it
	jr  firing_done		;continue

check_enemyfire:
	inc hl			;go to <y>
	inc hl			;go to <move>
	inc hl			;go to <fire>
	dec (hl)		;decrease counter till next blast
	ld  a,(hl)		;&&&doesn't seem efficient to me
	or  a			;has it reached zero?
	jr  nz,firing_done	;finished if not

	ld  a,(level_fire)	;re-set counter for next blast
	ld  (hl),a		;save time to fire
	inc hl			;next byte = bullettype &&&
	psh de			;save registers for firing-use
	cal Enemy_fires		;fires bullet
	pop de			;restore (destroyed by Enemy_fires)
firing_done:
	cal putwidesprite	;display sprite @ix

next_enemy:
	pop hl
	ld  bc,enemysize
	add hl,bc
	pop bc
	dnz handle_enemy
	ret

remove_enemy:
	pop hl
	ld  (hl),$0000		;bye bye enemy
	jr  next_enemy+1	;continue AFTER pop hl (already done)

exploding_enemy:
	inc hl
	psh hl
	ld  a,(hl)
	cal explosion_stuff	;display explosion
	pop hl

	ld  a,(hl)
	cp  15
	jr  z,remove_enemy	;remove when at last frame
	inc a
	ld  (hl),a		;next frame
	jr  next_enemy

;--------------------------- moving enemies ---------------------------------

moving_enemy:
	ld  a,(level_move)
	and a
	jr  z,movetype_updown	;type 0
	dec a
	jr  z,movetype_vslow	;1
	dec a
	jr  z,movetype_fast	;2
	dec a
	jr  z,movetype_vfast	;3
	dec a
	jr  z,movetype_smart	;4
	dec a
	jr  z,movetype_lure	;5
	dec a
	jr  z,movetype_slowlure	;6
	dec a
	jr  z,movetype_stoplure	;7
;	dec a
;	jr  z,movetype_fulllure	;8

movetype_fulllure:
	inc d
	ld  a,(timer)
	and 1
	ret z
	cal movetype_lure
	ld  a,(x)
	cp  d
	jr  c,lure_left
lure_right:
	inc d
	ret
lure_left:
	dec d
	ret

movetype_stoplure:
	inc d
	jr  movetype_slowlure

movetype_slowlure:
	ld  a,(timer)
	and 1
	ret z

movetype_lure:
	ld  a,(y)
	cp  e
	jr  c,lure_up
lure_down:
	inc e
	ret
lure_up:
	dec e
	ret

movetype_smart:
	inc hl			;hl =@ <move>
	ld  a,(timer)
	and %1111               ;     |
	ld  a,(hl)		;&&& \|/
	jr  nz,smartupdate
	inc a
smartupdate:
	ld  (hl),a

	or  a			;reset carry flag
	dec hl			;reset hl to <y>
	and %11111100
	jr  z,movetype_fast

movetype_vslow:
	ld  a,(timer)
	and %11
	ret z
	inc d
	ret

movetype_fast:
	ld  a,(timer)
	and %1
	ret z
movetype_vfast:
	dec d			;move left
	ret nz			;finished
	pop hl			;restore stack (no ret used)
	jp  remove_enemy	;remove this enemy (off screen)

movetype_updown:
	inc hl			;@ <move>
	ld  a,(hl)
	dec a
	jr  nz,move_updated
	add a,128
move_updated:
	ld  (hl),a

	or  a			;reset carry flag
	dec hl			;@ <y>
	and %00100000
	ld  a,(hl);&&&ld a,e	;load current y-position
	jr  z,movedown

moveup:	dec a			;decrease y-pos (=move up)
	ret m			;don't move off the screen (y<0)
	dec e			;save new y-pos
	ret			;finish
movedown:
	inc a			;increase y-pos
	cp  55			;compare with bottom
	ret nc			;return if it has passed that line (>40)
	inc e			;otherwise save new position
	ret			;and return

;--------------------------- check collision --------------------------------

Enemies_hit:
	ld  hl,(x)		;e = X, d = Y
	ld  de,$0707		;add 7 to both d and e
	add hl,de
	ld  d,h
	ld  e,l			;e = X+7, d = Y+7

	ld  hl,enemies+1
	ld  b,nrenemies		;check all 20 enemies
check_collision:
	psh hl
	ld  a,(hl)
	and %00000010
	jr  z,check_next	;2 or 3 = ok
	inc hl

collide_enemy:			;&&& include in Handle_enemy proc
	psh de
	cal find_sprite
	pop de

	inc hl
	ld  a,(hl)		;check x match
	sub e			;enemy position minus yours minus 7
	jp  p,check_next
	add a,6
	add a,(ix)
	jp  m,check_next

	inc hl
	ld  a,(hl)		;check y match
	sub d			;same as with x-check
	jp  p,check_next
	add a,6
	add a,(ix+1)
	jp  m,check_next
	dec hl
	dec hl

take_pickup:
	psh hl			;we need hl
	ld  hl,2		;increase score by 2
	cal scoreInc
	pop hl			;we're done

	ld  a,(hl)		;load enemy type
	or  a
	jr  nz,collide		;enemy when <>0

	psh hl
	ld  hl,your_pickup	;your pickups
	ld  a,(hl)		;current
	inc a			;go to next
	cp  6			;pickups >=6
	jr  c,not_maxpickup
	ld  a,1			;yes: reset to pickup 1
not_maxpickup:
	ld  (hl),a		;save new
	cal disp_icons		;display altered pickupicons
	pop hl

	dec hl			;to enemy occ
	xor a			;set to 0 = gone
	ld  (hl),a		;remove
	jr  check_next		;all done, next..

destroy_enemy:
	ld  (hl),%01		;set to explode
	inc hl
	ld  (hl),0		;explosionFrame 0
	jr  collide_done

collide:
	dec hl
	ld  a,(hl)
	and %11111100
	jr  z,destroy_enemy
	ld  a,(hl)
	sub %00000100
	ld  (hl),a
collide_done:
	ld  b,4			;damage
	cal damage_you

check_next:
	pop hl
	ld  a,b			;psh bc
	ld  bc,enemysize
	add hl,bc
	ld  b,a			;pop bc
	dnz check_collision
	ret

;--------------------------- story ------------------------------------------

storyPage:
	psh hl
	cal _clrLCD
	pop hl
storyLine:
	inc hl
	ld  e,(hl)
	inc hl
	ld  d,(hl)
	ld  (_penCol),de
	inc hl
	cal _vputs

	ld  a,(hl)
	dec a
	jr  z,storyLine

	psh hl
	ld  hl,VIDEO_MEM
	ld  de,GRAPH_MEM
	ld  bc,1024
	ldir
	cal _clrLCD
	pop hl

	inc hl
	ld  a,(hl)
	inc hl
	ld  b,(hl)
	psh hl
	cal DoSFX
	cal _getkey
	pop hl
	ret

dostory:
	cal storyPage			;do some story
	inc hl				;look at next hl
	ld  a,(hl)			;load in a
	dec hl				;restory hl
	inc a				;set z-flag if a = $ff
	jr  nz,dostory			;otherwise loop

	ld  bc,5			;story ends
	add hl,bc			;set hl to beginning of the level
	ld  (levelp),hl			;set the level-pointer
	ret				;and return

;--------------------------- SFX --------------------------------------------

CDoSFX:
	ld  hl,VIDEO_MEM
	ld  de,GRAPH_MEM
	ld  bc,1024
	ldir
	ld  b,64
	ld  a,-1

DoSFX:				;ins: a=beginLine b=nrOfLines
	ld  (curline),a
SFXframe:
	psh bc

	ld  a,(curline)		;get line number
	inc a			;go to the next line
	ld  (curline),a		;update

	ld  l,a
	ld  h,0
	add hl,hl
	add hl,hl
	add hl,hl
	add hl,hl

	ld  b,h			;save hl for later
	ld  c,l

	ld  de,VIDEO_MEM
	add hl,de		;go to ymin
	ld  d,h
	ld  e,l

	ld  hl,GRAPH_MEM
	add hl,bc		;hl->logo

	ld  a,(curline)		;Calculate how many lines to draw
	ld  c,a
	ld  a,64
	sub c
	ld  b,a

SFXdisp:			;display this frame on screen
	ld  a,b			;psh b (a will not be used)
	ld  bc,16		;one line (=16 bytes, you'd know by now)
	ldir			;display (copy actually)
	ld  bc,-16		;go up one line (not on screen)
	add hl,bc		;so the same line will be displayed
	ld  b,a			;pop b
	dnz SFXdisp		;repeat until whole screen is displayed

	ld  b,8
SFXdelay:
	halt
	dnz SFXdelay

	pop bc
	dnz SFXframe
	ret

;--------------------------- show icon --------------------------------------

drawline:
	ld  (hl),a		;draw one piece of the divider-line
	inc hl			;move right (8 pixels = 1 byte)
	dnz drawline		;repeat (16bytes * 8pixels =128= screen width)
	ret

disp_icons:
 psh bc \ psh de \ psh hl \ psh ix ;&&&

	ld  hl,VIDEO_MEM+(16*56);56 rows down = eight rows from bottom
	ld  (PutWhere),hl	;place icons at bottom of normal screen
	ld  b,16		;draw 16x (screen width)
	ld  a,%11111111		;horizontal line mask
	cal drawline		;draw divider-line

	ld  b,16*7		;draw 16x (screen width) 7x (height)
	xor a			;blank line mask
	cal drawline		;clear scorebar

	cal disp_lives

	ld  ix,spr_icon01	;armorIcon
	ld  de,$1901		;icon #1
	cal putwidesprite	;display icon
	cal disp_armor		;display bar

	ld  ix,spr_icon00
	ld  a,(torp_occ)
	or  a
	jr  z,no_torp
	ld  ix,spr_icon02	;torpedoIcon
no_torp:
	ld  de,$2901		;icon #2
	cal putwidesprite	;display

	ld  ix,spr_icon03	;bulletIcon
	ld  de,$3901		;icon #3
	cal putwidesprite	;display icon
	ld  hl,$3945		;position to display bullet-type digit
	ld  a,(your_weapon)	;digit
	dec a			;minus one (1=laser)
	ld  (_penCol),hl	;set location
	add a,'0'		;make digit
	cal _vputmap		;display char

	ld  ix,spr_icon00	;emptyIcon
	ld  a,(your_weapon)
	dec a
	jr  nz,no_laser
	ld  ix,spr_icon04	;laserIcon
no_laser:
	ld  de,$4901		;icon #4
	cal putwidesprite

	ld  ix,spr_icon00	;emptyIcon
	ld  a,(your_multiples)
	and %11
	jr  z,no_multiples
	ld  ix,spr_icon05
no_multiples:
	ld  de,$5901		;icon #5
	cal putwidesprite

	ld  ix,spr_dividerline
	ld  de,$6901
	cal putwidesprite

	ld  a,(your_pickup)	;pickups taken
	add a,a			;picks*2 (sets z-flag)
	jr  z,iconsdone		;return if no pickups
	add a,a			;picks*4
	add a,a			;picks*8
	add a,a			;picks*$10
	add a,$09		;add 0ah
	ld  d,a			;y-pos = picks * $10 + $0a (19,29,39,49,59)
	ld  e,$01		;x-pos = bottom (1a01,2a01,3a01,4a01,5a01)

	ld  ix,spr_icon
	cal putwidesprite
iconsdone:
	ld  hl,GRAPH_MEM	;normal game-screen
	ld  (PutWhere),hl	;set sprite-position to normal screen

 pop ix \ pop hl \ pop de \ pop bc
	ret

disp_armor:
	ld  hl,(57*16)+VIDEO_MEM+3
	ld  b,3
armorbarclr:
	dec hl
	ld  (hl),0
	dnz armorbarclr

	ld  a,(your_armor)	;load your armor
	ld  c,a			;psh a
	srl a			;/2
	srl a			;/4
	srl a			;/8: don't display last 2 bits of a (later)
	jr  z,noarmorbar	;if a=0 then it would loop 256x so skip it
	ld  b,a			;loop b=a times
armorbar:			;starting at ($39*16)+VIDEO_MEM
	ld  (hl),%11111111	;draw a piece of the bar
	inc hl			;next position
	dnz armorbar		;loop it b times

noarmorbar:
	ld  a,c			;pop a
	and %111		;display last bits of armor
	ret z			;if armor=0 then bit = %00000000 (don't disp)
	ld  b,a			;into B
	xor a			;bit = %00000000
armorbarbit:
	scf			;set carry flag
	rra			;rotates A right and sets bit 7 (c-flag)
	dnz armorbarbit		;repeat B times (so if B=6 then a=%11111100)
armorbarready:			;		(an if B=3 then a=%11100000)
	ld  (hl),a		;draw this last byte
	ret

disp_lives:
	ld  hl,$3A00		;display Lives
	ld  (_penCol),hl	;bottom left
	ld  hl,savestr+2
	ld  (hl),'L'
	inc hl
	ld  (hl),'x'
	inc hl

	ld  a,(your_lives)	;nr of lives in a
	add a,'0'		;make digit
	ld  (hl),a
	dec hl \ dec hl
	jp  _vputs		;display on screen +ret

;--------------------------- proc -------------------------------------------

Random5016:
	cal Random50		; a = 0..50
	inc a			; a = 1..51
	ld  h,0
	ld  l,a			;hl = 1..51
	add hl,hl		;hl = 1..51 * 2
	add hl,hl		;hl = 1..51 * 4
	add hl,hl		;hl = 1..51 * 8
	add hl,hl		;hl = 1..51 * 16 (left side at random y)
	dec hl			;hl = 1..51 * 16 (" at right side of screen)
	ld  de,GRAPH_MEM
	add hl,de		;position on screen
	ret

Random50:
	cal Random
	cp  51			;y may not be more than 50
	ret c			;OK if a<51
	and %00111111		;a = 0..63
	sub 13			;a = -13..50
	ret nc			;OK if a>=0
	add a,13+(50-12)	;a = -13..-1 >=> 0..12 >=> 39..50
	ret

Random:
	ld  a,(RanPos)		;a handy random-var.
	ld  hl,x		;add your x-coord for randomness
	adc a,(hl)
	inc hl			;add your y-coord for randomness
	adc a,(hl)
	ld  (RanPos),a		;save altered random-var
	ret			;RanPos also in #a

scoreInc:
	psh bc
	ld  bc,(score)
	add hl,bc
	ld  (score),hl
	pop bc
	ret

find_sprite:			;destroyed: de ix
	psh hl
	ld  e,(hl)		;e = enemy type
	ld  d,0			;de = e
	ld  hl,XLenemytable	;hl = @sprites offset-table
	add hl,de		;points to offset of current enemy offset
	ld  e,(hl)		;de = @enemy offset
	ld  d,0

	ld  ix,XLsprenemies	;first enemy sprite
	add ix,de		;add offset for current enemy
	add ix,de		;twice (offset stored as offset/2)
	pop hl
	ret

BLACKLCD:
	ld  hl,VIDEO_MEM	;screen location (top left)
	ld  de,VIDEO_MEM+1
	ld  (hl),%11111111
	ld  bc,1024-1		;do it 1024 times = entire screen
	ldir
	set 3,(iy+5)		;set white on black
	ret

waitnokeypressed:
	halt \ halt
	cal GET_KEY
	or  a
	jr  nz,waitnokeypressed
	ret

Decompress:			;hl=source(compressed) de=dest(decompressed)
	ld  a,(hl)
	bit 7,a
	jr  z,compressed
	inc hl
	and %01111111
	ld  b,0
	ld  c,a
	ldir
	jr  Decompress
compressed:
	psh af
	or  %11111100
	ld  b,a
	inc hl
	ld  c,(hl)
	inc hl
	pop af
	and %01111100
	rrca
	rrca
	or  a
	ret z
	psh hl
	ld  h,d
	ld  l,e
	add hl,bc
	inc a
	inc a
	ld  b,0
	ld  c,a
	ldir
	pop hl
	jr  Decompress

;--------------------------- game over / new game / death -------------------
chartable:
	.db 0,"!<>^",0,0,0,0
	.db 0,"xtoje0",0	;enter..clear
	.db " wsnid9",0		;(-)..custom
	.db "zvrmhc8",0		;dot..del
	.db "yuqlgb7x"		;0..xvar
	.db 0,"-pkfa6'"		;on..alpha
	.db "54321.",0,0	;F5..more

own_name:
	.db 7,"nemesis"

save_hi:
	ld  hl,own_name-1	;find own variable
	rst 20h			;cal _ABS_MOV10TOOP1
	rst 10h			;cal _FINDSYM
	ret c			;not found? who cares...

	xor a
        ld  hl,4+storehi_start-_asm_exec_ram
        add hl,de		;hl=pointer to data in original prog
        adc a,b
        cal _SET_ABS_DEST_ADDR
        xor a
        ld  hl,storehi_start
        cal _SET_ABS_SRC_ADDR
        ld  hl,storehi_end-storehi_start
        cal _SET_MM_NUM_BYTES
        cal _mm_ldir		;save done (cal \ ret)
	jp  _RAM_PAGE_1

save_lvl:
	ld  hl,own_name-1	;find own variable
	rst 20h			;cal _ABS_MOV10TOOP1
	rst 10h			;cal _FINDSYM
	ret c			;not found? who cares...

	xor a
	ld  hl,4+storesave_start-_asm_exec_ram
	add hl,de		;hl=pointer to data in original prog
	adc a,b
	cal _SET_ABS_DEST_ADDR
	xor a
	ld  hl,storesave_start
	cal _SET_ABS_SRC_ADDR
	ld  hl,storesave_end-storesave_start
	cal _SET_MM_NUM_BYTES
	cal _mm_ldir		;save done (cal \ ret)
	jp  _RAM_PAGE_1

game_over:
	pop hl			;=ret (game_over was called from a procedure)
game_over_nopop:
	cal BLACKLCD		;clear screen
	cal waitnokeypressed
	ld  hl,$0603
	ld  (_curRow),hl	;center
	ld  hl,txt_gameover
	cal _puts		;display "GAME OVER"

	ld  hl,$0007
	ld  (_curRow),hl

	ld  de,(score)
	ld  hl,(hiscore)
	cal CP_HL_DE
	jr  nc,no_hiscore
	ld  (hiscore),de

ask_hiname:
	ld  ix,hiname
	ld  a,9
	ld  (hiscorepos),a
enter_name_loop:
	ld  a,'_'
	cal _putc
	ld  hl,_curCol
	dec (hl)
nokeypressed:
	halt \ halt
	cal GET_KEY
	or  a
	jr  z,nokeypressed

	cp  K_DEL
	jr  z,backup
	cp  K_ENTER
	jr  z,nomore
	cp  K_EXIT
	jr  z,nomore

	ld  hl,hiscorepos
	ld  b,(hl)
	dec b
	jr  z,nokeypressed
	ld  (hl),b

	ld  hl,chartable
	ld  e,a
	ld  d,0
	add hl,de
	ld  a,(hl)
	or  a
	jr  z,nokeypressed

	ld  (ix),a
	cal _putc
	inc ix
	cal waitnokeypressed
	jr  enter_name_loop

backup:
	ld  hl,hiscorepos
	ld  a,(hl)
	cp  9
	jr  nc,nokeypressed
	inc (hl)

	dec ix
	ld  (ix),' '
	ld  a,32
	cal _putc
	ld  hl,_curCol
	dec (hl)
	dec (hl)
	jr  enter_name_loop

nomore:
	ld  a,' '
	cal _putc
	ld  (ix),0
	cal save_hi
	jr  hiscoredone

no_hiscore:
	ld  hl,hiname
	cal _puts

hiscoredone:
	xor a			;clear a (Ahl will be displayed)
	ld  hl,$1006		;bottom-1 right
	ld  (_curRow),hl	;set
	ld  hl,(score)		;your score
	cal _dispahl		;display it (a=0)

	ld  hl,$314b		;bottom-1 right before score ^^
	ld  (_penCol),hl	;set
	ld  hl,txt_score	;"Score"
	cal _vputs		;display (small)

	ld  hl,$1007		;bottom right
	ld  (_curRow),hl	;set
	ld  hl,(hiscore)	;hi-score
	cal _dispahl		;display
	ld  hl,$3946		;bottom right before hiscore ^^
	ld  (_penCol),hl	;set
	ld  hl,txt_hiscore	;"Hiscore"
	cal _vputs		;display (small)
	res 3,(iy+5)

	ld  b,16
	ld  de,16
	ld  hl,VIDEO_MEM+(49*16)-1
restore_line:
	set 1,(hl)
	add hl,de
	dnz restore_line

	cal _getkey		;wait for keypress
	jp  quit		;restore some things and return to TI-OS/shell

New_game:
	xor a			;ld a,0
	ld  (score),a		;reset score
	ld  (score+1),a		;reset score (0)
	ld  (torp_occ),a	;no torpedoes
	ld  (your_weapon),a	;no laser
	ld  (your_pickup),a	;reset pickups
	ld  (your_multiples),a	;no multiples
	inc a			;ld a,1
	ld  (level),a		;reset level nr (#1)
	ld  hl,XLlevelsdata	;set level pointer to level#1
	ld  (levelp),hl		;reset level pointer
	inc a			;ld a,2
	ld  (your_weapon),a	;default weapon
	ld  a,4
	ld  (your_lives),a	;3 lives (4 will be decreased @ You_die)
	ld  (pickuptimer),a	;next pickup after 4 enemies destroyed

You_die:
	ld  a,12
	ld  (your_armor),a	;12 HPs/shields
	ld  a,(your_lives)	;load lives left
	dec a			;decrease lives
	ld  (your_lives),a	;if lives=0ffh GO
	jp  c,game_over
	jr  samelevel

;--------------------------- next level -------------------------------------

Next_level:
	ld  a,(your_armor)	;load current armor
	cp  25-8		;may not become >=25
	jr  c,addok		;ok then just add 8
	ld  a,25-8		;set to maximum (8 will be added below)
addok:
	add a,8			;add 8 to armor
	ld  (your_armor),a	;change armor

	ld  hl,level		;level number
	ld  a,(hl)
	inc a
	ld  (hl),a

	add a,a
	add a,a
	ld  h,0			;increase score....
	ld  l,a			;by level number * 4
	ld  bc,20
	add hl,bc		;plus 20
	cal scoreInc		;update score

	ld  hl,(levelp)		;level pointer
	ld  bc,5+32+4+4		;advance one level
	add hl,bc		;update to point to next level
	ld  (levelp),hl		;save

samelevel:
	ld  a,80
	ld  (nextevent),a	;time to first enemy appearance

	ld  hl,(levelp)		;level pointer
	xor a
	cp  (hl)
	cal z,dostory

	ld  a,(hl)		;load new level-enemy type
	ld  (level_enemy),a	;set level-enemy
	inc hl
	ld  a,(hl)		;load new appearance-time
	ld  (eventtime),a	;set
	inc hl
	ld  a,(hl)		;load nr of enemies in this level
	ld  (eventleft),a	;set nr of events left
	inc hl
	ld  a,(hl)		;
	ld  (level_info),a	;
	inc hl
	ld  a,(hl)		;movement of enemies in this level
	ld  (level_move),a	;do it
	inc hl
	ld  a,(hl)		;how frequent the enemies fire a bullet
	ld  (level_fire),a	;consider it done

	inc hl
	ld  de,spacespace
	ld  bc,17+17+2
	ldir

	ld  ix,starx1
	ld  b,nrstars1
	cal placestars
	ld  hl,RanPos
	inc (hl)
	ld  ix,starx2
	ld  b,nrstars2
	cal placestars

	xor a
	ld  (timer),a		;reset time
	ld  hl,your_occ		;hl = your_occ
	ld  (hl),a		;reset your ship (not exploding)
	inc hl			;hl = your_inv
	ld  (hl),25		;set 25*4=100 frames invulnerable
	ld  hl,x		;begin position x=...
	ld  (hl),a		;...=a=0=left
	inc hl			;y=...
	ld  a,24		;...=24=middle
	ld  (hl),a		;your y

	ld  a,(torp_occ)
	or  a			;no torpedoes?
	jr  z,torpsclear	;then just continue (=0)
	ld  a,1			;if so, set to "ready to fire" (=1)
torpsclear:

	ld  de,$0018		;x=0, y=24 (like you..)
;	cal Place_multiples	;place all multiple-positions at (0,24)

	ld  hl,enemies		;remove all enemies and bullets
	ld  (hl),0		;clear first byte
	ld  de,enemies+1	;copy this to the next byte
	ld  bc,(nrenemies*enemysize)+((nrybuls+nrebuls)*3)-1
	ldir			;clear enemies + bullets (y/e)

;--------------------------- setup game -------------------------------------

game_setup:
	cal BLACKLCD
	ld  hl,$0703
	ld  (_curRow),hl	;center
	ld  hl,txt_level
	cal _puts		;display "LEVEL "

	ld  a,(level)
	ld  l,a
	ld  h,$00

	cal UNPACK_HL
	add a,'0'
	ld  b,a
	cal UNPACK_HL
	add a,'0'
	cal _putc		;display second digit
	ld  a,b
	cal _putmap		;display first digit

	ld  hl,$0904
	ld  (_curRow),hl	;display lives left below level nr
	ld  hl,txt_lives	;bar text: "Lx0"...
	ld  a,(your_lives)	;lives left
	add a,'0'		;make value
	ld  (txt_lives+3),a	;add to text
	cal _puts		;display the string
	res 3,(iy+5)		;set white on black

	cal _getkey		;wait for keypress
	cp  kF1
	cal z,save_lvl

	cal _clrLCD		;clear screen
	jp  disp_icons		;display bottom icons +ret

placestars:
	cal Random5016		;a = (0..50)*16 = random y-pos
	ld  a,b			;a =  b = star nr. = 1..7
	add a,a			;a = 2b = 2..14
	ld  d,0
	ld  e,a			;de = a = 2-14
	add hl,de		;add to random y => random pos anywhere

	ld  (ix),l		;save x-pos (l)
	ld  (ix+1),h		;save y-pos (h)
	inc ix \ inc ix		;next star
	dnz placestars		;repeat for all stars
	ret

loadweapon:
	ld  a,(your_weapon)
	add a,a			;weap*2
	add a,a			;    *4
	add a,a			;    *8
	ld  c,a
	ld  b,0
	ld  hl,weapondata-16
	add hl,bc
	ld  a,(hl)
	ld  (weapdamage),a	;damage of bullets
        inc hl
        ld  a,(hl)
;        ld  (weapdaminc),a	;damage increase
	ret

;--------------------------- putsprite --------------------------------------
;--------------------------- de =(X,Y) --------------------------------------

offsets_table:
	.db $80,$40,$20,$10,8,4,2,1
putsprite:
	ld  a,d			;a = X
	and %00000111		;a = X mod 8 = bit nr. to mask
	ld  hl,offsets_table	;pixel mask table
	ld  c,a			;bit nr.
	ld  b,0			;word
	add hl,bc		;add to table
	ld  a,(hl)		;a = pixel mask
	ld  (_smc1+1),a		;alter pixel mask

	ld  hl,GRAPH_MEM	;save-location
	ld  a,e			;y-coord
	add a,a			;y*2
	add a,a			;y*4
	add a,a			;y*8
	rl  b			;b (=0) =b*2+overflow (if y>32 then bc=bc+256)
	add a,a			;y*16 (width of screen)
	rl  b			;b=b*2+overflow (if y>64 then bc=bc+512)
	srl d			;d/2
	srl d			;d/4
	srl d			;d/8 (8 bits in byte) ** c is set when overflow
	add a,d			;a = (Y*16+X/8) mod 256
	jr  nc,_n1		;jump if no carry = no overflow = a<=255
	inc b			;a>255 so increase bc by 256
_n1:	ld  c,a			;c = (Y*16+X/8) mod 256
	add hl,bc		;bc = Y*16+X/8

	ld  d,(ix)
	ld  b,(ix+1)
_oloop:	psh bc			;Save # of rows
	psh hl			;Save screen address
	ld  b,d			;Load width
	ld  c,(ix+2)		;Load one line of image
	inc ix
_smc1:	ld  a,1			;Load pixel mask
_iloop:	sla c			;Test leftmost pixel
	jr  nc,_noplot		;See if a plot is needed
	ld  e,a			;OR pixel with screen
	or  (hl)
	ld  (hl),a
	ld  a,e
_noplot:rrca
	jr  nc,_notedge		;Test if edge of byte reached
	inc hl			;Go to next byte
_notedge:
	dnz _iloop
	pop hl			;Restore address
	ld  bc,16		;Go to next line
	add hl,bc
	pop bc			;Restore data
	dnz _oloop
	ret			;<jp>s are used instead of <jr> = faster

;--------------------------- putbigsprite -----------------------------------

putwidesprite:
	ld  a,d
	and 7
	ld  hl,offsets_table
	ld  c,a
	ld  b,0
	add hl,bc
	ld  a,(hl)
	ld  (wsmc1+1),a
	ld  (wsmc2+1),a
	ld  hl,(PutWhere)

	ld  a,e
	add a,a
	add a,a
	add a,a

	rl  b
	add a,a
	rl  b
	srl d
	srl d
	srl d
	add a,d
	jr  nc,n1
	inc b
n1:	ld  c,a
	add hl,bc

	ld  d,(ix)
	ld  b,(ix+1)
woloop:	psh bc			;Save # of rows
	psh hl			;Save screen address
	ld  b,d			;Load width
	ld  c,(ix+2)		;Load one line of image
	inc ix
wsmc1:	ld  a,1			;Load pixel mask
wiloop:	sla c			;Test leftmost pixel
	jr  nc,wnoplot		;See if a plot is needed
	ld  e,a			;OR pixel with screen
	or  (hl)
	ld  (hl),a
	ld  a,e
wnoplot:
	rrca
	jr  nc,wnotedge		;Test if edge of byte reached
	inc hl			;Go to next byte
wnotedge:
wsmc2:	cp  1
	jr  z,wover_1

	dnz wiloop
	pop hl			;Restore address
	ld  bc,16		;Go to next line
	add hl,bc
	pop bc			;Restore data
	dnz woloop
	ret
wover_1:
	ld  c,(ix+2)
	inc ix
	dnz wiloop
	dec ix
	pop hl
	ld  bc,16
	add hl,bc
	pop bc
	dnz woloop
	ret

;----------------------------------------------------------------------------
;------------------------------- sprites ------------------------------------
;----------------------------------------------------------------------------

spr_ship01:
	.db 7,7		;ship alpha class
	.db %01111000	;  ████
	.db %11100000	; ███
	.db %01111100	;  █████
	.db %11110010	; ████  █
	.db %01111100	;  █████
	.db %11100000	; ███
	.db %01111000	;  ████
spr_ship01i:
	.db 7,7		;ship alpha class
	.db %01010000	;  █ █
	.db %10100000	; █ █
	.db %01010100	;  █ █ █
	.db %10100010	; █ █   █
	.db %01010100	;  █ █ █
	.db %10100000	; █ █
	.db %01010000	;  █ █

spr_ship02:
;	.db 7,7		;ship beta class
;	.db %11100000	; ███
;	.db %11110000	; ████
;	.db %01111100	;  █████
;	.db %01110010	;  ███  █
;	.db %01111100	;  █████
;	.db %11110000	; ████
;	.db %11100000	; ███
spr_ship02i:
;	.db 7,7		;ship beta class
;	.db %01000000	;  █
;	.db %10100000	; █ █
;	.db %01010100	;  █ █ █
;	.db %00100010	;   █   █
;	.db %01010100	;  █ █ █
;	.db %10100000	; █ █
;	.db %01000000	;  █

spr_multiple:
	.db 6,4		;multiples
	.db %01111000	;  ████
	.db %11111100	; ██████
	.db %11111100	; ██████
	.db %01111000	;  ████

;--------------------------------- bullets ----------------------------------

spr_bullet01:
	.db 5,3		;dam=0-3
	.db %00110000	;  ▒██
	.db %01001000	; ▒█ ▒█
	.db %00110000	;  ▒██
spr_bullet02:
	.db 5,3		;dam=4-7
	.db %00110000	;  ▒██
	.db %01101000	; ▒██▒█
	.db %00110000	;  ▒██
spr_bullet03:
	.db 5,3		;dam=8-11
	.db %00110000	;  ▒██
	.db %11101000	;▒███▒█
	.db %00110000	;  ▒██
spr_bullet04:
	.db 5,3		;dam=8-11
	.db %00110000	;  ▒██
	.db %11111000	;▒█████
	.db %00110000	;  ▒██
spr_bullet05:
	.db 5,3		;dam=8-11
	.db %01110000	; ▒███
	.db %11111000	;▒█████
	.db %01110000	; ▒███
spr_bullet06:
	.db 5,3
	.db %11110000	;▒████
	.db %11111000	;▒█████
	.db %11110000	;▒████
spr_bullett1:
	.db 4,3		;▒▒▒
	.db %11100000	;▒███
	.db %11110000	; ████
	.db %01110000	;  ███

spr_bullete1:
	.db 4,3		;enemy bullets
	.db %01100000	;  ▒█▓▒░
	.db %11110000	; ▒███▓▒░
	.db %01100000	;  ▒█▓▒░

;-------------------------------- explosion ---------------------------------

spr_explosion:
	.db 8,6		;1
	.db %00000000
	.db %00011100	;    ███
	.db %00111110	;   █████
	.db %01010110	;  █ █ ██
	.db %00111000	;   ███
	.db %00000000

	.db 8,6		;2
	.db %00110000	;   ██
	.db %01001110	;  █ ▒███
	.db %10111110	; █ █████
	.db %01001111	;  █ ▒████
	.db %00111000	;   ███
	.db %00011010	;    ██ █

	.db 8,6		;3
	.db %10110000	; █ ██
	.db %01001110	;  █  ███
	.db %10110101	; █ ██▒█▒█
	.db %01000101	;  █  ▒█▒█
	.db %00111110	;   █████
	.db %01011010	;  █ ██ █

	.db 8,6		;4
	.db %00101010	; ▒ █▒█ █
	.db %01000110	;  █  ▒██
	.db %10110101	; █ ██ █ █
	.db %01100110	;  ██  ██▒
	.db %00111100	;   ████▒
	.db %01011001	;  █ ██ ▒█

	.db 8,6		;5
	.db %01000000	;  █▒ ▒ ▒
	.db %00100101	;  ▒█  █▒█
	.db %00010100	; ▒ ▒█ █ ▒
	.db %01000100	;  █▒  █
	.db %00010010	;   ▒█▒▒█
	.db %10011010	; █▒ ██ █▒

	.db 8,6		;6
	.db %01000100	;  █   █
	.db %00100000	;   ▒█ ▒ ▒
	.db %00000001	;    ▒ ▒ █
	.db %01000100	;  █   █
	.db %00100010	;   █▒  █
	.db %01001000	; ▒█ ▒█ ▒

	.db 8,6		;7
	.db %00001000	;  ▒  █▒
	.db %11000010	; ██ ▒  █
	.db %00000000	;        ▒
	.db %00100000	;  ▒█  ▒
	.db %00000001	;   ▒   ▒█
	.db %00110000	;  ▒██▒

	.db 8,6		;8
	.db %00000100	;     ▒█
	.db %00000000	; ▒▒    ▒
	.db %01000000	;  █
	.db %00000000	;   ▒
	.db %00000010	;       █▒
	.db %00100100	;   █▒ █

spr_yexplosion:
	.db 8,6		;8
	.db %00000000	;
	.db %00000000	;
	.db %00000000	;
	.db %00000000	;
	.db %00000000	;
	.db %00000000	;

;------------------------------------ bar -----------------------------------

spr_iconhalf:
	.db 16,7	;selected .......:
	.db %11111111		; ████████
	.db %00000001		;        █
	.db %00000001		;        █
	.db %00000001		;        █
	.db %00000001		;        █
	.db %00000001		;        █
	.db %11111111		; ████████
spr_icon:
	.db 16,7	;selected .......:.......:
	.db %11111111,%11111111	; ████████████████
	.db %11000000,%00000001	; ██             █
	.db %11000000,%00000001	; ██             █
	.db %11000000,%00000001	; ██             █
	.db %11000000,%00000001	; ██             █
	.db %11000000,%00000001	; ██             █
	.db %11111111,%11111111	; ████████████████
spr_icon00:
	.db 16,7	;unused   .......:.......:
	.db %10101010,%10101010	; █ █ █ █ █ █ █ █
	.db %11010101,%01010101	; ██ █ █ █ █ █ █ █
	.db %10101010,%10101010	; █ █ █ █ █ █ █ █
	.db %11010101,%01010101	; ██ █ █ █ █ █ █ █
	.db %10101010,%10101010	; █ █ █ █ █ █ █ █
	.db %11010101,%01010101	; ██ █ █ █ █ █ █ █
	.db %10101010,%10101010	; █ █ █ █ █ █ █ █
spr_icon01:
	.db 16,7	;armor	; .......:.......:
	.db %10000111,%11110000	; █    ███████
	.db %10011000,%00001100	; █  ██       ██
	.db %10110011,%11000110	; █ ██  ████   ██
	.db %10110000,%11110110	; █ ██    ████ ██
	.db %10110011,%11000110	; █ ██  ████   ██
	.db %10011000,%00001100	; █  ██       ██
	.db %10000111,%11110000	; █    ███████
spr_icon02:
	.db 16,7	;torpedo  .......:.......:
	.db %10111000,%00010101	; █ ███      █ █ █
	.db %10011100,%00010101	; █  ███     █ █ █
	.db %10111000,%01001010	; █ ███    █  █ █
	.db %10000000,%11101010	; █       ███ █ █
	.db %11100001,%11100101	; ███    ████  █ █
	.db %10011000,%11110101	; █  ██   ████ █ █
	.db %11100110,%00110010	; ███  ██   ██  █
spr_icon03:
	.db 16,7	;bullets  .......:.......:
	.db %10000000,%11000000	; █       ██
	.db %10000011,%11100000	; █     █████ ▒▒▒
	.db %10011000,%11000000	; █  ██   ██  ▒▒▒
	.db %11111100,%00000000	; ██████      ▒▒▒
	.db %10011000,%11000000	; █  ██   ██  ▒▒▒
	.db %10000011,%11100000	; █     █████ ▒▒▒
	.db %10000000,%11000000	; █       ██
spr_icon04:
	.db 16,7	;laser    .......:.......:
	.db %10000000,%00000000	; █
	.db %10110010,%10000000	; █ ██  █ █
	.db %10111011,%00000000	; █ ███ ██
	.db %10011101,%11111111	; █  ███ █████████
	.db %10111011,%00000000	; █ ███ ██
	.db %10110010,%10000000	; █ ██  █ █
	.db %10000000,%00000000	; █
spr_icon05:
	.db 16,7	;multiple .......:.......:
	.db %10000011,%10000000	; █     ███
	.db %10000001,%11100110	; █      ████  ██
	.db %10000001,%11100000	; █      ████
	.db %10000011,%10000000	; █     ███
	.db %10011000,%00000000	; █  ██
	.db %10111100,%11000011	; █ ████  ██    ██
	.db %10011000,%00000000	; █  ██
spr_dividerline:
	.db 8,7
	.db 128,128,128,128,128,128,128	;128 = %10000000

;-------------------------- weapondata --------------------------------------

;format:[unused] [ybuls(max.bullets)] [0000:direction 0000:speed] [offset]
maxnrweapons = 8+1
weapondata:
	.db 2,1,%00000010,2,%00000000,0,%00000000,0	;single fire
	.db 2,1,%00000011,2,%00000000,0,%00000000,0	;fast single
	.db 16,2,%00000010,0,%00000010,5,%00000000,0	;double
	.db 16,1,%00010010,2,%00110010,2,%01000010,2	;triple
	.db 16,1,%00010011,2,%00110011,2,%01000011,2
	.db 16,1,%00010011,2,%00110011,2,%01000100,2
	.db 16,1,%00010100,2,%00110100,2,%01000101,2
	.db 16,1,%00010100,2,%00110100,2,%01000101,2

;---------------------------- texts -----------------------------------------

txt_about:	.db " v0.96.A30",127,"by Shiar",0
txt_email:	.db "shiar0@hotmail.com",0
txt_menu1:	.db "NEW GAME",0
txt_menu2:	.db "CONTINUE",0

txt_level:	.db "LEVEL ",0
txt_gameover:	.db "GAME OVER!",0
txt_score:	.db "Score",0
txt_hiscore:	.db "Hiscore",0
txt_lives:	.db "Lx0?",0

txt_pressenter:	.db "Enter to continue",0
txt_teacher:	.db "(2",Lpi,"*.95)/sin 13",0
txt_teacherans:	.db Lneg,"14.2063168184",0

;---------------------------- save data -------------------------------------

PutWhere	.dw GRAPH_MEM		;where to put the wide sprites
laserlasts	.db 5

storehi_start:
hiscore		.dw $0000
hiname		.db "Shiar.97",0
storehi_end:

storesave_start:
level		.db $01			;level number
levelp		.dw XLlevelsdata	;pointer to level data
pickuptimer	.db $04			;counts when to place a pickup
score		.dw $0000

your_pickup	.db $00
your_occ	.db $00			;0=normal 1..16=exploding
your_inv	.db $00			;invincibility left
your_armor	.db $0a			;HP left
your_lives	.db $03			;

your_weapon	.db $02			;weapon: 0=no, 1=laser, 2+=bullet n+1
your_multiples	.db $00			;multiples present
torp_occ	.db $00			;torp.state: 0=unavail 1=avail 2=presnt
torp_pos	.dw $0000		;torpedo position (x,y)
storesave_end:


;XLlevelsdata:---------------------------------------------------------------
XLlevelsdata:

	.db 0
	.db $21,$1d,"Cosmic year 6716"		,0,0,$1d,$06
	.db $1b,$1d,"storyline coming soon..."	,0,0,$1d,$06
	.db $09,$19,"the Nemesis saga continues",0,1
	.db $2e,$21,"with NEMESIS 86"		,0,1
	.db $52,$36,"by Shiar"			,0,0,$19,$23
	.db $ff

;format:[enemy nr] [enemy frequency] [next lvl]
;	[level_info: 0000:damage 0:directfire 0:ground 0:ceiling 0:diagfire]
;	[level_move] [level_fire] [tunnel size] [groundtype] [16_ground]
;	[16_ceiling] [stars1] [stars2]

	.db $15,$07,$08			;fireFreq; moveType; enemyType
level01:				;efrequency must be odd if halfluring!
	.db $01,$1b,$2f,%00010001,0,255,0,0 ;0f>>2f		; 7
	.db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1			;16
	.db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1			;16
	.db 1,1							; 2
	.db $10,$07,$09						; 3

	.db 0
	.db $01,01,"And the storyline conti",
		.db "nues.....",0,1
	.db $01,09,"You decide to fly close",
		.db " to the",0,1
	.db $01,15,"surface of a nearby pl",
		.db "anet =)",0,0,1,20
	.db $FF

	.db $10,$07,$09						; 3
level02:							;44
	.db $02,$13,$4b,%00100101,0,064,0,0
	.db 1,2,3,4,5,6,6,5,4,3,4,5,4,3,2,1
	.db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
	.db 1,1
	.db $0E,$07,$09

	.db 0
	.db $01,01,"Blablabla...",0,1
	.db $01,34,"this storyline sux",0,0,1,39
	.DB $FF

	.db $0E,$07,$09
level03:
	.db $03,$2d,$3f,%00010110,0,255,-9,1
	.db 3,2,4,3,2,2,1,1,1,1 ,1,1,21,17,18,20
	.db 1,1,1,1,1,1,1,3,6,12,9,1,21,19,18,18
	.db -1,-1

	.db $0D,$07,$08
level04:
	.db $04,$11,$41,%00100001,0,057,0,0
	.db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
	.db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
	.db 1,1
	.db $0C,$07,$09
level05:
	.db $05,$11,$45,%00100101,%10,031,-7,1
	.db 14,12,11,9,10,7,7,5,4,3,4,4,2,3,1,2
	.db 1, 1, 1, 1,1, 1,1,1,1,1,1,1,1,1,1,1
	.db 1,1
	.db $0B,$07,$08
level06:
	.db $06,$19,$3a,%00100111,0,255,-4,1
	.db 20,22,18,15,9,1,1,1,1,1,1,1,1,1,1,1
	.db 20,22,18,15,9,1,1,1,1,1,1,1,1,1,1,1
	.db 1,1

	.db $08,$07,$09
level07:
	.db $07,$09,$ff,%00100001,0,043,0,0
	.db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
	.db 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
	.db 1,1

;XLenemytable:---------------------------------------------------------------
XLbullettable:
	.db (spr_bullet01-spr_bullet01) ;0
	.db (spr_bullet01-spr_bullet01) ;4
	.db (spr_bullet02-spr_bullet01) ;8
	.db (spr_bullet02-spr_bullet01) ;12
	.db (spr_bullet03-spr_bullet01) ;16
	.db (spr_bullet03-spr_bullet01) ;20
	.db (spr_bullet03-spr_bullet01) ;24
	.db (spr_bullet04-spr_bullet01) ;28
	.db (spr_bullet04-spr_bullet01) ;32
	.db (spr_bullet04-spr_bullet01) ;36
	.db (spr_bullet05-spr_bullet01) ;40
	.db (spr_bullet05-spr_bullet01) ;44
	.db (spr_bullet05-spr_bullet01) ;48
	.db (spr_bullet06-spr_bullet01) ;52
	.db (spr_bullet06-spr_bullet01) ;56
	.db (spr_bullet06-spr_bullet01) ;60

XLenemytable:
	.db $00				;00
	.db (spr_enemy01-spr_enemy00)/2	;01
	.db (spr_enemy02-spr_enemy00)/2	;02
	.db (spr_enemy03-spr_enemy00)/2	;03
	.db (spr_enemy04-spr_enemy00)/2	;04
	.db (spr_enemy05-spr_enemy00)/2	;05
	.db (spr_enemy06-spr_enemy00)/2	;06
	.db (spr_enemy07-spr_enemy00)/2	;07
	.db (spr_boss01 -spr_enemy00)/2	;08
	.db (spr_boss02 -spr_enemy00)/2	;09
	.db (spr_enemy08-spr_enemy00)/2	;0A
	.db (spr_enemy00-spr_enemy00)/2	;0B
	.db (spr_enemy00-spr_enemy00)/2	;0C
	.db (spr_enemy00-spr_enemy00)/2	;0D
	.db (spr_enemy00-spr_enemy00)/2	;0E
	.db (spr_enemy00-spr_enemy00)/2	;0F

;XLenemyinfos:---------------------------------------------------------------
XLenemyinfos:

;format: [000000:HP 00:occ] [HP64] [appearance(ypos)] [unused]

	.db %00100110,0,1,1	;#1	HP:1 	app:random
	.db %00101010,0,2,3	;#2	HP:1 	app:halflure
	.db %00001111,0,3,2	;#3	HP:1 	app:lure

	.db %00000110,0,4,2	;#4	HP:2 	app:lure
	.db %00000111,0,5,3	;#5	HP:2 	app:random	moving
	.db %00001011,0,6,2	;#6	HP:3	app:lure	moving

	.db %00011011,0,7,3	;#7	HP:7	app:halflure	moving

	.db %00110011,1,8,1	;boss1
	.db %00111011,0,9,3	;boss2

	.db %00000000,0,0,0
	.db %00000000,0,0,0
	.db %00000000,0,0,0
	.db %00000000,0,0,0
	.db %00000000,0,0,0
	.db %00000000,0,0,0
	.db %00000000,0,0,0

;XLsprenemies:---------------------------------------------------------------
XLsprenemies:

spr_enemy00:
	.db 8,8				;pickup
	.db %00011000			;    ██
	.db %00011000			;    ██
	.db %00011000			;    ██
	.db %11111111			; ████████
	.db %11111111			; ████████
	.db %00011000			;    ██
	.db %00011000			;    ██
	.db %00011000			;    ██

spr_enemy01:
	.db 6,6				;enemy type one
	.db %00111100			;   ████
	.db %01110000			;  ███
	.db %11110000			; ████
	.db %11110000			; ████
	.db %01110000			;  ███
	.db %00111100			;   ████
spr_enemy02:
	.db 8,6				;enemy type two
	.db %00111111			;    █████
	.db %01111000			;  ████
	.db %11111100			; ██████
	.db %11111100			; ██████
	.db %01111000			;  ████
	.db %00111111			;    █████
spr_enemy03:
	.db 6,6				;enemy type three
	.db %01111100			;  █████
	.db %11110000			; ████
	.db %11111000			; █████
	.db %11111000			; █████
	.db %11110000			; ████
	.db %01111100			;  █████
spr_enemy04:
	.db 6,6				;enemy type four
	.db %00111000			;   ███
	.db %01111100			;  █████
	.db %11111000			; █████
	.db %11111000			; █████
	.db %01111100			;  █████
	.db %00111000			;   ███
spr_enemy05:
	.db 7,6				;enemy type five
	.db %00011110			;    ████
	.db %01111110			;  ██████
	.db %11111100			; ██████
	.db %11111100			; ██████
	.db %01111110			;  ██████
	.db %00011110			;    ████
spr_enemy06:
	.db 7,6				;enemy type six
	.db %00011100			;    ███
	.db %01111110			;  ██████
	.db %10111000			; █ ███
	.db %10111000			; █ ███
	.db %01111110			;  ██████
	.db %00011100			;    ███
spr_enemy07:
	.db 8,6				;enemy type seven
	.db %00011110			;    ████
	.db %01111111			;  ███████
	.db %10011100			; █  ███
	.db %10011100			; █  ███
	.db %01111111			;  ███████
	.db %00011110			;    ████

spr_boss01:
	.db 16,10			;boss type one
	.db %00000001,%11111111		;        █████████
	.db %00001111,%11111110		;     ███████████
	.db %00111111,%11110000		;   ██████████
	.db %01011111,%10000000		;  █ ██████
	.db %10011111,%01000000		; █  █████ █
	.db %10011111,%01000000		; █  █████ █
	.db %01011111,%10000000		;  █ ██████
	.db %00111111,%11110000		;   ██████████
	.db %00001111,%11111110		;     ███████████
	.db %00000001,%11111111		;        █████████
spr_boss02:
	.db 16,10			;boss type:one   :
	.db %11111110,%00000000		; ███████
	.db %00001111,%10001111		;     █████   ████
	.db %00111111,%11100011		;   █████████   ██
	.db %01001111,%11111110		;  █  ███████████
	.db %10001101,%01111100		; █   ██ █ █████
	.db %10001101,%01111100		; █   ██ █ █████
	.db %01001111,%11111110		;  █  ███████████
	.db %00111111,%11100011		;   █████████   ██
	.db %00001111,%10001111		;     █████   ████
	.db %11111110,%00000000		; ███████


spr_enemy08:
	.db 8,6		;enemy type eight
	.db %00011110	;    ████
	.db %01111111	;  ███████
	.db %10011100	; █  ███
	.db %10011100	; █  ███
	.db %01111111	;  ███████
	.db %00011110	;    ████

;----------------------------------------------------------------------------
;----------------------------- logo ------------------------------------------
;----------------------------------------------------------------------------

logo_nemesis:
.db %11111111,%11111111,%11111111,%11111110,%11111111,%11110111,%11111111,%11111110,%11111111,%111101111,%11111111,%00001011,%11111111,%11111111,%11111111,%11111000
.db %01111111,%11111111,%11111111,%11111110,%11111111,%11110111,%11111111,%11111110,%11111111,%111101111,%11111111,%00011011,%11111111,%11111111,%11111111,%11110000
.db %00111111,%11111111,%11111111,%11111110,%11111111,%11110111,%11111111,%11111110,%11111111,%111101111,%11111111,%00111011,%11111111,%11111111,%11111111,%11100000
.db %00011111,%11111111,%11111111,%11111110,%11111111,%11110111,%11111111,%11111110,%11111111,%111101111,%11111111,%01111011,%11111111,%11111111,%11111111,%11000000
.db %00000000,%00000000,%00000001,%00011110,%00010000,%00000000,%10000001,%00011110,%00010000,%000000001,%00000000,%00001000,%01000000,%00000000,%00000000,%00000000
.db %00000000,%00000000,%00000011,%00011110,%00110000,%00000001,%10000011,%00011110,%00110000,%000000011,%00000000,%00011000,%11000000,%00000000,%00000000,%00000000
.db %00000000,%00000000,%00000111,%00011110,%01110000,%00000011,%10000111,%00011110,%01110000,%000000111,%00000000,%00111001,%11000000,%00000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11111111,%00000111,%10001111,%00011110,%11111111,%000001111,%11111111,%01111011,%11111111,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11111111,%00000111,%10001111,%00011110,%11111111,%000001111,%11111111,%01111011,%11111111,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11111111,%00000111,%10001111,%00011110,%11111111,%000001111,%11111111,%01111011,%11111111,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11111111,%00000111,%10001111,%00011110,%11111111,%000001111,%11111111,%01111011,%11111111,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11110000,%00000111,%10001111,%00011110,%11110000,%000000000,%00001111,%01111000,%00000011,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11110000,%00000111,%10001111,%00011110,%11110000,%000000000,%00001111,%01111000,%00000011,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11110000,%00000111,%10001111,%00011110,%11110000,%000000000,%00001111,%01111000,%00000011,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11110000,%00000111,%10001111,%00011110,%11110000,%000000000,%00001111,%01111000,%00000011,%11000000,%00000000,%00000000
.db %00000000,%00000000,%00001111,%00011110,%11111111,%11110111,%10001111,%00011110,%11111111,%111101111,%11111111,%01111011,%11111111,%11000000,%00000111,%11010001
.db %00000000,%00000000,%00001111,%00011110,%11111111,%11110111,%10001111,%00011110,%11111111,%111101111,%11111111,%01111011,%11111111,%11000000,%00000001,%00011011
.db %00000000,%00000000,%00001111,%00011110,%11111111,%11110111,%10001111,%00011110,%11111111,%111101111,%11111111,%01111011,%11111111,%11000000,%00000001,%00010101
.db %00000000,%00000000,%00001111,%00011110,%11111111,%11110111,%10001111,%00011110,%11111111,%111101111,%11111111,%01111011,%11111111,%11000000,%00000001,%00010001

;----------------------------- end ------------------------------------------

	.end
.end


;----------------------------------------------------------------------------
;----------------------------------------------------------------------------
;----------------------------------------------------------------------------

; 0.95.A22 -- 22.X.99 -- size 5321
;
;	* total size of enemy-sprites can now be 510 bytes (space = doubled!)
;	# bullets hit enemies correctly that aren't 6x6; even the 16x10 bosses!
;	* at g/o or nextlevel checks for keys released instead of waiting abit
;	+ name stored with hiscore (max. 8 chars, Shiar.95 by default)
;	+ when entering hi-name DEL goes back one char (with check 4 no chars)
;	# program is reloaded at start so some score-bugs solved! (_asapvar=0)
;	* at death, upgrades and pickups AREN'T removed! (just armor=0)
;	# bullet is not displayed after being removed anymore
;	# armor-icon stays hilighted when armor is decreased
;	* when stars move off screen, they are placed at a NEW y-pos!
;	* the starting x-positions of stars are not random, so the stars are
;	  spread all over screen. y is still random and changes during game
;	* make_random functions smaller and used by different procs
;	# MAJOR BUG! a "random" value was placed somewhere in mem thus
;	  creating bugs like unexplained loss of armor and stuff! (I think)
;
; 0.96.A31 -- 31.X.99 -- size 4836 + 888
;
;	# if you were hit when armor-icon selected, prog did weird stuff
;	+ armor-bar (shows armor as a black line left at bottom)
;	# bugs involving armor-bar changing armor to a wrong value
;	# YES!!! the saving-bugs were caused by mmldir: it reset all data
;	  at mem $8000, so data is now stored at asmexecram+6000 instead!
;	* external levels. All leveldata is loaded from "nemesis0"-var
;	* some optimization (like cal\ret>jp + unused code removed/shortened)
;	* storyline is loaded from level-file (will be compressed later..)
;	+ story can be _between_ levels, not only at the start of a new game
;	* "new game" and "continue" in main menu are swapped (new comes 1st)
;	* enemy bullets can do more than one damage: differs per level
;	* collision does 4 damage, ground does 5, you start with 12 armor
;	# running the level-file no longer crashes your calc but just returns
;	* you now move 1.5 pixels per frame! this way you can outrun enemies
;	* hellofajob but enemy-data is now stored at one location in 6 bytes,
;	  instead of two 4-byte spaces 40 bytes apart! (cleaner code; faster)
;	* ground/ceiling/stars are continued when at boss (c00l level 3 boss)
;
; 0.97.622 -- 06.VI.99 -- size 5kb
;
;	# bullets do damage in all levels
;	* more armor at armor-upgrade and extra armor at end of a level
;	- internal levels again (no need 4 external, safer/smaller)
;	# some registers not correctly pushed/popped
;	* several optimizations (init.procs some bytes smaller)
;	+ bullets "charge up" (more damage) when not firing
;	+ more powerful bullets have different sprites (larger=more damage)
;
;
;	 + added	- removed	* changed	# bug fixed