.include "asm86.h"
	.include "ti86asm.inc"
	.include "ti86abs.inc"

	.org _asm_exec_ram

	nop
	jp  Start
	.dw $0001
	.dw Title
	.dw spr_ship
Title:	.db "Nemesis v0.5.725 by Shiar",0
Start:
	jr init

just_fired	= $c0f9		;byte
temp1		= $c100		;word

;---------------------- init --------------------------------------------------

init:
	call _runindicoff

;---------------------- main menu ---------------------------------------------

;---------------------- game setup --------------------------------------------

play_game:
	call Next_level

;------------------------------------------------------------------------------
;---------------------- game loop ---------------------------------------------
;------------------------------------------------------------------------------

game_main_loop:
	ld  hl,timer		;update time
	inc (hl)

Clear_screen:
	xor a
	ld  hl,GRAPH_MEM+(16*12)
	ld  b,a
clearloop:
	ld  (hl),a
	inc hl
	ld  (hl),a
	inc hl
	ld  (hl),a
	inc hl
	djnz clearloop

check_exitkey:
	ld  a,%00111111		;<exit> pressed?
	out (1),a
	nop
	nop
	in  a,(1)
	bit 6,a
	jr  z,quit		;yes: quit game

game_stuff:
	call Level_event	;insert enemies
	call Handle_Ship	;move you
	call Fire_bullet	;check for fire
	call Handle_enemies	;move enemies
	call Handle_bullets	;move your bullets
	call Enemy_bullets	;move enemy bullets
	call Enemies_hit	;check for collision with enemies

	call Display_Screen	;display all
	halt \ halt \ halt	;delay
	jr   game_main_loop	;loop

quit:	ret

;---------------------- display -----------------------------------------------

Display_Screen:
	ld  a,64		;Display Image
	ld  hl,GRAPH_MEM+(16*12)
	ld  de,$fc00
displayloop:
	ld  bc,12
	ldir
	inc de
	inc de
	inc de
	inc de
	dec a
	jr  nz,displayloop

	ld  hl,$1006		;Display Score
	ld  (_curRow),hl
	ld  hl,(timer)
	ld  h,0
	jp  _D_HL_DECI
	ret

;------------------------- handle ship ----------------------------------------

Handle_Ship:
	ld  a,(your_occ)
	or  a
	jr  z,ok		;0 = normal stat

	inc a			;next (explosion)frame
	ld  (your_occ),a	;save

	cp  34			;last explosion frame?
	jr  c,exploding_you	;not yet: display explosion
	cp  54			;delay finished?
	jp  z,game_over		;yes = game over
	ret			;don't display anything

ok:
	ld  a,%01111110
	out (1),a
	ld  hl,y
	in  a,(1)
	rra
	ld  b,a

	jr  c,no_down
	ld  a,(hl)
	inc a
	cp  73			;y < 73
	jr  z,no_down
	ld  (hl),a
no_down:
	dec hl
	rr  b
	jr  c,no_left
	ld  a,(hl)
	dec a
	jr  z,no_left		;x > 0
	ld  (hl),a
no_left:
	rr b   
	jr  c,no_right
	ld  a,(hl)
	inc a
	cp  89			;x < 89
	jr  z,no_right
	ld  (hl),a
no_right:
	ld d,(hl)
	inc hl
	rr  b
	jr  c,no_up
	ld  a,(hl)
	dec a
	cp  15			;y > 15
	jr  z,no_up
	ld  (hl),a
no_up:	ld  ix,spr_ship01

display_common:
	ld  e,(hl)
	jp  drw_spr		;ret

exploding_you:
	srl a			;half the framerate
	dec a			;first frame is 1>inc>srl>dec = 0
	ld  hl,x-1

explosion_stuff:
	rra
	add a,a
	add a,a
	add a,a
	ld  c,a
	ld  b,0
	ld  ix,spr_explosion
	add ix,bc
	inc hl
	ld  d,(hl)
	inc hl
	jr  display_common

damage_you:
	ld  a,1			;set to explode (1st frame)
	ld  (your_occ),a
	ret

;------------------------- fire bullet ----------------------------------------

Fire_bullet:
	ld  a,%00111111
	out (1),a
	ld  a,(your_occ)
	or  a
	ret nz			;return if not normal stat
	ld  hl,just_fired
	in  a,(1)
	bit 4,a
	jr  z,fire		;fire pressed?
	ld  (hl),0		;not fired
	ret

fire:	ld  a,(hl)
	or  a			;can't fire when 1
	ret nz
	ld  (hl),1		;just fired

	ld  hl,ybullets
	ld  de,3
	ld  b,10
find_ybullet:
	ld  a,(hl)
	or  a
	jr  z,found_ybullet	;0 = no bullet here
	add hl,de
	djnz find_ybullet	;look next bullet
	ret

found_ybullet:
	ld  (hl),1		;use bullet
	inc hl
	ld  a,(x)
	add a,5
	ld  (hl),a		;set x
	ld  a,(y)
	add a,2
	inc hl
	ld  (hl),a		;set y
	ret

;------------------------ handle bullets --------------------------------------

remove_bullet:
	dec hl
	ld  (hl),0		;dump this bullet!
	ret

Handle_bullets:
	ld  hl,ybullets
	ld  b,10
scan_bullets:
	push bc
	push hl
	ld  (temp1),hl
	ld  a,(hl)
	inc hl
	dec a
	call z,bullet_type1
	pop hl
	pop bc
	ld  de,3
	add hl,de
	djnz scan_bullets
	ret

bullet_type1:
	ld  a,(hl)		;d = X
	inc a			;move right
	cp  $5a			;off screen?
	jr  z,remove_bullet
	inc a			;move right
	cp  $5a			;off screen?
	jr  z,remove_bullet
	ld  (hl),a		;save new pos.
	ld  d,a
	inc hl
	ld  e,(hl)		;e = Y
	ld  ix,spr_bullet01
	push de
	call drw_spr		;display bullet
	pop de
	ld  b,nrenemies
	ld  hl,enemies

hit_enemies:			;Hits with normal enemies
	push hl

	ld  a,(hl)
	and %00000010
	jr  z,nohit		;no hit when enemy_occ <> 2/3

	inc hl
	inc hl
	ld  a,(hl)		;check x
	sub d
	add a,5
	jp  m,nohit
	cp  8
	jr  nc,nohit

	inc hl
	ld  a,(hl)		;check y
	sub e
	add a,5
	jp  m,nohit
	cp  10
	jr  nc,nohit

	xor a
	push hl
	ld  hl,(temp1)
	ld  (hl),a		;remove bullet
	pop hl

	dec hl
	dec hl
	dec hl
	ld  a,(hl)		;occ
	ld  b,a			;push occ
	srl a
	srl a			;occ/4 = HP left
	jr  nz,hpleft
	ld  (hl),$01		;set to explode
	inc hl
	ld  (hl),a		;explosionFrame 0
	pop hl
	ret

hpleft:
	ld  a,b			;pop occ
	sub %00000100		;decrease HP by one
	ld  (hl),a		;save
	pop hl
	ret

nohit:	pop hl
	inc hl
	inc hl
	inc hl
	inc hl
	djnz hit_enemies	;check next enemy
	ret

;--------------------------- level events -------------------------------------

Level_event:
	ld  a,(nextevent)
	dec a
	ld  (nextevent),a
	or  a
	ret nz

do_event:
	ld  hl,(curevent)
	ld  de,enemies-4
chk_noenemy:
	inc de
	inc de
	inc de
	inc de
	ld  a,(de)
	or  a			;0 = no enemy present
	jr  nz,chk_noenemy

	ld  a,(hl)		;type
	ld  hl,enemy01
	ld  c,a
	ld  b,0
	add hl,bc
	add hl,bc
	add hl,bc		;hl = enemy specs
	ld  a,(hl)		;load hitpoints+occ of this enemy class
	ld  (de),a		;occ

	inc hl
	inc de
	ld  a,(hl)		;load movement+type of this enemy class
	ld  (de),a		;type

	inc de
	ld  a,$5a		;appear at right edge of screen
	ld  (de),a		;x
	inc de

	ld  hl,(curevent)
	inc hl
	ld  a,(hl)
	ld  (de),a		;y

	inc hl			;@ next event
	ld  a,(hl)
	cp  $ff			;255 = end marker
	jp  z,Next_level
	ld  (nextevent),a	;else time to next event

	inc hl
	ld  (curevent),hl	;update pointer

	or  a			;no delay
	jr  z,do_event
	ret			;no more events for now

;--------------------------- enemy fires --------------------------------------

Enemy_fires:			;de = x,y
	dec d
	dec d			;d = x-2
	inc e			;e = y+1

	ld  b,10
	ld  hl,ebullets
find_ebullet:
	ld  a,(hl)
	or  a
	jr  z,found_ebullet	;0 = not used
	inc hl
	inc hl
	inc hl
	djnz find_ebullet	;look next bullet
	ret

found_ebullet:
	ld  (hl),1		;use bullet
	inc hl
	ld  (hl),d		;set x-pos
	inc hl
	ld  (hl),e		;set y-pos
	ret         

;----------------------------- enemy bullets ----------------------------------

Enemy_bullets:
	ld  hl,ebullets
	ld  b,10
handle_bullet:
	push bc
	push hl
	ld  a,(hl)
	or  a
	jr  nz,enemy_bullet
next_bullet:
	pop hl
	pop bc
	inc hl
	inc hl
	inc hl
	djnz handle_bullet
	ret

enemy_bullet:
	inc hl
	ld  a,(hl)		;bullet x
	dec a
	jp  m,remove_ebullet	;off screen?
	jr  z,remove_ebullet	;"
	dec a			;move left
	ld  (hl),a
	ld  d,a			;d=x
	inc hl
	ld  e,(hl)		;e=y
	ld  ix,spr_bullet11	;display enemy bullet
	call drw_spr

	ld  a,(your_occ)
	or  a
	jr  nz,next_bullet	;0 = you're normal

	pop hl
	push hl
	inc hl			;check x
	ld  a,(x)
	sub (hl)
	add a,6
	jp  m,next_bullet
	cp  9
	jr  nc,next_bullet

	inc hl			;check y
	ld  a,(y)
	sub (hl)
	add a,6
	jp  m,next_bullet
	cp  9
	jr  nc,next_bullet

	call damage_you		;HIT!!
remove_ebullet:
	dec hl
	ld   (hl),0		;bullet > unused
	jr   next_bullet

;--------------------------- handle enemies -----------------------------------

Handle_enemies:
	ld  hl,enemies
	ld  b,nrenemies		;loop 20x

handle_enemy:
	push bc
	push hl

	ld  a,(hl)
	and %00000011
	jr  z,next_enemy	;occ "no enemy" 0
	dec a
	jr  z,exploding_enemy	;occ "exploding" 1
	ld  b,1
	dec a
	jr  z,normal_enemy	;occ "normal" 2

moving_enemy:			;occ "moving" 3
	ld  b,0

normal_enemy:
	inc hl
	ld  a,(hl)		;type
	and %11100000		;move-type
	add a,b			;add move bit from occ
	ld  b,a			;save in b
	ld  a,(hl)		;type
	add a,a
	add a,a
	add a,a
	ld  c,a			;type*8 = offset

	inc hl
	ld  a,(hl)		;x
	dec a			;move left
	jp  m,remove_enemy	;off screen
	jr  z,remove_enemy	;"
	ld  d,a

	inc hl
	ld  e,(hl)		;y
	ld  a,b			;%xxx00001=moving -0=normal
	dec a
	jr  z,ymove_done	;skip y-move

;	srl a
;	ld  b,a			;b = %0xxx0000 (move stat)
	ld  a,(timer)
	and %00010000		;switches 0<>1 every 16 turns
;	add a,b			;a = new move stat
;	add a,a
;	ld  b,a			;b = %xxx00000 (new move stat*2)

;	dec hl \ dec hl
;	ld  a,(hl)		;type
;	and %00011111		;reset move-type
;	add a,b			;set new move-type
;	ld  (hl),a
;	inc hl \ inc hl		;@y

;	and %00100000
	jr  z,movedown
moveup:	dec (hl)		;decrease y-pos
	jr ymove_done
movedown:
	inc (hl)		;increase y-pos

ymove_done:
	dec hl			;@x
	ld  (hl),d		;store new x
	ld  ix,spr_enemy01
	ld  b,$00
	add ix,bc

;	push hl			;save registers
	push de
	call drw_spr		;display
	pop  de			;restore (destroyed by drw_spr)
;	pop  hl

;	dec hl
;	ld  b,(hl)		;type
;	and %00011111		;enemy class
;	ld  hl,enemy01		;all enemies' specs
;	inc b			;next enemy's specs
;	ld  c,$00
;	add hl,bc
;	add hl,bc
;	add hl,bc		;go there
;	dec hl			;last byte of this enemy's specs

	ld  a,$ff		;fire frequency
	call Random		;random value < a
	dec a			;fire if 1
	call z,Enemy_fires	;fires bullet
	jr   next_enemy

remove_enemy:
	pop hl
	ld  (hl),$0000		;bye bye enemy
	push hl
next_enemy:
	pop hl
	ld  bc,$0004
	add hl,bc
	pop bc
	djnz handle_enemy
	ret

exploding_enemy:
	inc  hl
	push hl
	ld   a,(hl)
	call explosion_stuff	;display explosion
	pop  hl

	ld  a,(hl)
	cp  15
	jr  z,remove_enemy	;remove when at last frame
	inc a
	ld  (hl),a		;next frame
	jr  next_enemy

;--------------------------- check collision ----------------------------------

Enemies_hit:
	ld  a,(your_occ)
	or  a			;0 = you're normal
	ret nz

	ld  de,(x)		;e = X, d = Y
	ld  hl,enemies
	ld  b,nrenemies		;check all 20 enemies
check_collision:
	push hl
	ld  a,(hl)
	and %00000010
	jr  z,check_next	;2/3 = ok

	inc hl
	inc hl
	ld  a,(hl)		;check x match
	sub e
	add a,6
	jp  m,check_next
	cp  12
	jr  nc,check_next

	inc hl
	ld  a,(hl)		;check y match
	sub d
	add a,6
	jp  m,check_next
	cp  12
	jr  nc,check_next

	dec hl
	dec hl
	xor a
	ld  (hl),a		;explosionFrame 0
	dec hl
	inc a
	ld  (hl),a		;set to explode
	call damage_you		;auch!

check_next:
	pop hl
	inc hl
	inc hl
	inc hl
	inc hl
	djnz check_collision
	ret

;--------------------------- next level ---------------------------------------

Next_level:
	ld  hl,Leveldata+1	;reset level data
	ld  (curevent),hl

	call _clrLCD		;clear screen
	ld  hl,$0703
	ld  (_curRow),hl	;center
	ld  hl,txt_level
	call _puts		;display "LEVEL "

	ld  a,(level)
	inc a			;increase level nr.
	ld  (level),a
	ld  l,a
	ld  h,$00

	call UNPACK_HL
	add a,'0'
	ld  b,a
	call UNPACK_HL
	add a,'0'
	call _putc		;display second digit
	ld  a,b
	call _putc		;display first digit

	ld  b,$20
wait:	halt \ halt
	djnz wait		;delay
	call _getkey		;wait for keypress
	jr  game_setup		;prepare display and vars
	ret

;--------------------------- game over ----------------------------------------

game_over:
	ld  hl,Leveldata+1	;reset level data
	ld  (curevent),hl

	call _clrLCD		;clear screen
	ld  hl,$0603
	ld  (_curRow),hl	;center
	ld  hl,txt_gameover
	call _puts		;display "GAME OVER"

	ld  b,$20
wait2:	halt \ halt
	djnz wait2		;delay
	call _getkey		;wait for keypress
	jr  game_setup		;prepare display and vars
	ret

;---------------------- setup game --------------------------------------------

game_setup:
	call _clrLCD
	ld  hl,$1005
	ld  (_curRow),hl
	ld  hl,txt_score	;display "SCORE"
	call _puts			;display texts

	xor a
	ld  (timer),a			;reset time
	ld  (level),a			;level 1
	ld  hl,Leveldata+1
	ld  (curevent),hl		;reset level
	ld  hl,(Leveldata)
	ld  (nextevent),hl
					;ret
;---------------------- exit --------------------------------------------------

exit_game:
	ret

;--------------------------- putsprite ----------------------------------------

offsets_table:
	.db 128,64,32,16,8,4,2,1
drw_spr:
	ld  a,d
	and 7
	ld  hl,offsets_table
	ld  c,a
	ld  b,0
	add hl,bc
	ld  a,(hl)
	ld  (_smc1+1),a

	ld  (_smc1+1),a
	ld  hl,GRAPH_MEM
	ld  a,e
	add a,a
	add a,e
	add a,a
	rl  b
	add a,a
	rl  b
	srl d
	srl d
	srl d
	add a,d
	jr  nc,_n1
	inc b
_n1:	ld  c,a
	add hl,bc
          
	ld  d,(ix)
	ld  b,(ix+1)
_oloop:	push bc			;Save # of rows
	push hl			;Save screen address
	ld  b,d			;Load width
	ld  c,(ix+2)		;Load one line of image
	inc ix
_smc1:	ld  a,1			;Load pixel mask
_iloop:	sla c			;Test leftmost pixel
	jr  nc,_noplot		;See if a plot is needed
	ld  e,a			;OR pixel with screen
	or  (hl)
	ld  (hl),a
	ld  a,e
_noplot: rrca
	jr  nc,_notedge		;Test if edge of byte reached
	inc hl			;Go to next byte
_notedge:djnz _iloop
	pop hl			;Restore address
	ld  bc,12		;Go to next line
	add hl,bc
	pop bc			;Restore data
	djnz _oloop
	ret

;---------------------- random ------------------------------------------------

Random: 	       ; Creates a random number 0 <= x < A
 push bc
 push de
 push hl
 ld b,a
 ld a,r
 add a,a
 ld hl,0
 ld d,0
 ld e,a
RMul:
 add hl,de
 djnz RMul
 ld a,h
 pop hl
 pop de
 pop bc
 ret

;------------------------

_D_HL_DECI:
         push     bc
         ld       de,up_data+4
         ld       b,5
ldhld:   call     UNPACK_HL
         add      a,'0'
         ld       (de),a
         dec      de
         djnz     ldhld
         ld       hl,up_data
         ld       b,4
lis:     ld       a,(hl)
         cp       '0'
         jr       nz,dis
         ld       (hl),' '
         inc      hl
         djnz     lis
dis:     ld       hl,up_data
         call     _puts
         pop      bc
         ret

up_data: .db      "PAD98",0



;------------------------------- sprites --------------------------------------

spr_ship:
	.db 9,1		;ship icon
	.db %11100000	; ███
	.db %11111000	; █████
	.db %00111110	;   █████
	.db %11111001	; █████  █
	.db %11111101	; ██████ █
	.db %11111001	; █████  █
	.db %00111110	;   █████
	.db %11111000	; █████
	.db %11100000	; ███

spr_ship01:
	.db 7,7		;ship alpha class
	.db %01110000	;  ███
	.db %11100000	; ███
	.db %11111100	; ██████
	.db %11110010	; ████  █
	.db %11111100	; ██████
	.db %11100000	; ███
	.db %01110000	;  ███
spr_ship02:
	.db 7,7		;ship beta class
	.db %11000000	; ██
	.db %11110000	; ████
	.db %01111100	;  █████
	.db %01110010	;  ███  █
	.db %01111100	;  █████
	.db %11110000	; ████
	.db %11000000	; ██

spr_bullet01:
	.db 5,3		;your bullets
	.db %00110000	;   ░▒▓██
	.db %11111000	; ░▒▓█████
	.db %00110000	;   ░▒▓██
spr_bullet02:
	.db 5,3		;your bullets
	.db %11110000	; ░▒▓████
	.db %11111000	; ░▒▓█████
	.db %11110000	; ░▒▓████

spr_bullet11:
	.db 3,3		;enemy bullets
	.db %01000000	;  █▓▒░
	.db %11100000	; ███▓▒░
	.db %01000000	;  █▓▒░

spr_explosion:                               
	.db 8,6		;1
	.db %00000000
	.db %00011100	;    ███
	.db %00111110	;   █████
	.db %01010110	;  █ █ ██
	.db %00111000	;   ███
	.db %00000000

	.db 8,6		;2
	.db %00110000	;   ██
	.db %01001110	;  █ ▒███
	.db %10111110	; █ █████
	.db %01001111	;  █ ▒████
	.db %00111000	;   ███
	.db %00011010	;    ██ █

	.db 8,6		;3
	.db %10110011	; █ ██  ██
	.db %01001110	;  █  ███
	.db %10110101	; █ ██▒█▒█
	.db %01000101	;  █  ▒█▒█
	.db %00111110	;   █████
	.db %11011010	; ██ ██ █

	.db 8,6		;4
	.db %00101010	; ▒ █▒█ █▒
	.db %01000110	;  █  ▒██
	.db %10110101	; █ ██ █ █
	.db %01100110	;  ██  ██▒
	.db %00111100	;   ████▒
	.db %01011001	; ▒█ ██ ▒█

	.db 8,6		;5
	.db %01000001	;  █▒ ▒ ▒█
	.db %00100101	;  ▒█  █▒█
	.db %00010100	; ▒ ▒█ █ ▒
	.db %01000100	;  █▒  █
	.db %00010010	;   ▒█▒▒█
	.db %10011010	; █▒ ██ █▒

	.db 8,6		;6
	.db %01000100	;  █   █ ▒
	.db %00100000	;   ▒█ ▒ ▒
	.db %00000001	;    ▒ ▒ █
	.db %01000100	;  █   █
	.db %00100010	;   █▒  █
	.db %01001000	; ▒█ ▒█ ▒

	.db 8,6		;7
	.db %00001000	;  ▒  █▒
	.db %11000010	; ██ ▒  █
	.db %00000000	;        ▒
	.db %00100000	;  ▒█  ▒
	.db %00000001	;   ▒   ▒█
	.db %00110000	;  ▒██▒

	.db 8,6		;8
	.db %00000100	;     ▒█
	.db %00000000	; ▒▒    ▒
	.db %01000000	;  █
	.db %00000000	;   ▒
	.db %00000010	;       █▒
	.db %00100100	;   █▒ █

spr_icon01:
	.db 5,4
	.db %00100000	;   █
	.db %10101000	; █ █ █
	.db %11111000	; █████
	.db %01110000	;  ███
spr_icon02:
	.db 5,4
	.db %00000000	;  ███
	.db %00000000	; ██ ██
	.db %00000000	; █   █
	.db %00000000	;

;---------------------------- texts -------------------------------------------

txt_title:	.db "* * NEMESIS * *",0
txt_level:	.db "LEVEL ",0
txt_gameover:	.db "GAME OVER!",0
txt_score:	.db "SCORE",0

;---------------------------- save data ---------------------------------------

stored_data_start:

level		.db $00			;level number
timer		.db $00			;frame counter
curevent	.dw Leveldata+1		;next event
nextevent	.db (Leveldata)		;time to next event

score		.dw $0000

your_occ	.db $00			;0=normal 1..16=exploding
;lives		.dw $0003	;unused
x		.db $16			;x-pos
y		.db $46			;think about it..
hp		.db $00			;hitpoints left

ybullets	.dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0	;10 x (state,x,y)
ebullets	.dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0	;10 x (state,x,y)

nrenemies	= 32
enemies		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000

		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000

; %111111 (HP left) 11 (00=no enemy 01=exploding 10=normal 11=moving)
; %111 (move ptrn) 11111 (ship or explosion frame)  %11111111 (x) %11111111 (y)


;---------------------------- enemy data --------------------------------------

spr_enemy01:
	.db 6,6		;enemy type one
	.db %00111100	;   ████
	.db %01110000	;  ███
	.db %11110000	; ████
	.db %11110000	; ████
	.db %01110000	;  ███
	.db %00111100	;   ████
spr_enemy02:
	.db 6,6		;enemy type two
	.db %00111000	;   ███
	.db %01100000	;  ██
	.db %11111100	; ██████
	.db %11111100	; ██████
	.db %01100000	;  ██
	.db %00111000	;   ███
spr_enemy03:
	.db 6,6		;enemy type three
	.db %01111100	;  █████
	.db %11110000	; ████
	.db %11111000	; █████
	.db %11111000	; █████
	.db %11110000	; ████
	.db %01111100	;  █████
spr_enemy04:
	.db 6,6		;enemy type four
	.db %00111000	;   ███
	.db %01111100	;  █████
	.db %11111000	; █████
	.db %11111000	; █████
	.db %01111100	;  █████
	.db %00111000	;   ███

enemy01:				;HP:1  move:- fire:-
	.db %00000010,%00000000,%00000000		;first two enemy bytes
enemy02:				;HP:1  move:1 fire:1.5%
	.db %00000011,%00100001,%01111111
enemy03:				;HP:2  move:- fire:3%
	.db %00000110,%00000010,%00001111
enemy04:				;HP:5  move:- fire:6%
	.db %00010010,%00000011,%00000011
enemy05:				;HP:10 move:- fire:25%
	.db %00100111,%00000100,%00000011

;---------------------------- level data --------------------------------------

Leveldata:			;time,enemyclass,ypos
	.db $0d,$00,$38			;first wave (bottom)
	.db $00,$00,$40
	.db $00,$00,$48
	.db $1e,$00,$10			;second wave (top)
	.db $00,$00,$18
	.db $00,$00,$20
	.db $1e,$00,$24			;third wave (middle)
	.db $00,$02,$2c
	.db $00,$00,$34

	.db $0d,$00,$10			;top & bottom
	.db $00,$00,$4a
	.db $2a,$01,$2d			;middle: moving
	.db $0c,$02,$2d			;	 3HP
	.db $0b,$02,$2d			;	 3HP
	.db $09,$00,$27			;two 1HP behind him
	.db $00,$00,$33
	.db $09,$02,$21			;two 3HP behind them
	.db $00,$02,$39
	.db $09,$02,$1b			;and two 3HP behind them
	.db $00,$02,$3f

	.db $15,$03,$11			;one vertical line of 8HPs
	.db $00,$03,$19
	.db $00,$03,$21
	.db $00,$03,$29
	.db $00,$03,$31
	.db $00,$03,$39
	.db $00,$03,$41
	.db $00,$03,$49

	.db $0c,$02,$11			;one vertical line of 3HPs
	.db $00,$02,$19
	.db $00,$02,$21
	.db $00,$02,$29
	.db $00,$02,$31
	.db $00,$02,$39
	.db $00,$02,$41
	.db $00,$02,$49

	.db $0c,$00,$11			;one vertical line of 1HPs
	.db $00,$00,$19
	.db $00,$00,$21
	.db $00,$00,$29
	.db $00,$00,$31
	.db $00,$00,$39
	.db $00,$00,$41
	.db $00,$00,$49







	.db $f1,$01,$40
	.db $10,$00,$30
	.db $10,$02,$20
	.db $40,$01,$10
	.db $01,$00,$44
	.db $15,$01,$31
	.db $04,$02,$38
	.db $05,$00,$40
	.db $03,$00,$2f
	.db $04,$00,$3a
	.db $12,$02,$10
	.db $10,$03,$18
	.db $0e,$03,$20
	.db $0c,$03,$28
	.db $0a,$02,$30
	.db $08,$02,$38
	.db $06,$01,$40
	.db $04,$00,$48
	.db $2a,$00,$20
	.db $ff,$ff,$ff

;----------------------------- end --------------------------------------------

	.end
.end




;----------------------------- NEMESIS'86 by Shiar ----------------------------

;----------------------------- version history --------------------------------

;0.01.717 -- 17.VII.99 -- size 984
;
;	+ movement of ship over whole screen
;	+ enemies moving from right to left, appearing right at specified times
;
; 0.1.718 -- 18.VII.99 -- size 907
;
;	# no crash when level restarts for the third time
;	* exit-procedure updated, unnecessary stuff/keychecks removed
;	* alot of unused code removed
;	+ different types of enemies (just look different)
;	+ collision detection!! enemy ships disappear when you hit them
;
; 0.2.718 -- 18.VII.99 -- size 1153
;
;	+ ability to fire bullets (F1). Enemies disappear on impact
;	* enemies explode instead of disappearing
;
; 0.3.719 -- 19.VII.99 -- size 1401
;
;	* bullets appear correctly (not INSIDE your ship)
;	+ some enemies can take multiple hits (differs per class)
;	+ all enemies fire bullets at random
;	+ if you're hit by bullet/enemy, you'll lose one hitpoint
;
; 0.4.720 -- 20.VII.99 -- size 1481
;
;	# collision detection fixed and optimized (much faster now!)
;	+ shell-icon added (YAS type)
;	* code optimizations, some data "compression"
;	* explosion looks better, and some vars removed/smaller
;	# enemies are removed if at left side (instead of becoming invisible)
;	+ displays level number before each level begins
;
; 0.5.725 -- 25.VII.99 -- size 1778
;
;	* waits a sec at level display (in case of accidental keypress)
;	* moving enemies (move up&down)
;	# bullets removed correctly so they can be used again later
;	* first level made
;	# enemy weaponfire is fired from correct positions
;	+ your ship explodes on impact with ships/bullets
;	* game over screen will be displayed just *after* your ship's gone
;	+ frame counter onscreen
;

;	 + added	- removed	* changed	# bug fixed