.include "asm86.h"           
	.include "ti86asm.inc"
	.include "ti86abs.inc"
	.org _asm_exec_ram
	nop
	jp  Start
	.dw $0000
	.dw Title
Title:	.db "Nemesis v0.1.718 by Shiar",0
Start:
	jr init

;-------------------- init ----------------------------------------------------

init:
	call _runindicoff

;-------------------- main menu -----------------------------------------------

	jp play_game

;-------------------- exit ----------------------------------------------------

exit_game:
	ret

;----------------------- game setup -------------------------------------------

play_game:
	ld  hl,stored_data_start
	ld  bc,variables_end-stored_data_start-1

;---------------------- display setup ----------------------------------------

set_up_display:
	call _clrLCD

	ld  hl,in_game_text
	ld  b,3
l11:	ld  a,(hl)
	ld  (_curCol),a
	inc hl
	ld  a,(hl)
	ld  (_curRow),a
	inc hl
	call _puts
	djnz l11

in_game_text:
	.db 16,0,"LIVES",0
	.db 16,3,"LEVEL",0
	.db 16,6,"SCORE",0

str_question:
	.db "-----",0

;------------------------------------------------------------------------------
;-------------------------- game loop -----------------------------------------
;------------------------------------------------------------------------------

game_main_loop:
	ld  hl,timer		;update time
	inc (hl)

Clear_screen:
	xor a
	ld  hl,GRAPH_MEM+(16*12)
	ld  b,a
clearloop:
	ld  (hl),a
	inc hl
	ld  (hl),a
	inc hl
	ld  (hl),a
	inc hl
	djnz clearloop

check_exitkey:
	ld  a,%00111111		;<exit> pressed?
	out (1),a
	nop
	nop
	in  a,(1)
	bit 6,a
	jr  z,quit		;yes: quit game

game_stuff:
	call Level_event	;insert enemies
	call Handle_Ship	;move you
	call Handle_enemies	;move enemies
	call Enemies_hit	;check for collision with enemies

	call Display_Screen	;display all
;	halt \ halt \ halt	;delay
	jr   game_main_loop	;loop

quit:	ret

;---------------------- display -----------------------------------------------

Display_Screen:
	ld  a,64		;Display Image
	ld  hl,GRAPH_MEM+(16*12)
	ld  de,$fc00
displayloop:
	ld  bc,12
	ldir
	inc de
	inc de
	inc de
	inc de
	dec a
	jr  nz,displayloop

;	ld  hl,$1007		;Display Score
;	ld  (_curRow),hl
;	ld  hl,(score)
;	jp  _D_HL_DECI
	ret

;------------------------- handle ship ----------------------------------------

Handle_Ship:
	ld  a,(your_status)
;	bit 4,a
;	jr  nz,you_not_normal
	or  a
	jr  z,ok
;	dec a
;	ld  (your_status),a
;	ld  hl,(lives)
;	ld  a,l
;	or  h
;	jr  nz,ok
;	pop af
;	ret

ok:
	ld  a,%01111110
	out (1),a
	ld  hl,y
	in  a,(1)
	rra
	ld  b,a

	jr  c,no_down
	ld  a,(hl)
	inc a
	cp  73			;y < 73
	jr  z,no_down
	ld  (hl),a
no_down:
	dec hl
	rr  b
	jr  c,no_left
	ld  a,(hl)
	dec a
	jr  z,no_left		;x > 0
	ld  (hl),a
no_left:
	rr b   
	jr  c,no_right
	ld  a,(hl)
	inc a
	cp  89			;x < 89
	jr  z,no_right
	ld  (hl),a
no_right:
	ld d,(hl)
	inc hl
	rr  b
	jr  c,no_up
	ld  a,(hl)
	dec a
	cp  15			;y > 15
	jr  z,no_up
	ld  (hl),a
no_up:	ld  ix,spr_ship

display_common:
	ld  e,(hl)
	jp  drw_spr

;you_not_normal:
;	ld       hl,(score)
;	ld       de,-6
;	add      hl,de    
;	ld       a,255
;	cp       h
;	jr       nz,_ok_
;	ld       hl,0
;_ok_:	ld       (score),hl
;	ld       a,(your_status)
;	dec      a
;	ld       (your_status),a
;	inc      a
;	and      14
;	xor      14
;	ld       hl,x-1

;explosion_stuff:
;	rra
;	add a,a
;	add a,a
;	add a,a
;	ld  c,a
;	ld  b,0
;	ld  ix,spr_explosion
;	add ix,bc
;	inc hl
;	ld  d,(hl)
;	inc hl
;	jr  display_common

;--------------------------- level events -------------------------------------

Level_event:
	ld  a,(nextevent)
	dec a
	ld  (nextevent),a
	or  a
	ret nz

do_event:
	ld  hl,(curevent)	;+1
	ld  de,enemies-4
chk_noenemy:
	inc de
	inc de
	inc de
	inc de
	ld  a,(de)
	or  a
	jr  nz,chk_noenemy

	ld  a,$01
	ld  (de),a	;occ
	inc de

	ld  a,(hl)
	ld  (de),a	;type
	inc de

	ld  a,$5a
	ld  (de),a	;x
	inc de

	inc hl			;+2
	ld  a,(hl)
	ld  (de),a	;y

	inc hl			;+0
	ld  a,(hl)
	cp  $ff
	jp  z,Next_level
	ld  (nextevent),a

	inc hl			;+1
	ld  (curevent),hl
	ret

;--------------------------- handle enemies -----------------------------------

Handle_enemies:
	ld  hl,enemies

handle_enemy:
	push hl

	ld  a,(hl)
	cp  1
	jr  nz,next_enemy

	inc hl
	ld  c,(hl)		;type
	inc hl
	ld  d,(hl)		;x
	inc hl
	ld  e,(hl)		;y

	ld  a,d
	or  a
	jr  z,next_enemy
	dec a
	ld  d,a
	jr  z,remove_enemy

	ld  (hl),e
	dec hl
	ld  (hl),d
	ld  ix,spr_enemy01
	ld  b,$00
	add ix,bc
	call drw_spr
	jr  next_enemy

remove_enemy:
	dec hl
	dec hl
	dec hl
	ld  (hl),$0000

next_enemy:
	pop hl
	inc hl
	inc hl
	inc hl
	inc hl
	ld  a,(hl)
	cp  $ff
	jr  nz,handle_enemy

	ret

;--------------------------- check collision ----------------------------------

Enemies_hit:
	ld  de,(x)		;e = X, d = Y
	ld  hl,enemies-4
check_next:
	inc hl
	inc hl
	inc hl
	inc hl

	ld  a,(hl)
	cp  $ff
	ret z			;-1 = no more enemies
	push hl
	cp  1
	jr  nz,nocrash		;1 = enemy

	inc hl
	inc hl
	ld  a,(hl)		;check x match
	sub e
	add a,6
	jp  m,nocrash
	cp  12
	jr  nc,nocrash

	inc hl
	ld  a,(hl)		;check y match
	sub d
	add a,6
	jp  m,nocrash
	cp  12
	jr  nc,nocrash

	dec hl
	dec hl
	ld  (hl),0
	dec hl
	ld  (hl),2		;set to explode

nocrash:
	pop hl
	jr  check_next

;--------------------------- next level ---------------------------------------

Next_level:
	ld  hl,Leveldata+1
	ld  (curevent),hl
	ret

;--------------------------- putsprite ----------------------------------------

offsets_table:
	.db 128,64,32,16,8,4,2,1
drw_spr:
	ld  a,d
	and 7
	ld  hl,offsets_table
	ld  c,a
	ld  b,0
	add hl,bc
	ld  a,(hl)
	ld  (_smc1+1),a

	ld  (_smc1+1),a
	ld  hl,GRAPH_MEM
	ld  a,e
	add a,a
	add a,e
	add a,a
	rl  b
	add a,a
	rl  b
	srl d
	srl d
	srl d
	add a,d
	jr  nc,_n1
	inc b
_n1:	ld  c,a
	add hl,bc
          
	ld  d,(ix)
	ld  b,(ix+1)
_oloop:	push bc			;Save # of rows
	push hl			;Save screen address
	ld  b,d			;Load width
	ld  c,(ix+2)		;Load one line of image
	inc ix
_smc1:	ld  a,1			;Load pixel mask
_iloop:	sla c			;Test leftmost pixel
	jr  nc,_noplot		;See if a plot is needed
	ld  e,a			;OR pixel with screen
	or  (hl)
	ld  (hl),a
	ld  a,e
_noplot: rrca
	jr  nc,_notedge		;Test if edge of byte reached
	inc hl			;Go to next byte
_notedge:djnz _iloop
	pop hl			;Restore address
	ld  bc,12		;Go to next line
	add hl,bc
	pop bc			;Restore data
	djnz _oloop
	ret



_D_HL_DECI:
         push     bc
         ld       de,up_data+4
         ld       b,5
ldhld:   call     UNPACK_HL
         add      a,'0'
         ld       (de),a
         dec      de
         djnz     ldhld
         ld       hl,up_data
         ld       b,4
lis:     ld       a,(hl)
         cp       '0'
         jr       nz,dis
         ld       (hl),' '
         inc      hl
         djnz     lis
dis:     ld       hl,up_data
         call     _puts
         pop      bc
         ret

up_data: .db      "PAD98",0



;------------------------------- sprites --------------------------------------

spr_ship:
	.db 7,7
	.db %11111000
	.db %11000000
	.db %11111100
	.db %11111110
	.db %11111100
	.db %11000000
	.db %11111000

spr_bullet01:
	.db 5,3
	.db %11110000
	.db %11111000
	.db %11110000

spr_bullet02:
	.db 3,3
	.db %01000000
	.db %11100000
	.db %01000000

spr_enemy01:
	.db 6,6
	.db %00111100
	.db %01110000
	.db %11110000
	.db %11110000
	.db %01110000
	.db %00111100
spr_enemy02:
	.db 6,6
	.db %01111100
	.db %11110000
	.db %10111000
	.db %10111000
	.db %11110000
	.db %01111100

spr_explosion:                               
	.db 8,6
	.db %00000000
	.db %00011100
	.db %00111110
	.db %01010110
	.db %00111000
	.db %00000000

	.db 8,6
	.db %00110000
	.db %01001110
	.db %10111110
	.db %01001111
	.db %00111000
	.db %00011010

	.db 8,6
	.db %11110011
	.db %01001110
	.db %10110101
	.db %01000101
	.db %00111110
	.db %11011010

	.db 8,6
	.db %11110010
	.db %01001110
	.db %10110101
	.db %01000101
	.db %00111110
	.db %01011010

	.db 8,6
	.db %01000001
	.db %00100110
	.db %00010101
	.db %01000100
	.db %00010010
	.db %10011010

	.db 8,6
	.db %01000100
	.db %00100000
	.db %00000001
	.db %01000100
	.db %00100010
	.db %10001000

	.db 8,6
	.db %00001000
	.db %11000010
	.db %00000000
	.db %00100000
	.db %00000001
	.db %00110000

	.db 8,6
	.db %00000100
	.db %00000000
	.db %01000000
	.db %00000000
	.db %00000001
	.db %00100100

;---------------------------- level data -------------------------------------
Leveldata:
	.db $10,$00,$40		;$time (ff=end)    $type    $y-pos
	.db $10,$08,$30
	.db $10,$08,$20
	.db $40,$00,$10
	.db $ff,$ff,$ff

;---------------------------- texts ------------------------------------------

title_message:
         .db      "* * NEMESIS * *",0

;---------------------------- save data --------------------------------------

stored_data_start:

curevent	.dw Leveldata+1		;next event
nextevent	.db (Leveldata)		;time to next event
score		.dw $0000
lives		.dw $0003
level		.dw $0000
x		.db $16
y		.db $46
shield		.db $00
ybullets	.dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
ebuls		.dw 0,0,0,0,0,0,0,0,0,0,0,0,0,0,0
enemies		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000
		.dw $0000,$0000,$0000,$0000,$0000,$0000,$0000,$0000,$ffff,$ffff
; 0011 2233 >>	0=occupation (0=no enemy 1=normal 2=exploding)
;		1=frame/ship 2=x 3=y

boss_status	.db 00
boss_pwr          .db 00
boss_x            .db 00
boss_y            .db 00
boss_2bytes       .dw 0000

timer		.dw $0000
your_status	.db $00
		.db $00
warped_status	.db $00

variables_end:

stored_data_end:


	.end




;NEMESIS'86 by Shiar


; 0.01.717 -- 17.VII.99 -- size 984
;
;	+ movement of ship over whole screen
;	+ enemies moving from right to left, appearing right at specified times
;
; 0.1.718  -- 18.VII.99 -- size 907
;
;	* no crash when level restarts for the third time
;	* exit-procedure updated, unnecessary stuff/keychecks removed
;	* alot of unused code removed
;	+ different types of enemies (just look different)
;	+ collision detection!! enemy ships disappear when you hit them