package PLP;

# Not to be used without the CGI script;

our $VERSION = '3.00';

use PLP::Functions ();
use PLP::Fields;
use PLP::Tie::Headers;
use PLP::Tie::Delay;
use PLP::Tie::Print;

sub SendHeaders () {
    our $sentheaders = 1;
    print STDOUT "Content-Type: text/plain\n\n" if $DEBUG & 2;
    print STDOUT map("$_: $PLP::Script::header{$_}\n", keys %PLP::Script::header), "\n";
};

sub source {
    my ($path, $level) = @_;
    our ($inA, $inB);
    (my $file = $path) =~ s[.*/][];
    my $source = $level
	? qq/\cQ;\n#line 1 "$file"\nprint q\cQ/
	: qq/\n#line 1 "$file"\nprint q\cQ/;
    my $linenr = 0;
    local *SOURCE;
    open SOURCE, $path or return $level
	? qq{\cQ; die qq[Can't open "\Q$path\E" (\Q$!\E)]; print q\cQ}
	: qq{\ndie qq[Can't open "\Q$path\e" (\Q$!\E)];};
    LINE: while (defined (my $line = <SOURCE>)) {
	$linenr++;
	for (;;) {
	    $line =~ /
		\G                  # Begin where left off
		( \z                # End
		| <:=? | :>         # PLP tags     <:=? ... :>
		| <\(.*?\)>         # Include tags <(...)>
		| <[^:(][^<:]*      # Normal text
		| :[^>][^<:]*       # Normal text
		| [^<:]*            # Normal text
		)
	    /gxs;
	    next LINE unless length $1;
	    my $part = $1;
	    if ($part eq '<:=' and not $inA || $inB) {
		$inA = 1;
		$source .= "\cQ, ";
	    } elsif ($part eq '<:' and not $inA || $inB) {
		$inB = 1;
		$source .= "\cQ; ";
	    } elsif ($part eq ':>' and $inA) {
		$inA = 0;
		$source .= ", q\cQ";
	    } elsif ($part eq ':>' and $inB) {
		$inB = 0;
		$source .= "; print q\cQ";
	    } elsif ($part =~ /^<\((.*?)\)>\z/ and not $inA || $inB) {
		$source .= source($1, $level + 1) .
			   qq/\cQ, \n#line $linenr "$file"\nq\cQ/;
	    } else {
		$part =~ s/\\/\\\\/ if not $inA || $inB;
		$source .= $part;
	    }
	}
    }
    $source .= "\cQ" unless $level;
    return $source;
}

1;

