package List::Index;

use 5.010;
use strict;
use warnings;

use Exporter 'import';

our $VERSION = '1.01';
our @EXPORT_OK = qw(rangematch);

sub new {
	my ($class, $values) = @_;
	bless [sort map { s/[^a-z]/./g; $_ } @$values], $class;
}

sub ranges {
	my $self = shift;
	my $options = shift || {};
	my $pagesize = $options->{pagesize} || 50;
	my $context  = $options->{context } // 1 + ($pagesize >> 4);
	my $length   = $options->{length  } || 4;
	my $pages    = $options->{pages   } || 1 + int $#$self / $pagesize;

	$pagesize = @$self / $pages;
	my $offset = 0;
	my @links;
	while ($offset < @$self) {
		my $link = substr $self->[$offset], 0, $length;
		if ($context) {
			my $trim = 1;
			my $before = $offset > $context ? $self->[$offset - $context] : '';
			for my $match (split //, $before) {
				scalar $link =~ /\G\Q$match/g or last;
				$trim++;
			}
			substr($link, $trim) = '' unless $trim > length $link;
		}

		push @links, [$link];
		$offset += $pagesize;
	}

	for my $i (0 .. $#links - 1) {
		my ($link, $lastchar) = $links[$i + 1]->[0] =~ /(.*)(.)/;
		$link .= $lastchar eq '.' ? 'a' : chr( ord($lastchar) - 1 )
			unless $lastchar eq 'a';
		$links[$i]->[1] = $link;
	}
	$links[-1]->[1] = '';

	return \@links;
}

sub rangematch {
	my ($link) = @_;
	my ($s1, $s2) = $link =~ /([^-]*) - ([^-]*)/x
		or return qr/^\Q$link/i;
	my @allow;

	if (length $s1) {
		if (length $s2) {
			$s1 le $s2 or $s1 =~ /^\Q$s2/ or return undef;
		}

		my $prefix = '';
		my $char;
		for my $i (0 .. length($s1) - 1) {
			$char = substr $s1, $i, 1;
			my $next = $char;
			$next = chr( ord($char) + 1 ) if length $s1 > $i + 1;
			my $last = 'z';
			if (length $s2 > $i) {
				if ($s2 =~ /^\Q$prefix/) {
					$last = substr $s2, $i, 1;
					next if $char eq $last;
					$last = chr( ord($last) - (length $s2 > 1) );
					next if $next gt $last;
				}
			}
			push @allow, $prefix."[$next-$last]";
		}
		continue {
			$prefix .= $char;
		}
	}

	if (length $s2) {
		my $prefix = '';
		my $char;
		for my $i (0 .. length($s2) - 1) {
			$char = substr $s2, $i, 1;
			my $last = 'z';
			if (length $s1 > $i) {
				my $c1 = substr $s1, $i, 1;
				if ($s1 =~ /^\Q$prefix/) {
					next if $c1 le $char;
				}
			}
			push @allow, $prefix."(?![$char-$last])"
				if $i or $s1 eq '';
		}
		continue {
			$prefix .= $char;
		}

		push @allow, $prefix
			if $s2 =~ /^\Q$prefix/ and $s1 le $s2
			and not (length $s2 == 1 && length $s1 >= length $s2 && $s1 ne $s2);
	}

	my $match = sprintf @allow <= 1 ? '%s' : '(?:%s)', join('|', @allow);
	return qr/^$match/i;
}

1;

__END__

=head1 NAME

List::Index - Paginate alphabetic entries by finding minimal prefixes

=head1 SYNOPSIS

	use List::Index;
	my $index = List::Index->new(\@values);
	my @pages = $index->ranges({pagesize => 50});
	printf '<a href="?q=%s-%s">%1$s</a> ', @$_ for @pages;

	use List::Index 'rangematch';
	my $limit = rangematch('b-bmq');  # matches prefix like 'baa'..'bmq'
	@results = grep { $limit } @results;

=head1 DESCRIPTION

TODO

=head1 SEE ALSO

L<List::Maker|List::Maker> for complex ranges of numeric lists.

=head1 AUTHOR

Mischa POSLAWSKY <perl@shiar.org>

=head1 LICENSE

Copyright. All rights reserved.

